Initial import of evolution-ews skeleton

Makefile.am

@@ -0,0 +1,17 @@
+SUBDIRS = src po
+DIST_SUBDIRS= src po
+
+changelogs =			\
+	ChangeLog
+
+EXTRA_DIST = 			\
+	$(changelog)		\
+	intltool-merge.in	\
+	intltool-update.in	\
+	intltool-extract.in	
+
+CLEANFILES = 	intltool-merge	\
+		intltool-update	\
+		intltool-extract	
+
+-include $(top_srcdir)/git.mk

README

@@ -0,0 +1 @@
+http://www.go-evolution.org/

acinclude.m4

@@ -0,0 +1,62 @@
+dnl as-compiler-flag.m4 0.1.0
+
+dnl autostars m4 macro for detection of compiler flags
+
+dnl David Schleef <ds@schleef.org>
+
+dnl $Id: as-compiler-flag.m4,v 1.1 2005/12/15 23:35:19 ds Exp $
+
+dnl AS_COMPILER_FLAG(CFLAGS, ACTION-IF-ACCEPTED, [ACTION-IF-NOT-ACCEPTED])
+dnl Tries to compile with the given CFLAGS.
+dnl Runs ACTION-IF-ACCEPTED if the compiler can compile with the flags,
+dnl and ACTION-IF-NOT-ACCEPTED otherwise.
+
+AC_DEFUN([AS_COMPILER_FLAG],
+[
+  AC_MSG_CHECKING([to see if compiler understands $1])
+
+  save_CFLAGS="$CFLAGS"
+  CFLAGS="$CFLAGS $1"
+
+  AC_TRY_COMPILE([ ], [], [flag_ok=yes], [flag_ok=no])
+  CFLAGS="$save_CFLAGS"
+
+  if test "X$flag_ok" = Xyes ; then
+    m4_ifvaln([$2],[$2])
+    true
+  else
+    m4_ifvaln([$3],[$3])
+    true
+  fi
+  AC_MSG_RESULT([$flag_ok])
+])
+
+dnl AS_COMPILER_FLAGS(VAR, FLAGS)
+dnl Tries to compile with the given CFLAGS.
+
+AC_DEFUN([AS_COMPILER_FLAGS],
+[
+  list=$2
+  flags_supported=""
+  flags_unsupported=""
+  AC_MSG_CHECKING([for supported compiler flags])
+  for each in $list
+  do
+    save_CFLAGS="$CFLAGS"
+    CFLAGS="$CFLAGS $each"
+    AC_TRY_COMPILE([ ], [], [flag_ok=yes], [flag_ok=no])
+    CFLAGS="$save_CFLAGS"
+
+    if test "X$flag_ok" = Xyes ; then
+      flags_supported="$flags_supported $each"
+    else
+      flags_unsupported="$flags_unsupported $each"
+    fi
+  done
+  AC_MSG_RESULT([$flags_supported])
+  if test "X$flags_unsupported" != X ; then
+    AC_MSG_WARN([unsupported compiler flags: $flags_unsupported])
+  fi
+  $1="$$1 $flags_supported"
+])
+

autogen.sh

