-
Notifications
You must be signed in to change notification settings - Fork 140
/
milawa_logicScript.sml
2258 lines (2073 loc) · 105 KB
/
milawa_logicScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
open HolKernel Parse boolLib bossLib; val _ = new_theory "milawa_logic";
open listTheory arithmeticTheory lisp_sexpTheory milawa_ordinalTheory;
open pred_setTheory combinTheory finite_mapTheory stringTheory;
(* ========================================================================== *)
(* *)
(* This theory defines (1) the syntax of the Milawa logic, *)
(* (2) its semantics and *)
(* (3) its axioms and inference rules. *)
(* *)
(* Towards the end we also prove soundness and theorem which states that *)
(* it is sound to add new definitions. *)
(* *)
(* ========================================================================== *)
infix \\
val op \\ = op THEN;
(* PART 1: SYNTAX
We start by defining the abstract syntax of valid Milawa terms and formulas. *)
val _ = Hol_datatype `
logic_primitive_op =
logic_CONS | logic_EQUAL | logic_LESS | logic_SYMBOL_LESS |
logic_ADD | logic_SUB | logic_NOT | logic_RANK | logic_CONSP | logic_NATP |
logic_SYMBOLP | logic_CAR | logic_CDR | logic_ORD_LESS | logic_ORDP | logic_IF`;
val _ = Hol_datatype `
logic_func = mPrimitiveFun of logic_primitive_op
| mFun of string`;
val _ = Hol_datatype `
logic_term = mConst of SExp
| mVar of string
| mApp of logic_func => logic_term list
| mLamApp of string list => logic_term => logic_term list`
val _ = Hol_datatype `
formula = Or of formula => formula (* por* *)
| Not of formula (* pnot* *)
| Equal of logic_term => logic_term (* pequal* *)`;
(* Unfortunately, the above definition is not enough to completely define
what correct syntax is. In particular, the folloing properties require
a separate (term_ok) assertion:
- all user-defined functions must have an entry in the context (ctxt)
- the arity of function applications must be correct
- all variables inside the body of mLamApp must be bound
- the variable list in mLamApp must not contain duplicates
- the number of arguments to mLamApp must match the parameter list
A context (ctxt) is a finite mapping from function names (strings)
to lists of formal parameters (strings) and either:
- concrete function body (term), or
- witness function for a certain expression and variable name. *)
val logic_term_size_def = fetch "-" "logic_term_size_def";
val free_vars_def = tDefine "free_vars" `
(free_vars (mConst s) = []) /\
(free_vars (mVar v) = [v]) /\
(free_vars (mApp fc vs) = FLAT (MAP free_vars vs)) /\
(free_vars (mLamApp xs z ys) = FLAT (MAP free_vars ys))`
(WF_REL_TAC `measure logic_term_size` \\ SRW_TAC [] []
THEN1 (Induct_on `vs` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
THEN1 (Induct_on `ys` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
\\ DECIDE_TAC);
val primitive_arity_def = Define `
(primitive_arity logic_CONSP = 1) /\
(primitive_arity logic_NATP = 1) /\
(primitive_arity logic_SYMBOLP = 1) /\
(primitive_arity logic_CAR = 1) /\
(primitive_arity logic_CDR = 1) /\
(primitive_arity logic_ORDP = 1) /\
(primitive_arity logic_NOT = 1) /\
(primitive_arity logic_RANK = 1) /\
(primitive_arity logic_IF = 3) /\
(primitive_arity _ = 2:num)`;
val _ = Hol_datatype `
func_body = (* body of normal function defition *)
BODY_FUN of logic_term
| (* expression, variable name, and semantic witness function *)
WITNESS_FUN of logic_term => string
| (* intermediate step in function definition *)
NO_FUN`;
val _ = type_abbrev("context_type",
``:string |-> (string list # func_body # (SExp list -> SExp))``)
val func_arity_def = Define `
(func_arity (ctxt:context_type) (mPrimitiveFun p) = SOME (primitive_arity p)) /\
(func_arity ctxt (mFun f) = if f IN FDOM ctxt then SOME (LENGTH (FST (ctxt ' f))) else NONE)`;
val term_ok_def = tDefine "term_ok" `
(term_ok ctxt (mConst s) = T) /\
(term_ok ctxt (mVar v) = T) /\
(term_ok ctxt (mApp fc vs) =
(func_arity ctxt fc = SOME (LENGTH vs)) /\ EVERY (term_ok ctxt) vs) /\
(term_ok ctxt (mLamApp xs y zs) =
(LIST_TO_SET (free_vars y) SUBSET LIST_TO_SET xs) /\ ALL_DISTINCT xs /\
EVERY (term_ok ctxt) zs /\ term_ok ctxt y /\ (LENGTH xs = LENGTH zs))`
(WF_REL_TAC `measure (logic_term_size o SND)` \\ SRW_TAC [] [] THEN1 DECIDE_TAC
THEN1 (Induct_on `vs` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
THEN1 (Induct_on `zs` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
\\ DECIDE_TAC);
val formula_ok_def = Define `
(formula_ok ctxt (Not x) = formula_ok ctxt x) /\
(formula_ok ctxt (Or x y) = formula_ok ctxt x /\ formula_ok ctxt y) /\
(formula_ok ctxt (Equal t1 t2) = term_ok ctxt t1 /\ term_ok ctxt t2)`;
(* PART 2: Semantics
We define the semantics of a formula as MilawaValid. For that we
need a few auxilliary definitions. First we need a semantics for
evaluation of terms. *)
val FunVarBind_def = Define `
(FunVarBind [] args = (\x. Sym "NIL")) /\
(FunVarBind (p::ps) [] = (\x. Sym "NIL")) /\
(FunVarBind (p::ps) (a::as) = (p =+ a) (FunVarBind ps as))`;
val LISP_IF_def = Define `LISP_IF x y z = if isTrue x then y else z`;
val EVAL_PRIMITIVE_def = Define `
(EVAL_PRIMITIVE logic_CONS xs = LISP_CONS (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_EQUAL xs = LISP_EQUAL (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_LESS xs = LISP_LESS (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_SYMBOL_LESS xs = LISP_SYMBOL_LESS (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_ADD xs = LISP_ADD (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_SUB xs = LISP_SUB (EL 0 xs) (EL 1 xs)) /\
(EVAL_PRIMITIVE logic_CONSP xs = LISP_CONSP (EL 0 xs)) /\
(EVAL_PRIMITIVE logic_NATP xs = LISP_NUMBERP (EL 0 xs)) /\
(EVAL_PRIMITIVE logic_SYMBOLP xs = LISP_SYMBOLP (EL 0 xs)) /\
(EVAL_PRIMITIVE logic_NOT xs = LISP_TEST (EL 0 xs = Sym "NIL")) /\
(EVAL_PRIMITIVE logic_RANK xs = Val (LSIZE (EL 0 xs))) /\
(EVAL_PRIMITIVE logic_IF xs = LISP_IF (EL 0 xs) (EL 1 xs) (EL 2 xs)) /\
(EVAL_PRIMITIVE logic_CAR xs = CAR (EL 0 xs)) /\
(EVAL_PRIMITIVE logic_CDR xs = CDR (EL 0 xs)) /\
(EVAL_PRIMITIVE logic_ORD_LESS xs = LISP_TEST (ORD_LT (EL 0 xs) (EL 1 xs))) /\
(EVAL_PRIMITIVE logic_ORDP xs = LISP_TEST (ORDP (EL 0 xs)))`;
val EvalApp_def = Define `
(EvalApp (mPrimitiveFun p,args,ctxt) = EVAL_PRIMITIVE p args) /\
(EvalApp (mFun name,args,ctxt) =
let (params,body,sem) = ctxt ' name in sem args)`;
val MEM_IMP_logic_term_size = prove(
``!xs x. MEM x xs ==> logic_term_size x < logic_term1_size xs``,
Induct \\ SIMP_TAC std_ss [MEM] \\ NTAC 2 STRIP_TAC
\\ Cases_on `x = h` \\ FULL_SIMP_TAC std_ss [EVERY_DEF,logic_term_size_def]
\\ REPEAT STRIP_TAC THEN1 DECIDE_TAC \\ RES_TAC \\ DECIDE_TAC);
val EvalTerm_def = tDefine "EvalTerm" `
(EvalTerm (a,ctxt) (mConst c) = c) /\
(EvalTerm (a,ctxt) (mVar v) = a v) /\
(EvalTerm (a,ctxt) (mApp f args) =
EvalApp (f,MAP (EvalTerm (a,ctxt)) args,ctxt)) /\
(EvalTerm (a,ctxt) (mLamApp vs x ys) =
let xs = MAP (EvalTerm (a,ctxt)) ys in
EvalTerm (FunVarBind vs xs,ctxt) x)`
(WF_REL_TAC `measure (logic_term_size o SND)`
\\ SRW_TAC [] []
\\ IMP_RES_TAC MEM_IMP_logic_term_size
\\ REPEAT DECIDE_TAC
\\ Cases_on `args` \\ FULL_SIMP_TAC std_ss [LENGTH]
\\ Cases_on `t` \\ FULL_SIMP_TAC std_ss [LENGTH]
\\ Cases_on `t'` \\ FULL_SIMP_TAC std_ss [LENGTH,EL]
\\ EVAL_TAC \\ DECIDE_TAC);
val EvalFormula_def = Define `
(EvalFormula (a,ctxt) (Not f) = ~EvalFormula (a,ctxt) f) /\
(EvalFormula (a,ctxt) (Or f1 f2) = EvalFormula (a,ctxt) f1 \/ EvalFormula (a,ctxt) f2) /\
(EvalFormula (a,ctxt) (Equal t1 t2) = (EvalTerm (a,ctxt) t1 = EvalTerm (a,ctxt) t2))`;
(* A Milawa formula is considered to be valid if it is true for all
variable instantiations, and syntacically well-formed. *)
val MilawaValid_def = Define `
MilawaValid ctxt f = formula_ok ctxt f /\ !a. EvalFormula (a,ctxt) f`;
(* We require all functions in the context to be syntactically correct
functions that do not to have any duplicate parameters and do not
mention variables other than their respective formal
parameters. Their semantic functions must satisfy the relevant
property: functions that have a concrete body, and must satisfy the
defining equation and witness functions must return a value that
make a property true.
Notice that normal function definitions need not exist. *)
val context_ok_def = Define `
context_ok ctxt =
(!fname params body sem.
fname IN FDOM ctxt /\ (ctxt ' fname = (params,BODY_FUN body,sem)) ==>
term_ok ctxt body /\ ALL_DISTINCT params /\
LIST_TO_SET (free_vars body) SUBSET LIST_TO_SET params /\
!i. sem (MAP i params) = EvalTerm (i,ctxt) body) /\
(!fname params exp var sem.
fname IN FDOM ctxt /\ (ctxt ' fname = (params,WITNESS_FUN exp var,sem)) ==>
term_ok ctxt exp /\ ALL_DISTINCT (var::params) /\
LIST_TO_SET (free_vars exp) SUBSET LIST_TO_SET (var::params) /\
!args.
(?v. isTrue (EvalTerm (FunVarBind (var::params) (v::args),ctxt) exp)) ==>
isTrue (EvalTerm (FunVarBind (var::params) ((sem args)::args),ctxt) exp))`;
(* PART 3: Axioms and inference rules *)
(* --- Axioms --- *)
val natp = ``mApp (mPrimitiveFun logic_NATP)``
val symbolp = ``mApp (mPrimitiveFun logic_SYMBOLP)``
val consp = ``mApp (mPrimitiveFun logic_CONSP)``
val ordp = ``mApp (mPrimitiveFun logic_ORDP)``
val ord_less = ``mApp (mPrimitiveFun logic_ORD_LESS)``
val eequal = ``mApp (mPrimitiveFun logic_EQUAL)``
val ccons = ``mApp (mPrimitiveFun logic_CONS)``
val car = ``mApp (mPrimitiveFun logic_CAR)``
val cdr = ``mApp (mPrimitiveFun logic_CDR)``
val symbol_less = ``mApp (mPrimitiveFun logic_SYMBOL_LESS)``
val add = ``mApp (mPrimitiveFun logic_ADD)``
val sub = ``mApp (mPrimitiveFun logic_SUB)``
val less = ``mApp (mPrimitiveFun logic_LESS)``
val nnot = ``mApp (mPrimitiveFun logic_NOT)``
val rank = ``mApp (mPrimitiveFun logic_RANK)``
val ord_lt = ``mApp (mPrimitiveFun logic_ORD_LESS)``
val ordp = ``mApp (mPrimitiveFun logic_ORDP)``
val iff = ``mApp (mPrimitiveFun logic_IF)``
val t = ``mConst (Sym "T")``
val nnil = ``mConst (Sym "NIL")``
val pnot = ``Not``
val pequal = ``Equal``
val por = ``Or``
val a = ``mVar "A"``
val b = ``mVar "B"``
val c = ``mVar "C"``
val x = ``mVar "X"``
val y = ``mVar "Y"``
val z = ``mVar "Z"``
val x1 = ``mVar "X1"``
val x2 = ``mVar "X2"``
val x3 = ``mVar "X3"``
val y1 = ``mVar "Y1"``
val y2 = ``mVar "Y2"``
val y3 = ``mVar "Y3"``
val zero = ``mConst (Val 0)``
val one = ``mConst (Val 1)``
val aand = ``(\x y. mIf x y (mConst (Sym "NIL")))``
val MILAWA_AXIOMS_def = Define `
MILAWA_AXIOMS = [
(* Axiom 1. reflexivity *)
(^pequal ^x ^x);
(* Axiom 2. equality *)
(^por (^pnot (^pequal ^x1 ^y1))
(^por (^pnot (^pequal ^x2 ^y2))
(^por (^pnot (^pequal ^x1 ^x2))
(^pequal ^y1 ^y2))));
(* Axiom 3. t-not-nil *)
(^pnot (^pequal ^t ^nnil));
(* Axiom 4. equal-when-same *)
(^por (^pnot (^pequal ^x ^y))
(^pequal (^eequal [^x;^y]) ^t));
(* Axiom 5. equal-when-diff *)
(^por (^pequal ^x ^y)
(^pequal (^eequal [^x;^y]) ^nnil));
(* Axiom 6. if-when-nil *)
(^por (^pnot (^pequal ^x ^nnil))
(^pequal (^iff [^x;^y;^z]) ^z));
(* Axiom 7. if-when-not-nil *)
(^por (^pequal ^x ^nnil)
(^pequal (^iff [^x;^y;^z]) ^y));
(* Axiom 8. consp-of-cons *)
(^pequal (^consp [^ccons [^x;^y]]) ^t);
(* Axiom 9. car-of-cons *)
(^pequal (^car [^ccons [^x;^y]]) ^x);
(* Axiom 10. cdr-of-cons *)
(^pequal (^cdr [^ccons [^x;^y]]) ^y);
(* Axiom 11. consp-nil-or-t *)
(^por (^pequal (^consp [^x]) ^nnil)
(^pequal (^consp [^x]) ^t));
(* Axiom 12. car-when-not-consp *)
(^por (^pnot (^pequal (^consp [^x]) ^nnil))
(^pequal (^car [^x]) ^nnil));
(* Axiom 13. cdr-when-not-consp *)
(^por (^pnot (^pequal (^consp [^x]) ^nnil))
(^pequal (^cdr [^x]) ^nnil));
(* Axiom 14. cons-of-car-and-cdr *)
(^por (^pequal (^consp [^x]) ^nnil)
(^pequal (^ccons [^car [^x]; ^cdr [^x]]) ^x));
(* Axiom 15. symbolp-nil-or-t *)
(^por (^pequal (^symbolp [^x]) ^nnil)
(^pequal (^symbolp [^x]) ^t));
(* Axiom 16. symbol-<-nil-or-t *)
(^por (^pequal (^symbol_less [^x;^y]) ^nnil)
(^pequal (^symbol_less [^x;^y]) ^t));
(* Axiom 17. irreflexivity-of-symbol-< *)
(^pequal (^symbol_less [^x;^x]) ^nnil);
(* Axiom 18. antisymmetry-of-symbol-< *)
(^por (^pequal (^symbol_less [^x;^y]) ^nnil)
(^pequal (^symbol_less [^y;^x]) ^nnil));
(* Axiom 19. transitivity-of-symbol-< *)
(^por (^pequal (^symbol_less [^x;^y]) ^nnil)
(^por (^pequal (^symbol_less [^y;^z]) ^nnil)
(^pequal (^symbol_less [^x;^z]) ^t)));
(* Axiom 20. trichotomy-of-symbol-< *)
(^por (^pequal (^symbolp [^x]) ^nnil)
(^por (^pequal (^symbolp [^y]) ^nnil)
(^por (^pequal (^symbol_less [^x;^y]) ^t)
(^por (^pequal (^symbol_less [^y;^x]) ^t)
(^pequal ^x ^y)))));
(* Axiom 21. symbol-<-completion-left *)
(^por (^pequal (^symbolp [^x]) ^t)
(^pequal (^symbol_less [^x;^y]) (^symbol_less [^nnil;^y])));
(* Axiom 22. symbol-<-completion-right *)
(^por (^pequal (^symbolp [^y]) ^t)
(^pequal (^symbol_less [^x;^y]) (^symbol_less [^x;^nnil])));
(* Axiom 23. disjoint-symbols-and-naturals *)
(^por (^pequal (^symbolp [^x]) ^nnil)
(^pequal (^natp [^x]) ^nnil));
(* Axiom 24. disjoint-symbols-and-conses *)
(^por (^pequal (^symbolp [^x]) ^nnil)
(^pequal (^consp [^x]) ^nnil));
(* Axiom 25. disjoint-naturals-and-conses *)
(^por (^pequal (^natp [^x]) ^nnil)
(^pequal (^consp [^x]) ^nnil));
(* Axiom 26. natp-nil-or-t *)
(^por (^pequal (^natp [^x]) ^nnil)
(^pequal (^natp [^x]) ^t));
(* Axiom 27. natp-of-plus *)
(^pequal (^natp [^add [^a;^b]]) ^t);
(* Axiom 28. commutativity-of-+ *)
(^pequal (^add [^a;^b]) (^add [^b;^a]));
(* Axiom 29. associativity-of-+ *)
(^pequal (^add [^add [^a;^b];^c])
(^add [^a;^add [^b;^c]]));
(* Axiom 30. plus-when-not-natp-left *)
(^por (^pequal (^natp [^a]) ^t)
(^pequal (^add [^a;^b]) (^add [^zero;^b])));
(* Axiom 31. plus-of-zero-when-natural *)
(^por (^pequal (^natp [^a]) ^nnil)
(^pequal (^add [^a;^zero]) ^a));
(* Axiom 32. <-nil-or-t *)
(^por (^pequal (^less [^x;^y]) ^nnil)
(^pequal (^less [^x;^y]) ^t));
(* Axiom 33. irreflexivity-of-< *)
(^pequal (^less [^a;^a]) ^nnil);
(* Axiom 34. less-of-zero-right *)
(^pequal (^less [^a;^zero]) ^nnil);
(* Axiom 35. less-of-zero-left-when-natp *)
(^por (^pequal (^natp [^a]) ^nnil)
(^pequal (^less [^zero;^a]) (^iff [^eequal [^a;^zero];^nnil;^t])));
(* Axiom 36. less-completion-left *)
(^por (^pequal (^natp [^a]) ^t)
(^pequal (^less [^a;^b]) (^less [^zero;^b])));
(* Axiom 37. less-completion-right *)
(^por (^pequal (^natp [^b]) ^t)
(^pequal (^less [^a;^b]) ^nnil));
(* Axiom 38. transitivity-of-< *)
(^por (^pequal (^less [^a;^b]) ^nnil)
(^por (^pequal (^less [^b;^c]) ^nnil)
(^pequal (^less [^a;^c]) ^t)));
(* Axiom 39. trichotomy-of-<-when-natp *)
(^por (^pequal (^natp [^a]) ^nnil)
(^por (^pequal (^natp [^b]) ^nnil)
(^por (^pequal (^less [^a;^b]) ^t)
(^por (^pequal (^less [^b;^a]) ^t)
(^pequal ^a ^b)))));
(* Axiom 40. one-plus-trick *)
(^por (^pequal (^less [^a;^b]) ^nnil)
(^pequal (^less [^b;^add [^one;^a]]) ^nnil));
(* Axiom 41. natural-less-than-one-is-zero *)
(^por (^pequal (^natp [^a]) ^nnil)
(^por (^pequal (^less [^a;^one]) ^nnil)
(^pequal ^a ^zero)));
(* Axiom 42. less-than-of-plus-and-plus *)
(^pequal (^less [^add [^a;^b];^add [^a;^c]]) (^less [^b;^c]));
(* Axiom 43. natp-of-minus *)
(^pequal (^natp [^sub [^a;^b]]) ^t);
(* Axiom 44. minus-when-subtrahend-as-large *)
(^por (^pequal (^less [^b;^a]) ^t)
(^pequal (^sub [^a;^b]) ^zero));
(* Axiom 45. minus-cancels-summand-right *)
(^pequal (^sub [^add [^a;^b];^b])
(^iff [^natp [^a];^a;^zero]));
(* Axiom 46. less-of-minus-left *)
(^por (^pequal (^less [^b;^a]) ^nnil)
(^pequal (^less [^sub [^a;^b];^c])
(^less [^a;^add [^b;^c]])));
(* Axiom 47. less-of-minus-right *)
(^pequal (^less [^a;^sub [^b;^c]])
(^less [^add [^a;^c];^b]));
(* Axiom 48. plus-of-minus-right *)
(^por (^pequal (^less [^c;^b]) ^nnil)
(^pequal (^add [^a;^sub [^b;^c]])
(^sub [^add [^a;^b];^c])));
(* Axiom 49. minus-of-minus-right *)
(^por (^pequal (^less [^c;^b]) ^nnil)
(^pequal (^sub [^a;^sub [^b;^c]])
(^sub [^add [^a;^c];^b])));
(* Axiom 50. minus-of-minus-left *)
(^pequal (^sub [^sub [^a;^b];^c])
(^sub [^a;^add [^b;^c]]));
(* Axiom 51. equal-of-minus-property *)
(^por (^pequal (^less [^b;^a]) ^nnil)
(^pequal (^eequal [^sub [^a;^b];^c])
(^eequal [^a;^add [^b;^c]])));
(* Axiom 52. closed-universe *)
(^por (^pequal (^natp [^x]) ^t)
(^por (^pequal (^symbolp [^x]) ^t)
(^pequal (^consp [^x]) ^t)));
(* Axiom 53. definition-of-not *)
(^pequal (^nnot [^x]) (^iff [^x;^nnil;^t]));
(* Axiom 54. definition-of-rank *)
(^pequal (^rank [^x])
(^iff [^consp [^x];
^add [^one;^add [^rank [^car [^x]]; ^rank [^cdr [^x]]]];
^zero]));
(* Axiom 55. definition-of-ord< *)
(^pequal (^ord_lt [^x;^y])
(^iff [^nnot [^consp [^x]];
^iff [^consp [^y]; ^t; (^less [^x;^y])];
(^iff [^nnot [^consp [^y]];
^nnil;
(^iff [^nnot [^eequal [^car [^car [^x]]; ^car [^car [^y]]]];
^ord_lt [^car [^car [^x]]; ^car [^car [^y]]];
(^iff [^nnot [^eequal [^cdr [^car [^x]]; ^cdr [^car [^y]]]];
^less [^cdr [^car [^x]]; ^cdr [^car [^y]]];
(^iff [^t;^ord_lt [^cdr [^x];^cdr [^y]];^nnil])])])])]));
(* Axiom 56. definition-of-ordp *)
(^pequal (^ordp [^x])
(^iff [^nnot [^consp [^x]];
^natp [^x];
(^iff [^consp [^car [^x]];
(^iff [^ordp [^car [^car [^x]]];
(^iff [^nnot [^eequal [^car [^car [^x]]; ^zero]];
(^iff [^less [^zero; ^cdr [^car [^x]]];
(^iff [^ordp [^cdr [^x]];
(^iff [^consp [^cdr [^x]];
^ord_lt [^car [^car [^cdr [^x]]]; ^car [^car [^x]]];
^t]); ^nnil]); ^nnil]); ^nnil]); ^nnil]); ^nnil])]))]`;
(* --- Inference rules --- *)
val LOOKUP_def = Define `
(LOOKUP x [] r = r) /\
(LOOKUP x ((y,z)::ys) r = if x = y then z else LOOKUP x ys r)`;
val term_sub_def = tDefine "term_sub" `
(term_sub ss (mConst s) = mConst s) /\
(term_sub ss (mVar v) = LOOKUP v ss (mVar v)) /\
(term_sub ss (mApp fc vs) = mApp fc (MAP (term_sub ss) vs)) /\
(term_sub ss (mLamApp xs z ys) = mLamApp xs z (MAP (term_sub ss) ys))`
(WF_REL_TAC `measure (logic_term_size o SND)` \\ SRW_TAC [] []
THEN1 (Induct_on `vs` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
THEN1 (Induct_on `ys` \\ SRW_TAC [] [MEM,logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
\\ DECIDE_TAC);
val formula_sub_def = Define `
(formula_sub ss (Not x) = Not (formula_sub ss x)) /\
(formula_sub ss (Or x y) = Or (formula_sub ss x) (formula_sub ss y)) /\
(formula_sub ss (Equal t1 t2) = Equal (term_sub ss t1) (term_sub ss t2))`;
val or_not_equal_list_def = Define `
(or_not_equal_list [] x = x) /\
(or_not_equal_list ((t,s)::xs) x = Or (Not (Equal t s))
(or_not_equal_list xs x))`;
val or_list_def = Define `
(or_list [x] = x) /\
(or_list (x::y::xs) = Or x (or_list (y::xs)))`;
val (MilawaTrue_rules,MilawaTrue_ind,MilawaTrue_cases) = Hol_reln `
(* Associativity *)
(!a b c ctxt.
MilawaTrue ctxt (Or a (Or b c)) ==>
MilawaTrue ctxt (Or (Or a b) c))
/\
(* Contraction *)
(!a ctxt.
MilawaTrue ctxt (Or a a) ==>
MilawaTrue ctxt a)
/\
(* Cut *)
(!a b c ctxt.
MilawaTrue ctxt (Or a b) /\ MilawaTrue ctxt (Or (Not a) c) ==>
MilawaTrue ctxt (Or b c))
/\
(* Expansion *)
(!a b ctxt.
formula_ok ctxt a /\
MilawaTrue ctxt b ==>
MilawaTrue ctxt (Or a b))
/\
(* Propositional Schema *)
(!a ctxt.
formula_ok ctxt a ==>
MilawaTrue ctxt (Or (Not a) a))
/\
(* Functional Equality *)
(!f ts_list ctxt result.
(result = (or_not_equal_list ts_list (Equal (mApp f (MAP FST ts_list))
(mApp f (MAP SND ts_list))))) /\
formula_ok ctxt result ==>
MilawaTrue ctxt result)
/\
(* Instantiation *)
(!a ss ctxt.
formula_ok ctxt (formula_sub ss a) /\
MilawaTrue ctxt a ==>
MilawaTrue ctxt (formula_sub ss a))
/\
(* Beta-reduction *)
(!a xs ys ctxt.
formula_ok ctxt (Equal (mLamApp xs a ys) (term_sub (ZIP(xs,ys)) a)) ==>
MilawaTrue ctxt (Equal (mLamApp xs a ys) (term_sub (ZIP(xs,ys)) a)))
/\
(* Base evaluation *)
(!p args ctxt.
(primitive_arity p = LENGTH args) ==>
MilawaTrue ctxt (Equal (mApp (mPrimitiveFun p) (MAP mConst args))
(mConst (EVAL_PRIMITIVE p args))))
/\
(* Axioms *)
(!a ctxt.
MEM a MILAWA_AXIOMS ==>
MilawaTrue ctxt a)
/\
(* User definitions *)
(!f params body ctxt sem.
f IN FDOM ctxt /\ (ctxt ' f = (params,BODY_FUN body,sem)) ==>
MilawaTrue ctxt (Equal (mApp (mFun f) (MAP mVar params)) body))
/\
(* User witness function definitions *)
(!f params exp var_name witness ctxt.
f IN FDOM ctxt /\ (ctxt ' f = (params,WITNESS_FUN exp var_name,witness)) ==>
MilawaTrue ctxt (Or (Equal exp ^nnil)
(Not (Equal (mLamApp (var_name::params) exp
(mApp (mFun f) (MAP mVar params)::MAP mVar params))
^nnil))))
/\
(* Induction *)
(!f qs_ss m ctxt.
(* base case *)
MilawaTrue ctxt (or_list (f::MAP FST qs_ss)) /\
(* inductive step *)
(!q ss. MEM (q,ss) qs_ss ==>
MilawaTrue ctxt (or_list (f::Not q::MAP (\s. Not (formula_sub s f)) ss))) /\
(* ordinal step *)
MilawaTrue ctxt (Equal (^ordp [m]) (mConst (Sym "T"))) /\
(* measure step *)
(!q ss s. MEM (q,ss) qs_ss /\ MEM s ss ==>
MilawaTrue ctxt (Or (Not q)
(Equal (^ord_less [term_sub s m;m])
(mConst (Sym "T")))))
==>
MilawaTrue ctxt f)`;
(* Next we prove a sanity result: MilawaTrue can only derive
syntactically valid formulas. *)
val MilawaAxiom_IMP_formula_ok = prove(
``!x ctxt. MEM x MILAWA_AXIOMS ==> formula_ok ctxt x``,
SIMP_TAC std_ss [MILAWA_AXIOMS_def,MEM] \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [formula_ok_def,term_ok_def,
func_arity_def,LENGTH,EVERY_DEF,primitive_arity_def]);
val PULL_FORALL_IMP = METIS_PROVE [] ``(p ==> !x. q x) = !x. p ==> q x``;
val term_ok_sub = store_thm("term_ok_sub",
``!a ss ctxt.
term_ok ctxt a /\ EVERY (term_ok ctxt) (MAP SND ss) ==>
term_ok ctxt (term_sub ss a)``,
completeInduct_on `logic_term_size a` \\ FULL_SIMP_TAC std_ss [PULL_FORALL_IMP]
\\ REPEAT STRIP_TAC \\ FULL_SIMP_TAC std_ss [] \\ Cases_on `a`
THEN1 (FULL_SIMP_TAC std_ss [term_ok_def,term_sub_def,LENGTH_MAP])
THEN1 (FULL_SIMP_TAC std_ss [term_ok_def,term_sub_def,LENGTH_MAP]
\\ Induct_on `ss` \\ SIMP_TAC std_ss [EVERY_DEF,LOOKUP_def,term_ok_def]
\\ Cases_on `h` \\ SIMP_TAC std_ss [EVERY_DEF,LOOKUP_def,term_ok_def]
\\ SRW_TAC [] [])
THEN1
(FULL_SIMP_TAC std_ss [term_ok_def,term_sub_def,LENGTH_MAP,logic_term_size_def]
\\ SIMP_TAC std_ss [EVERY_MEM,MEM_MAP] \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [AND_IMP_INTRO]
\\ Q.PAT_X_ASSUM `!a.bbb` MATCH_MP_TAC \\ FULL_SIMP_TAC std_ss []
\\ FULL_SIMP_TAC std_ss [EVERY_MEM]
\\ POP_ASSUM MP_TAC
\\ REPEAT (POP_ASSUM (K ALL_TAC))
\\ Induct_on `l` \\ SRW_TAC [] [logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC)
\\ FULL_SIMP_TAC std_ss [term_ok_def,term_sub_def,LENGTH_MAP]
\\ SIMP_TAC std_ss [EVERY_MEM,MEM_MAP] \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [AND_IMP_INTRO]
\\ Q.PAT_X_ASSUM `!a.bbb` MATCH_MP_TAC \\ FULL_SIMP_TAC std_ss []
\\ FULL_SIMP_TAC std_ss [EVERY_MEM,logic_term_size_def]
\\ POP_ASSUM MP_TAC \\ REPEAT (POP_ASSUM (K ALL_TAC))
\\ Induct_on `l0` \\ SRW_TAC [] [logic_term_size_def] \\ RES_TAC \\ DECIDE_TAC);
val formula_ok_sub = prove(
``!a ss ctxt.
formula_ok ctxt a /\ EVERY (term_ok ctxt) (MAP SND ss) ==>
formula_ok ctxt (formula_sub ss a)``,
Induct \\ FULL_SIMP_TAC std_ss [formula_ok_def,formula_sub_def,term_ok_sub]);
val MAP_FST_ZIP = prove(
``!xs ys. (LENGTH xs = LENGTH ys) ==> (MAP FST (ZIP (xs,ys)) = xs)``,
Induct \\ Cases_on `ys` \\ FULL_SIMP_TAC std_ss [LENGTH,ADD1,ZIP,MAP]);
val MAP_SND_ZIP = prove(
``!xs ys. (LENGTH xs = LENGTH ys) ==> (MAP SND (ZIP (xs,ys)) = ys)``,
Induct \\ Cases_on `ys` \\ FULL_SIMP_TAC std_ss [LENGTH,ADD1,ZIP,MAP]);
val MilawaTrue_IMP_formula_ok = store_thm("MilawaTrue_IMP_formula_ok",
``!ctxt x. MilawaTrue ctxt x ==> context_ok ctxt ==> formula_ok ctxt x``,
HO_MATCH_MP_TAC MilawaTrue_ind \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [formula_ok_def,term_ok_def,
func_arity_def,LENGTH,EVERY_DEF,primitive_arity_def,
MilawaAxiom_IMP_formula_ok,LENGTH_MAP]
\\ FULL_SIMP_TAC std_ss [EVERY_MEM,MEM_MAP]
\\ REPEAT STRIP_TAC \\ FULL_SIMP_TAC std_ss [term_ok_def]
\\ TRY (Cases_on `qs_ss` \\ FULL_SIMP_TAC std_ss [formula_ok_def,or_list_def,MAP] \\ NO_TAC)
\\ FULL_SIMP_TAC std_ss [context_ok_def] \\ RES_TAC);
(* PART 4: Proof of soundness of the inference rules *)
val EvalTerm_Const_Var = prove(
``(EvalTerm (a,ctxt) (mConst x) = x) /\
(EvalTerm (a,ctxt) (mVar v) = a v)``,
SIMP_TAC std_ss [EvalTerm_def]);
val MOVE_EXISTS = METIS_PROVE []
``(?x. P x) /\ Q = ?x. P x /\ Q``
val EvalTerm_Primtives1 = prove(
``(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_NATP) [x]) =
LISP_NUMBERP (EvalTerm (a,ctxt) x)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_SYMBOLP) [x]) =
LISP_SYMBOLP (EvalTerm (a,ctxt) x)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_CONSP) [x]) =
LISP_CONSP (EvalTerm (a,ctxt) x)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_CAR) [x]) =
CAR (EvalTerm (a,ctxt) x)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_CDR) [x]) =
CDR (EvalTerm (a,ctxt) x)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_ORDP) [x]) =
LISP_TEST (ORDP (EvalTerm (a,ctxt) x))) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_NOT) [x]) =
LISP_TEST ((EvalTerm (a,ctxt) x) = Sym "NIL")) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_RANK) [x]) =
Val (LSIZE (EvalTerm (a,ctxt) x)))``,
SIMP_TAC (srw_ss()) [EvalApp_def,EVAL_PRIMITIVE_def,EvalTerm_def]);
val EvalTerm_Primtives2 = prove(
``(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_CONS) [x;y]) =
LISP_CONS (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_EQUAL) [x;y]) =
LISP_EQUAL (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_LESS) [x;y]) =
LISP_LESS (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_SYMBOL_LESS) [x;y]) =
LISP_SYMBOL_LESS (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_ADD) [x;y]) =
LISP_ADD (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_SUB) [x;y]) =
LISP_SUB (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)) /\
(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_ORD_LESS) [x;y]) =
LISP_TEST (ORD_LT (EvalTerm (a,ctxt) x) (EvalTerm (a,ctxt) y)))``,
SIMP_TAC (srw_ss()) [EvalApp_def,EVAL_PRIMITIVE_def,EvalTerm_def]);
val EvalTerm_IF = prove(
``(EvalTerm (a,ctxt) (mApp (mPrimitiveFun logic_IF) [x;y;z]) =
if EvalTerm (a,ctxt) x = Sym "NIL" then
EvalTerm (a,ctxt) z else EvalTerm (a,ctxt) y)``,
SIMP_TAC (srw_ss()) [EvalApp_def,EVAL_PRIMITIVE_def,EvalTerm_def,LISP_IF_def]
\\ METIS_TAC [isTrue_def]);
val EvalTerm_CLAUSES = LIST_CONJ [EvalTerm_Primtives1,
EvalTerm_Primtives2,EvalTerm_Const_Var,EvalTerm_IF]
val IF_T = prove(
``(((if b then Sym "T" else Sym "NIL") = Sym "T") = b) /\
(((if b then Sym "NIL" else Sym "T") = Sym "T") = ~b) /\
(((if b then Sym "NIL" else Sym "T") = Sym "NIL") = b) /\
(((if b then Sym "T" else Sym "NIL") = Sym "NIL") = ~b) /\
(((if b then Sym "T" else Sym "NIL") = (if b2 then Sym "T" else Sym "NIL")) = (b = b2))``,
Cases_on `b` \\ Cases_on `b2` \\ EVAL_TAC);
val axioms_ss = rewrites [MilawaValid_def,formula_ok_def,EvalFormula_def,IF_T,
term_ok_def,func_arity_def,primitive_arity_def,LENGTH,EVERY_DEF,EvalTerm_CLAUSES,
DECIDE ``0<n = ~(n=0:num)``]
val NOT_T_NIL = EVAL ``Sym "T" = Sym "NIL"``
val lemmas = [string_lt_nonrefl,string_lt_antisym,string_lt_trans,string_lt_cases]
val MilawaAxiom_IMP_MilawaValid = prove(
``!ctxt x. MEM x MILAWA_AXIOMS ==> context_ok ctxt ==> MilawaValid ctxt x``,
REWRITE_TAC [MILAWA_AXIOMS_def,MEM] \\ REPEAT STRIP_TAC
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ METIS_TAC [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ METIS_TAC [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC \\ METIS_TAC [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ Cases_on `a "Y"` \\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ Cases_on `a "Y"` \\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ Cases_on `a "Y"` \\ EVAL_TAC \\ METIS_TAC (lemmas))
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC \\ METIS_TAC [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ Cases_on `a "C"` \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC \\ EVAL_TAC
\\ FULL_SIMP_TAC (std_ss++axioms_ss) []
\\ Cases_on `a "A"` \\ Cases_on `a "B"` \\ Cases_on `a "C"` \\ EVAL_TAC
\\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) []
\\ REPEAT STRIP_TAC \\ Cases_on `a "X"` \\ EVAL_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) []
\\ EVAL_TAC \\ SIMP_TAC std_ss [])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ Cases_on `a "X"` \\ EVAL_TAC \\ DECIDE_TAC)
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ SIMP_TAC std_ss [Once ORD_LT_def]
\\ FULL_SIMP_TAC std_ss [LISP_TEST_def,LISP_CONSP_def,LISP_EQUAL_def,LISP_LESS_def]
\\ Cases_on `isDot (a "X")` \\ FULL_SIMP_TAC std_ss []
\\ Cases_on `isDot (a "Y")` \\ FULL_SIMP_TAC std_ss []
\\ Cases_on `CDR (CAR (a "X")) = CDR (CAR (a "Y"))`
\\ FULL_SIMP_TAC std_ss [NOT_T_NIL]
\\ Cases_on `CAR (CAR (a "X")) = CAR (CAR (a "Y"))`
\\ FULL_SIMP_TAC std_ss [NOT_T_NIL])
THEN1 (FULL_SIMP_TAC (std_ss++axioms_ss) [] \\ REPEAT STRIP_TAC
\\ SIMP_TAC std_ss [Once ORDP_def]
\\ FULL_SIMP_TAC std_ss [LISP_TEST_def,LISP_CONSP_def,LISP_EQUAL_def,LISP_LESS_def,LISP_NUMBERP_def]
\\ Cases_on `isDot (a "X")` \\ FULL_SIMP_TAC std_ss []
\\ Cases_on `isDot (CAR (a "X"))` \\ FULL_SIMP_TAC std_ss []
\\ Cases_on `isDot (CAR (a "X"))` \\ FULL_SIMP_TAC std_ss [NOT_T_NIL]
\\ Cases_on `ORDP (CAR (CAR (a "X")))`
\\ FULL_SIMP_TAC std_ss [NOT_T_NIL,getVal_def]
\\ Cases_on `CAR (CAR (a "X")) = Val 0` \\ FULL_SIMP_TAC std_ss [NOT_T_NIL]
\\ Cases_on `0 < getVal (CDR (CAR (a "X")))` \\ FULL_SIMP_TAC std_ss [NOT_T_NIL]
\\ Cases_on `ORDP (CDR (a "X"))` \\ FULL_SIMP_TAC std_ss [NOT_T_NIL]
\\ Cases_on `isDot (CDR (a "X"))` \\ FULL_SIMP_TAC std_ss [NOT_T_NIL]));
val Milawa_SOUNDESS_LEMMA = prove(
``!xs. ((2 = LENGTH xs) = ?x1 x2. xs = [x1;x2]) /\
((1 = LENGTH xs) = ?x1. xs = [x1])``,
Cases \\ SIMP_TAC (srw_ss()) [LENGTH,ADD1]
\\ Cases_on `t` \\ SIMP_TAC (srw_ss()) [LENGTH,ADD1]
\\ Cases_on `t'` \\ SIMP_TAC (srw_ss()) [LENGTH,ADD1] \\ DECIDE_TAC)
val NOT_MEM_LOOKUP = prove(
``!ss s x. ~(MEM s (MAP FST ss)) ==> (LOOKUP s ss x = x)``,
Induct \\ SIMP_TAC std_ss [LOOKUP_def] \\ Cases
\\ ASM_SIMP_TAC std_ss [LOOKUP_def,MAP,MEM]);
val MEM_MAP_FST = prove(
``!ss. MEM s (MAP FST ss) ==>
?ys t zs. (ss = ys ++ (s,t)::zs) /\ ~(MEM s (MAP FST ys))``,
Induct \\ SIMP_TAC std_ss [MEM,MAP] \\ STRIP_TAC
\\ Cases_on `s = FST h` \\ FULL_SIMP_TAC std_ss [] THEN1
(Q.LIST_EXISTS_TAC [`[]`,`SND h`,`ss`]
\\ EVAL_TAC \\ Cases_on `h` \\ FULL_SIMP_TAC std_ss [])
\\ REPEAT STRIP_TAC \\ RES_TAC
\\ FULL_SIMP_TAC std_ss [] \\ Q.EXISTS_TAC `h::ys'`
\\ FULL_SIMP_TAC std_ss [APPEND,MEM,MAP] \\ METIS_TAC []);
val FunVarBindAux_def = Define `
(FunVarBindAux [] args d = d) /\
(FunVarBindAux (p::ps) [] d = (p =+ Sym "NIL") (FunVarBindAux ps [] d)) /\
(FunVarBindAux (p::ps) (a::as) d = (p =+ a) (FunVarBindAux ps as d))`;
val FunVarBindAux_APPEND = prove(
``!ys f xs qs d.
~(MEM a (MAP FST ys)) ==>
(FunVarBindAux (MAP FST ys ++ xs) (MAP f ys ++ qs) d a = FunVarBindAux xs qs d a) /\
(LOOKUP a (ys ++ ts) c = LOOKUP a ts c)``,
Induct \\ FULL_SIMP_TAC std_ss [APPEND,MAP,FunVarBindAux_def,
APPLY_UPDATE_THM,MEM,LOOKUP_def] \\ Cases \\ FULL_SIMP_TAC std_ss [LOOKUP_def]);
val EVERY_TERM_ok_sub = prove(
``!xs ctxt ss.
EVERY (term_ok ctxt) xs /\ EVERY (term_ok ctxt) (MAP SND ss) ==>
EVERY (term_ok ctxt) (MAP (\a. term_sub ss a) xs)``,
Induct \\ ASM_SIMP_TAC std_ss [EVERY_DEF,MAP] \\ REPEAT STRIP_TAC
\\ MATCH_MP_TAC term_ok_sub \\ ASM_SIMP_TAC std_ss []);
val MAP_EQ_EQ = prove(
``!xs ys f.
(MAP f xs = ys) = (LENGTH xs = LENGTH ys) /\
(!x y. MEM (x,y) (ZIP(xs,ys)) ==> (f x = y))``,
Induct \\ Cases_on `ys` \\ SIMP_TAC (srw_ss()) [LENGTH,ADD1] \\ METIS_TAC []);
val MEM_logic_term_size_alt = prove(
``!xs x. MEM x xs /\ EVERY (term_ok ctxt) xs ==>
logic_term_size x < logic_term1_size xs /\ term_ok ctxt x``,
Induct \\ SIMP_TAC std_ss [MEM] \\ NTAC 2 STRIP_TAC
\\ Cases_on `x = h` \\ FULL_SIMP_TAC std_ss [EVERY_DEF,logic_term_size_def]
\\ REPEAT STRIP_TAC THEN1 DECIDE_TAC \\ RES_TAC \\ DECIDE_TAC);
val MEM_ZIP = prove(
``!xs ys. (LENGTH xs = LENGTH ys) /\ MEM (x,y) (ZIP (xs,ys)) ==> MEM x xs``,
Induct \\ Cases_on `ys` \\ SIMP_TAC std_ss [LENGTH,ADD1,ZIP,MEM] \\ METIS_TAC []);
val IMP_IMP = METIS_PROVE [] ``b1 /\ (b2 ==> b3) ==> ((b1 ==> b2) ==> b3)``;
val IMP_MAP_EQ_MAP = prove(
``!xs. (!x. MEM x xs ==> (f x = g x)) ==> (MAP f xs = MAP g xs)``,
Induct \\ FULL_SIMP_TAC std_ss [MAP,MEM]);
val EvalTerm_sub = prove(
``!x a ss.
EvalTerm (a,ctxt) (term_sub ss x) =
EvalTerm (FunVarBindAux (MAP FST ss) (MAP (EvalTerm (a,ctxt) o SND) ss) a,ctxt) x``,
completeInduct_on `logic_term_size x`
\\ FULL_SIMP_TAC std_ss [PULL_FORALL_IMP] \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [] \\ Cases_on `x`
THEN1 (SIMP_TAC std_ss [EvalTerm_def,term_sub_def])
THEN1
(SIMP_TAC std_ss [EvalTerm_def,term_sub_def]
\\ REVERSE (Cases_on `MEM s (MAP FST ss)`) THEN1
(ASM_SIMP_TAC std_ss [NOT_MEM_LOOKUP,EvalTerm_def]
\\ POP_ASSUM MP_TAC \\ Q.SPEC_TAC (`ss`,`xs`)
\\ Induct \\ FULL_SIMP_TAC std_ss [MAP,FunVarBindAux_def,MEM]
\\ FULL_SIMP_TAC std_ss [APPLY_UPDATE_THM])
\\ IMP_RES_TAC MEM_MAP_FST
\\ FULL_SIMP_TAC std_ss [MAP_APPEND,MAP,FunVarBindAux_APPEND]
\\ FULL_SIMP_TAC std_ss [FunVarBindAux_def,APPLY_UPDATE_THM,LOOKUP_def])
THEN1
(SIMP_TAC std_ss [EvalTerm_def,term_sub_def,LENGTH_MAP]
\\ AP_TERM_TAC \\ AP_TERM_TAC \\ AP_THM_TAC \\ AP_TERM_TAC
\\ FULL_SIMP_TAC std_ss [MAP_MAP_o,combinTheory.o_DEF]
\\ MATCH_MP_TAC IMP_MAP_EQ_MAP \\ SIMP_TAC std_ss [] \\ REPEAT STRIP_TAC
\\ FULL_SIMP_TAC std_ss [AND_IMP_INTRO]
\\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ FULL_SIMP_TAC std_ss [term_ok_def,EVERY_MEM,logic_term_size_def]
\\ FULL_SIMP_TAC std_ss [GSYM EVERY_MEM]
\\ IMP_RES_TAC MEM_IMP_logic_term_size \\ DECIDE_TAC)
\\ FULL_SIMP_TAC std_ss [EvalTerm_def,term_sub_def,LET_DEF,term_ok_def]
\\ FULL_SIMP_TAC std_ss [MAP_MAP_o,combinTheory.o_DEF]
\\ AP_THM_TAC \\ AP_TERM_TAC \\ AP_THM_TAC \\ AP_TERM_TAC \\ AP_TERM_TAC
\\ MATCH_MP_TAC IMP_MAP_EQ_MAP \\ SIMP_TAC std_ss [] \\ REPEAT STRIP_TAC
\\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ FULL_SIMP_TAC std_ss [term_ok_def,EVERY_MEM,logic_term_size_def]
\\ IMP_RES_TAC MEM_IMP_logic_term_size \\ DECIDE_TAC);
val PULL_EXISTS_IMP = METIS_PROVE [] ``((?x. P x) ==> b) = !x. P x ==> b``
val MEM_logic_term_size_alt_alt = prove(
``!xs x. MEM x xs ==> logic_term_size x < logic_term1_size xs``,
Induct \\ FULL_SIMP_TAC std_ss [MEM,logic_term_size_def]
\\ REPEAT STRIP_TAC \\ FULL_SIMP_TAC std_ss [] \\ RES_TAC \\ DECIDE_TAC);
val EvalFormula_sub = prove(
``!x a ss.
EvalFormula (a,ctxt) (formula_sub ss x) =
EvalFormula (FunVarBindAux (MAP FST ss) (MAP (EvalTerm (a,ctxt) o SND) ss) a,ctxt) x``,
Induct \\ FULL_SIMP_TAC std_ss [EvalFormula_def,formula_sub_def,
formula_ok_def,EvalTerm_sub]);
val LENGTH_EQ_3 = prove(
``((LENGTH args = 3) = ?x1 x2 x3. args = [x1;x2;x3]) /\
((3 = LENGTH args) = ?x1 x2 x3. args = [x1;x2;x3])``,
Cases_on `args` \\ FULL_SIMP_TAC (srw_ss()) [LENGTH]
\\ Cases_on `t` \\ FULL_SIMP_TAC (srw_ss()) [LENGTH]
\\ Cases_on `t'` \\ FULL_SIMP_TAC (srw_ss()) [LENGTH]
\\ Cases_on `t` \\ FULL_SIMP_TAC (srw_ss()) [LENGTH] \\ DECIDE_TAC);
val EvalTerm_CHANGE_INST = prove(
``!a ctxt body.
(\(a,ctxt) body. !b.
(!x. MEM x (free_vars body) ==> (a x = b x)) ==>
(EvalTerm (a,ctxt) body = EvalTerm (b,ctxt) body)) (a,ctxt) body``,
HO_MATCH_MP_TAC (fetch "-" "EvalTerm_ind")
\\ SIMP_TAC std_ss [EvalTerm_def,free_vars_def,MEM]
\\ REVERSE (REPEAT STRIP_TAC) THEN1
(SIMP_TAC std_ss [LET_DEF]
\\ AP_THM_TAC \\ AP_TERM_TAC \\ AP_THM_TAC \\ AP_TERM_TAC \\ AP_TERM_TAC
\\ MATCH_MP_TAC IMP_MAP_EQ_MAP \\ SIMP_TAC std_ss [] \\ REPEAT STRIP_TAC
\\ RES_TAC \\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ REPEAT STRIP_TAC \\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ FULL_SIMP_TAC std_ss [MEM_FLAT]
\\ Q.EXISTS_TAC `free_vars x'` \\ ASM_SIMP_TAC std_ss [MEM_MAP] \\ METIS_TAC [])
\\ AP_TERM_TAC \\ AP_TERM_TAC \\ AP_THM_TAC \\ AP_TERM_TAC
\\ MATCH_MP_TAC IMP_MAP_EQ_MAP \\ SIMP_TAC std_ss [] \\ REPEAT STRIP_TAC
\\ RES_TAC \\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ REPEAT STRIP_TAC \\ Q.PAT_X_ASSUM `!x.bbb` MATCH_MP_TAC
\\ FULL_SIMP_TAC std_ss [MEM_FLAT] \\ METIS_TAC [MEM_MAP]) |> SIMP_RULE std_ss [];
val EL_LEMMA = CONJ (EVAL ``EL 0 (x::xs)``) (EVAL ``EL 1 (x::y::xs)``)
val formula_ok_or_not_equal_list = prove(
``!ts_list x.
formula_ok ctxt (or_not_equal_list ts_list x) =
EVERY (\(t,s). term_ok ctxt t /\ term_ok ctxt s) ts_list /\ formula_ok ctxt x``,
Induct \\ SIMP_TAC std_ss [or_not_equal_list_def,EVERY_DEF] \\ Cases
\\ ASM_SIMP_TAC std_ss [or_not_equal_list_def,EVERY_DEF,formula_ok_def] \\ METIS_TAC []);
val EvalFormula_or_not_equal_list = prove(
``!ts_list x.
EvalFormula (a,ctxt) (or_not_equal_list ts_list x) =
(EVERY (\(t,s). EvalTerm (a,ctxt) t = EvalTerm (a,ctxt) s) ts_list ==>
EvalFormula (a,ctxt) x)``,
Induct \\ SIMP_TAC std_ss [or_not_equal_list_def,EVERY_DEF] \\ Cases
\\ ASM_SIMP_TAC std_ss [or_not_equal_list_def,EVERY_DEF,formula_ok_def,
EvalFormula_def] \\ METIS_TAC []);
val or_list_EXPAND = prove(
``~(xs = []) ==> (or_list (x::xs) = Or x (or_list xs))``,
Cases_on `xs` \\ SIMP_TAC std_ss [or_list_def] \\ METIS_TAC []);