Missing import of PseudoSteppingSchemes.adaptive_step_parameters?

[navidcy]

Isn't this method

ParameterEstimocean.jl/src/EnsembleKalmanInversions.jl

Lines 509 to 515 in f939c72

	successful_Xⁿ⁺¹, Δt = adaptive_step_parameters(pseudo_stepping,
	successful_Xⁿ,
	successful_Gⁿ,
	eki;
	Δt,
	covariance_inflation,
	momentum_parameter)

from the PseudoSteppingSchemes module

ParameterEstimocean.jl/src/PseudoSteppingSchemes.jl

Line 43 in f939c72

function adaptive_step_parameters(pseudo_scheme, Xₙ, Gₙ, eki; Δt=1.0,

and thus we need to import it?

cc @glwagner, @adelinehillier

[glwagner]

It looks like PseudoSteppingSchemes is importing it from EnsembleKalmanInversions

[navidcy]

But how is EnsembleKalmanInversions using the method PseudoSteppingSchemes defines without importing it?

[glwagner]

It's defined by EnsembleKalmanInversions. The module that defines a function does not need to import it.

[navidcy]

But not that method. Or I missed it….

[glwagner]

EnsembleKalmanInversions is included first in the source:

ParameterEstimocean.jl/src/ParameterEstimocean.jl

Lines 46 to 47 in f939c72

	include("EnsembleKalmanInversions.jl")
	include("PseudoSteppingSchemes.jl")

So, it defines the function adaptive_step_parameters. The first occurrence is here:

ParameterEstimocean.jl/src/EnsembleKalmanInversions.jl

Line 484 in f939c72

adaptive_step_parameters(::Nothing, Xⁿ, Gⁿ, y, Γy, process; Δt) = step_parameters(Xⁿ, Gⁿ, y, Γy, process; Δt), Δt

Next, PseudoSteppingSchemes imports this method:

ParameterEstimocean.jl/src/PseudoSteppingSchemes.jl

Line 15 in f939c72

import ..EnsembleKalmanInversions: adaptive_step_parameters, eki_objective

and extends it here:

ParameterEstimocean.jl/src/PseudoSteppingSchemes.jl

Line 43 in f939c72

function adaptive_step_parameters(pseudo_scheme, Xₙ, Gₙ, eki; Δt=1.0,

[navidcy]

But in line I'm referring at the first comment on this issue, EnsembleKalmanInversions seems to use the method that is extended by PseudoSteppingSchemes. Is this possible? How is this done since, as you point out, EnsembleKalmanInversions is included first in the source? That's my question.

[glwagner]

The method to be used is resolved at the time the function is called (it doesn't have to do with the order in which the methods are defined). So by the time the user calls adaptive_step_parameters (or rather, calls the function that calls it), it's been extended appropriately.

The title of this issue says that EnsembleKalmanInversions should import adaptive_step_parameters from PseudoSteppingSchemes. But this is not possible because EnsembleKalmanInversions is loaded first and therefore PseudoSteppingSchemes does not exist when EnsembleKalmanInversions code is loaded.

[glwagner]

This is an example:

julia> import ParameterEstimocean.Utils: tupleit

julia> tupleit(1)
(1,)

julia> tupleit(a::Number) = println("This isn't a tuple at all")
tupleit (generic function with 2 methods)

julia> tupleit(1)
This isn't a tuple at all

[glwagner]

Or maybe this is a clearer example, where one function is used by another:

julia> g(x, y) = x + y
g (generic function with 1 method)

julia> f(x, y) = 2 * g(x, y)
f (generic function with 1 method)

julia> f(1, 2)
6

julia> g(x::Float64, y::Float64) = x - y
g (generic function with 2 methods)

julia> f(1, 2)
6

julia> f(1.0, 2.0)
-2.0

[navidcy]

So by the time the user calls adaptive_step_parameters (or rather, calls the function that calls it), it's been extended appropriately.

OK, all clear now. Thanks!!

[glwagner]

We can even use functions with no methods at all, provided the name is defined:

julia> function g end
g (generic function with 0 methods)

julia> f(x, y) = 2 * g(x, y)
f (generic function with 1 method)

julia> f(1, 2)
ERROR: MethodError: no method matching g(::Int64, ::Int64)
Stacktrace:
 [1] f(x::Int64, y::Int64)
   @ Main ./REPL[2]:1
 [2] top-level scope
   @ REPL[3]:1

julia> g(x, y) = x + y
g (generic function with 1 method)

julia> f(1, 2)
6

This is a useful technique for building up frameworks