@@ -0,0 +1,25 @@
+#!/bin/sh
+# Run this to generate all the initial makefiles, etc.
+
+srcdir=`dirname $0`
+test -z "$srcdir" && srcdir=.
+
+PKG_NAME="evolution-groupwise"
+REQUIRED_AUTOCONF_VERSION=2.58
+REQUIRED_AUTOMAKE_VERSION=1.9
+REQUIRED_LIBTOOL_VERSION=2.2
+REQUIRED_INTLTOOL_VERSION=0.35.5
+
+(test -f $srcdir/configure.ac \
+  && test -f $srcdir/ChangeLog \
+  && test -d $srcdir/src/camel) || {
+    echo -n "**Error**: Directory "\`$srcdir\'" does not look like the" >&2
+    echo " top-level $PKG_NAME directory" >&2
+    exit 1
+}
+
+which gnome-autogen.sh || {
+    echo "You need to install gnome-common from the GNOME git" >&2
+    exit 1
+}
+USE_GNOME2_MACROS=1 . gnome-autogen.sh

configure.ac

@@ -0,0 +1,220 @@
+AC_PREREQ(2.58)
+AC_INIT([evolution-ews], [0.31.0], [http://bugzilla.gnome.org/browse.cgi?product=evolution-ews])
+AM_INIT_AUTOMAKE([gnu 1.9])
+AC_CONFIG_SRCDIR(README)
+AC_CONFIG_HEADERS(config.h)
+
+BASE_VERSION=3.0
+m4_define([base_version], [3.0])
+AC_SUBST(BASE_VERSION)
+
+dnl ****************************
+dnl Evolution-EWS API version
+dnl ****************************
+m4_define([EVO_EWS_API_VERSION_MACRO], [1.0])
+EVO_EWS_API_VERSION=EVO_EWS_API_VERSION_MACRO
+AC_SUBST(EVO_EWS_API_VERSION)
+
+dnl Some requirements have versioned package names
+dnl XXX In the spirit of getting rid of versioned
+dnl     files, can we please drop these suffixes?
+EDS_PACKAGE=1.2
+
+dnl *******************
+dnl Required Packages
+dnl *******************
+m4_define([eds_minimum_version], [2.31.1])
+m4_define([evo_minimum_version], [2.31.1])
+m4_define([glib_minimum_version], [2.16.1])
+m4_define([gconf_minimum_version], [2.0.0])
+
+dnl **********************************
+dnl Gtk-3 compatibility
+dnl Use the API version 3.0 while compiling with gtk+-3
+dnl **********************************
+AC_ARG_ENABLE([gtk3],
+	AS_HELP_STRING([--enable-gtk3],
+	[Attempt to use gtk+-3]),
+	[enable_gtk3=$enableval],[enable_gtk3=no])
+
+if test "x${enable_gtk3}" = "xyes"; then
+	LIBEDATASERVER_UI_API_VERSION=3.0
+	GTK_PACKAGE="gtk+-3.0"
+	EVO_PLUGIN_PACKAGE="evolution-plugin-3.0"
+	gtk_minimum_version="2.90.4"
+	gweather_minimum_version="2.90.0"
+else	
+	LIBEDATASERVER_UI_API_VERSION=1.2
+	GTK_PACKAGE="gtk+-2.0"
+	EVO_PLUGIN_PACKAGE="evolution-plugin"
+	gtk_minimum_version="2.20.0"
+	gweather_minimum_version="2.25.4"
+fi
+
+AM_CONDITIONAL([ENABLE_GTK3], [test "$enable_gtk3" = yes])
+GTK_MODULE="$GTK_PACKAGE >= $gtk_minimum_version"
+AC_SUBST(GTK_MODULE)
+
+dnl ***********************************
+dnl Automake 1.11 - Silent Build Rules
+dnl ***********************************
+m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+
+dnl ****************************
+dnl Initialize maintainer mode
+dnl ****************************
+AM_MAINTAINER_MODE
+
+AC_PROG_CC
+AC_PROG_CPP
+AC_C_INLINE
+AC_PROG_INSTALL
+AC_PROG_LN_S
+AC_PROG_MAKE_SET
+
+dnl ***********************
+dnl Compiler Warning Flags
+dnl ***********************
+AS_COMPILER_FLAGS(WARNING_FLAGS,
+	"-DG_DISABLE_DEPRECATED
+	-DPANGO_DISABLE_DEPRECATED
+	-DGDK_DISABLE_DEPRECATED
+	-DGDK_PIXBUF_DISABLE_DEPRECATED
+	-DGTK_DISABLE_DEPRECATED
+	-DGNOME_DISABLE_DEPRECATED
+	-DGSEAL_ENABLE
+	-Wall -Wextra
+	-Wno-missing-field-initializers
+	-Wno-sign-compare
+	-Wno-unused-parameter
+	-Wdeclaration-after-statement
+	-Werror-implicit-function-declaration
+	-Wformat-nonliteral -Wformat-security -Winit-self
+	-Wmissing-declarations -Wmissing-include-dirs
+	-Wmissing-noreturn -Wnested-externs -Wpointer-arith
+	-Wundef -Wwrite-strings")
+AC_SUBST(WARNING_FLAGS)
+
+dnl Other useful compiler warnings for test builds only.
+dnl These may produce warnings we have no control over.
+dnl
+dnl	-Wmissing-format-attribute
+dnl	-Wshadow
+dnl	-Wredundant-decls
+
+CFLAGS="$CFLAGS $WARNING_FLAGS"
+
+dnl ************
+dnl i18n stuff
+dnl ************
+IT_PROG_INTLTOOL([0.35.5])
+AM_GLIB_GNU_GETTEXT
+
+GETTEXT_PACKAGE=evolution-ews
+AC_SUBST(GETTEXT_PACKAGE)
+AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Package name for gettext])
+
+localedir='$(prefix)/$(DATADIRNAME)/locale'
+AC_SUBST(localedir)
+
+dnl ****************************
+dnl Initialize libtool
+dnl ****************************
+AM_DISABLE_STATIC
+AC_PROG_LIBTOOL
+
+PKG_PROG_PKG_CONFIG
+
+dnl *****************************
+dnl Check for GNOME Platform
+dnl *****************************
+PKG_CHECK_MODULES(GNOME_PLATFORM,
+	[glib-2.0 >= glib_minimum_version
+	$GTK_MODULE
+	gconf-2.0 >= gconf_minimum_version])
+
+dnl ********************************
+dnl Check for evolution-data-server 
+dnl ********************************
+PKG_CHECK_MODULES(EVOLUTION_DATA_SERVER, evolution-data-server-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBEDATASERVER, libedataserver-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBEBACKEND, libebackend-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBECAL, libecal-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBEDATACAL, libedata-cal-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBBOOK, libebook-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(LIBEDATABOOK, libedata-book-$EDS_PACKAGE >= eds_minimum_version)
+PKG_CHECK_MODULES(CAMEL, camel-provider-$EDS_PACKAGE >= eds_minimum_version)
+
+dnl ****************************
+dnl Check for evolution plugins 
+dnl ****************************
+PKG_CHECK_MODULES(EVOLUTION_PLUGIN, evolution-plugin >= evo_minimum_version)
+
+dnl ****************************
+dnl Expose version information
+dnl ****************************
+API_VERSION=$EDS_PACKAGE
+AC_SUBST(API_VERSION)
+
+EDS_REQUIRED=eds_minimum_version
+AC_SUBST(EDS_REQUIRED)
+
+EVO_REQUIRED=evo_minimum_version
+AC_SUBST(EVO_REQUIRED)
+
+dnl *******************************
+dnl Add evolution plugin rules here
+dnl *******************************
+EVO_PLUGIN_RULE=$srcdir/eplugin-rule.mk
+AC_SUBST_FILE(EVO_PLUGIN_RULE)
+
+dnl *******************
+dnl Special directories
+dnl *******************
+plugindir=`$PKG_CONFIG --variable=plugindir evolution-plugin`
+AC_SUBST(plugindir)
+
+extensiondir=`$PKG_CONFIG --variable=extensiondir evolution-data-server-$EDS_PACKAGE`
+AC_SUBST(extensiondir)
+
+camel_providerdir=`$PKG_CONFIG --variable=camel_providerdir camel-provider-$EDS_PACKAGE`
+AC_SUBST(camel_providerdir) 
+
+privdatadir='${datadir}'/evolution-data-server-$BASE_VERSION
+AC_SUBST(privdatadir)
+
+privincludedir='${includedir}'/evolution-data-server-$BASE_VERSION
+AC_SUBST(privincludedir)
+
+privlibdir='${libdir}'/evolution-data-server-$BASE_VERSION
+AC_SUBST(privlibdir)
+
+imagesdir='${datadir}'/pixmaps/evolution-data-server
+AC_SUBST(imagesdir)
+
+uidir="$privdatadir/ui"
+AC_SUBST(uidir)
+
+edataserver_privincludedir=`$PKG_CONFIG --variable=privincludedir libedataserver-$EDS_PACKAGE`
+AC_SUBST(edataserver_privincludedir)
+
+dnl *************
+dnl Gtk Doc stuff
+dnl *************
+GTK_DOC_CHECK(1.9)
+
+dnl **************************
+dnl Makefiles, generated .pc's
+dnl **************************
+AC_CONFIG_FILES([
+Makefile 
+src/Makefile
+src/account-setup-eplugin/Makefile
+src/addressbook/Makefile
+src/calendar/Makefile
+src/camel/Makefile
+src/server/Makefile
+src/server/libeews.pc
+po/Makefile.in
+])
+AC_OUTPUT

po/POTFILES.in

@@ -0,0 +1,3 @@
+# List of source files containing translatable strings.
+# Please keep this list in alphabetic order.
+[encoding: UTF-8]

src/Makefile.am

@@ -0,0 +1,17 @@
+SUBDIRS = server calendar addressbook camel
+DIST_SUBDIRS = server calendar addressbook camel
+
+changelogs =			\
+	ChangeLog
+
+EXTRA_DIST = 			\
+	$(changelog)		\
+	intltool-merge.in	\
+	intltool-update.in	\
+	intltool-extract.in	
+
+CLEANFILES = 	intltool-merge	\
+		intltool-update	\
+		intltool-extract	
+
+-include $(top_srcdir)/git.mk

src/account-setup-eplugin/Makefile.am

@@ -0,0 +1,37 @@
+AM_CPPFLAGS = -I .					\
+	-DEVOLUTION_GLADEDIR=\""$(gladedir)"\" 		\
+	-DCONNECTOR_GLADEDIR=\""$(gladedir)"\" 		\
+	$(EVOLUTION_PLUGIN_CFLAGS)			\
+	$(CAMEL_CFLAGS)				\
+	$(LIBECAL_CFLAGS)
+
+@EVO_PLUGIN_RULE@
+
+plugin_DATA = org-gnome-exchange-ews.eplug 	
+
+plugin_LTLIBRARIES = liborg-gnome-exchange-ews.la
+
+liborg_gnome_exchange_ews_la_SOURCES = 		\
+	exchange-ews-account-setup.c			\
+	exchange-ews-account-setup.h			\
+	exchange-ews-account-listener.c		\
+	exchange-ews-account-listener.h
+
+liborg_gnome_exchange_ews_la_LIBADD = 			\
+	$(top_builddir)/src/libexchangeews/libexchangeews-1.0.la \
+	$(EVOLUTION_PLUGIN_LIBS)			\
+	$(CAMEL_LIBS) 					\
+	$(LIBECAL_LIBS)
+
+liborg_gnome_exchange_ews_la_LDFLAGS = -module -avoid-version -no-undefined
+liborg_gnome_exchange_ews_la_CFLAGS = $(LIBEWS_CFLAGS)
+
+EXTRA_DIST = 						\
+	org-gnome-exchange-ews.eplug.xml
+
+BUILT_SOURCES = org-gnome-exchange-ews.eplug	
+
+CLEANFILES = $(BUILT_SOURCES)
+
+
+-include $(top_srcdir)/git.mk