PS3MFW Builder 0.2.1

AUTHORS

@@ -0,0 +1 @@
+Anonymous Developers (Code Monkeys)

AppMain.tcl

@@ -0,0 +1,37 @@
+#!/usr/bin/env wish8.5
+#
+# ps3mfw -- PS3 MFW creator
+#
+# Copyright (C) Anonymous Developers (Code Monkeys)
+#
+# This software is distributed under the terms of the GNU General Public
+# License ("GPL") version 3, as published by the Free Software Foundation.
+#
+
+# MacOS X / Windows wrapper 
+#
+# Mac OSX: Remove Cocoa argument from arglist
+if {[string first "-psn" [lindex $argv 0]] == 0} { set argv [lrange $argv 1 end]}
+
+#Source the main file
+if { $::tcl_platform(platform) == "windows"} {
+	source [file join [pwd] ps3mfw]
+} else {
+	#Set variable program_dir
+	set program_dir [file dirname [info script]]
+	set program [file tail [info script]]
+
+	while {[catch {file readlink [file join $program_dir $program]} program]== 0} {
+		if {[file pathtype $program] == "absolute"} {
+			set program_dir [file dirname $program]
+		} else {
+			set program_dir [file join $program_dir [file dirname $program]]
+		}
+
+		set program [file tail $program]
+	}
+
+	unset program
+	source [file join $program_dir ps3mfw]
+}
+

CREDITS

@@ -0,0 +1,21 @@
+DEVELOPED BY:
+Anonymous Developers (Code Monkeys)
+
+SPECIAL THANKS TO:
+Phineus
+anonymous developer - (self_rebuilder)
+evilsperm
+jbc
+grafchokolo (LV1 Patch)
+PL3 and its contributors (LV2/vsh/nas_plugin patches)
+fail0verflow team
+
+TESTERS:
+jbc
+King "The Man" Dong
+CrackKillsDreams
+drizztbsd
+CrashSerious
+kmeaw
+a few other anonymous testers.
+

FIRMWARE

@@ -0,0 +1,12 @@
+3.15 PS3UPDAT.PUP
+MD5::54ee80e14e479f8351a988eb9a472072
+SHA1::fc4e891e84333f9b37ff7f253eca165aa416c6ad
+
+3.41 PS3UPDAT.PUP
+MD5::e07d2b84c9e9691c261b73e5f1aada20
+SHA1::e7f522ba85c8fc780b8bcbaff6c70d36487e2e45
+
+3.55 PS3UPDAT.PUP
+MD5::ca595ad9f3af8f1491d9c9b6921a8c61
+SHA1::a3a0d1c61e17c6a58a5fa247a3dbb51524329e0a
+

Settings.xml

@@ -0,0 +1,9 @@
+<Settings>
+    <language>English</language>
+	<BUILD_DIR>C:\Users\DanyL\AppData\Local\Temp\PS3MFW</BUILD_DIR>
+	<PS3_KEYS></PS3_KEYS>
+    <Theme>xpnative</Theme>
+    <IN_FILE></IN_FILE>
+    <OUT_FILE></OUT_FILE>
+	<tasks> add_license_msg change_version patch_category_game</tasks>
+</Settings>

console.tcl

@@ -0,0 +1,199 @@
+# FILE: console.tcl
+ #
+ #       Provides a console window.
+ #
+ # Last modified on: $Date: 2006-01-28 17:42:17 -0500 (Sat, 28 Jan 2006) $
+ # Last modified by: $Author: redacted $
+ #
+ # This file is evaluated to provide a console window interface to the
+ # root Tcl interpreter of an OOMMF application.  It calls on a script
+ # included with the Tk script library to do most of the work, making use
+ # of Tk interface details which are only semi-public.  For this reason,
+ # there is some risk that future versions of Tk will no longer support
+ # this script.  That is why this script has been isolated in a file of
+ # its own.
+
+ ########################################################################
+ # If the Tcl command 'console' is already in the interpreter, our work
+ # is done.
+ ########################################################################
+ if {![catch {console show}]} {
+     return
+ }
+
+ ########################################################################
+ # Check Tcl/Tk support
+ ########################################################################
+ if {[catch {package require Tcl 8}]} {
+     package require Tcl 7.5
+ }
+
+ if {[catch {package require Tk 8}]} {
+     if {[catch {package require Tk 4.1}]} {
+         return -code error "Tk required but not loaded."
+     }
+ }
+
+ set _ [file join $tk_library console.tcl]
+ if {![file readable $_]} {
+     return -code error "File not readable: $_"
+ }
+
+ ########################################################################
+ # Provide the support which the Tk library script console.tcl assumes
+ ########################################################################
+ # 1. Create an interpreter for the console window widget and load Tk
+ set consoleInterp [interp create]
+ $consoleInterp eval [list set tk_library $tk_library]
+ $consoleInterp alias exit exit
+ load "" Tk $consoleInterp
+
+ # 2. A command 'console' in the application interpreter
+ ;proc console {sub {optarg {}}} [subst -nocommands {
+     switch -exact -- \$sub {
+        title {
+            $consoleInterp eval wm title . [list \$optarg]
+        }
+        hide {
+            $consoleInterp eval wm withdraw .
+        }
+        show {
+            $consoleInterp eval wm deiconify .
+        }
+        eval {
+            $consoleInterp eval \$optarg
+        }
+        default {
+            error "bad option \\\"\$sub\\\": should be hide, show, or title"
+        }
+    }
+ }]
+
+ # 3. Alias a command 'consoleinterp' in the console window interpreter
+ #       to cause evaluation of the command 'consoleinterp' in the
+ #       application interpreter.
+ ;proc consoleinterp {sub cmd} {
+    switch -exact -- $sub {
+        eval {
+            uplevel #0 $cmd
+        }
+        record {
+            history add $cmd
+            catch {uplevel #0 $cmd} retval
+            return $retval
+        }
+        default {
+            error "bad option \"$sub\": should be eval or record"
+        }
+    }
+ }
+ if {[package vsatisfies [package provide Tk] 4]} {
+    $consoleInterp alias interp consoleinterp
+ } else {
+    $consoleInterp alias consoleinterp consoleinterp
+ }
+
+ # 4. Bind the <Destroy> event of the application interpreter's main
+ #    window to kill the console (via tkConsoleExit)
+ bind . <Destroy> [list +if {[string match . %W]} [list catch \
+        [list $consoleInterp eval tkConsoleExit]]]
+
+ # 5. Redefine the Tcl command 'puts' in the application interpreter
+ #    so that messages to stdout and stderr appear in the console.
+ rename puts tcl_puts
+ ;proc puts {args} [subst -nocommands {
+    switch -exact -- [llength \$args] {
+        1 {
+            if {[string match -nonewline \$args]} {
+                if {[catch {uplevel 1 [linsert \$args 0 tcl_puts]} msg]} {
+                    regsub -all tcl_puts \$msg puts msg
+                    return -code error \$msg
+                }
+            } else {
+                $consoleInterp eval [list tkConsoleOutput stdout \
+                        "[lindex \$args 0]\n"]
+            }
+        }
+        2 {
+            if {[string match -nonewline [lindex \$args 0]]} {
+                $consoleInterp eval [list tkConsoleOutput stdout \
+                        [lindex \$args 1]]
+            } elseif {[string match stdout [lindex \$args 0]]} {
+                $consoleInterp eval [list tkConsoleOutput stdout \
+                        "[lindex \$args 1]\n"]
+            } elseif {[string match stderr [lindex \$args 0]]} {
+                $consoleInterp eval [list tkConsoleOutput stderr \
+                        "[lindex \$args 1]\n"]
+            } else {
+                if {[catch {uplevel 1 [linsert \$args 0 tcl_puts]} msg]} {
+                    regsub -all tcl_puts \$msg puts msg
+                    return -code error \$msg
+                }
+            }
+        }
+        3 {
+            if {![string match -nonewline [lindex \$args 0]]} {
+                if {[catch {uplevel 1 [linsert \$args 0 tcl_puts]} msg]} {
+                    regsub -all tcl_puts \$msg puts msg
+                    return -code error \$msg
+                }
+            } elseif {[string match stdout [lindex \$args 1]]} {
+                $consoleInterp eval [list tkConsoleOutput stdout \
+                        [lindex \$args 2]]
+            } elseif {[string match stderr [lindex \$args 1]]} {
+                $consoleInterp eval [list tkConsoleOutput stderr \
+                        [lindex \$args 2]]
+            } else {
+                if {[catch {uplevel 1 [linsert \$args 0 tcl_puts]} msg]} {
+                    regsub -all tcl_puts \$msg puts msg
+                    return -code error \$msg
+                }
+            }
+        }
+        default {
+            if {[catch {uplevel 1 [linsert \$args 0 tcl_puts]} msg]} {
+                regsub -all tcl_puts \$msg puts msg
+                return -code error \$msg
+            }
+        }
+    }
+ }]
+ $consoleInterp alias puts puts
+
+ # 6. No matter what Tk_Main says, insist that this is an interactive  shell
+ set tcl_interactive 1
+
+ ########################################################################
+ # Evaluate the Tk library script console.tcl in the console interpreter
+ ########################################################################
+ $consoleInterp eval source [list [file join $tk_library console.tcl]]
+ $consoleInterp eval {
+    if {![llength [info commands tkConsoleExit]]} {
+        tk::unsupported::ExposePrivateCommand tkConsoleExit
+    }
+ }
+ $consoleInterp eval {
+    if {![llength [info commands tkConsoleOutput]]} {
+        tk::unsupported::ExposePrivateCommand tkConsoleOutput
+    }
+ }
+ if {[string match 8.3.4 $tk_patchLevel]} {
+    # Workaround bug in first draft of the tkcon enhancments
+    $consoleInterp eval {
+        bind Console <Control-Key-v> {}
+    }
+ }
+ # Restore normal [puts] if console widget goes away...
+ proc Oc_RestorePuts {slave} {
+     rename puts {}
+     rename tcl_puts puts
+     interp delete $slave
+ }
+ $consoleInterp alias Oc_RestorePuts Oc_RestorePuts $consoleInterp
+ $consoleInterp eval {
+     bind Console <Destroy> +Oc_RestorePuts
+ }
+
+ unset consoleInterp
+
+ console title "[wm title .] Console"