-
Notifications
You must be signed in to change notification settings - Fork 290
/
Enemy.hx
282 lines (240 loc) · 6.92 KB
/
Enemy.hx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
package;
import flixel.FlxG;
import flixel.FlxSprite;
import flixel.effects.particles.FlxEmitter;
import flixel.group.FlxGroup.FlxTypedGroup;
import flixel.math.FlxPoint;
import flixel.math.FlxVelocity;
import flixel.system.FlxAssets;
import flixel.util.FlxSpriteUtil;
class Enemy extends FlxSprite implements IHurt
{
/**
* The player object
*/
var _player:Player;
/**
* A group of enemy bullet objects (Enemies shoot these out)
*/
var _bullets:FlxTypedGroup<EnemyBullet>;
/**
* A group of bits and pieces that explode when the Enemy dies.
*/
var _gibs:FlxEmitter;
/**
* We use this number to figure out how fast the ship is flying
*/
var _thrust:Float;
/**
* A special effect - little poofs shoot out the back of the ship
*/
var _jets:FlxEmitter;
// These are "timers" - numbers that count down until we want something interesting to happen.
/**
* Helps us decide when to fly and when to stop flying.
*/
var _timer:Float;
/**
* Helps us decide when to shoot.
*/
var _shotClock:Float;
/**
* This object isn't strictly necessary, and is only used with getMidpoint().
* By passing this object, we can avoid a potentially costly allocation of
* a FlxPoint.get() object by the getMidpoint() function.
*/
var _playerMidpoint:FlxPoint;
var _health:Int = 2;
/**
* This is the constructor for the enemy class. Because we are recycling
* enemies, we don't want our constructor to have any required parameters.
*/
public function new()
{
super();
#if flash
loadRotatedGraphic(AssetPaths.bot__png, 64, 0, false, false);
#else
loadGraphic(AssetPaths.bot__png);
#end
// We want the enemy's "hit box" or actual size to be
// smaller than the enemy graphic itself, just by a few pixels.
width = 12;
height = 12;
centerOffsets();
// Here we are setting up the jet particles
// that shoot out the back of the ship.
_jets = new FlxEmitter();
_jets.loadParticles(AssetPaths.jet__png, 15, 0, false);
// These parameters help control the ship's
// speed and direction during the update() loop.
maxAngular = 120;
angularDrag = 400;
drag.x = 35;
_thrust = 0;
_playerMidpoint = FlxPoint.get();
}
/**
* Each time an Enemy is recycled (in this game, by the Spawner object)
* we call init() on it afterward. That allows us to set critical parameters
* like references to the player object and the ship's new position.
*/
public function init(xPos:Int, yPos:Int, Bullets:FlxTypedGroup<EnemyBullet>, Gibs:FlxEmitter, ThePlayer:Player):Void
{
_player = ThePlayer;
_bullets = Bullets;
_gibs = Gibs;
reset(xPos - width / 2, yPos - height / 2);
angle = angleTowardPlayer();
// Enemies take 2 shots to kill
_health = 2;
_timer = 0;
_shotClock = 0;
}
/**
* Called by flixel to help clean up memory.
*/
override public function destroy():Void
{
super.destroy();
_player = null;
_bullets = null;
_gibs = null;
_jets.destroy();
_jets = null;
_playerMidpoint = null;
}
/**
* This is the main flixel update function or loop function.
* Most of the enemy's logic or behavior is in this function here.
*/
override public function update(elapsed:Float):Void
{
// Then, rotate toward that angle.
// We could rotate instantly toward the player by simply calling:
// angle = angleTowardPlayer();
// However, we want some less predictable, more wobbly behavior.
var da:Float = angleTowardPlayer();
if (da < angle)
angularAcceleration = -angularDrag;
else if (da > angle)
angularAcceleration = angularDrag;
else
angularAcceleration = 0;
// Figure out if we want the jets on or not.
_timer += elapsed;
if (_timer > 8)
_timer = 0;
var jetsOn:Bool = _timer < 6;
// Set the bot's movement speed and direction
// based on angle and whether the jets are on.
_thrust = FlxVelocity.computeVelocity(_thrust, (jetsOn ? 90 : 0), drag.x, 60, elapsed);
velocity.setPolarDegrees(_thrust, angle);
// Shooting - three shots every few seconds
if (isOnScreen())
{
var shoot:Bool = false;
var os:Float = _shotClock;
_shotClock += elapsed;
if ((os < 4.0) && (_shotClock >= 4.0))
{
_shotClock = 0;
shoot = true;
}
else if ((os < 3.5) && (_shotClock >= 3.5))
{
shoot = true;
}
else if ((os < 3.0) && (_shotClock >= 3.0))
{
shoot = true;
}
// If we rolled over one of those time thresholds,
// shoot a bullet out along the angle we're currently facing.
if (shoot)
{
// First, recycle a bullet from the bullet pile.
// If there are none, recycle will automatically create one for us.
var b:EnemyBullet = _bullets.recycle(EnemyBullet.new);
// Then, shoot it from our midpoint out along our angle.
b.shoot(getMidpoint(_point), angle);
}
}
// Then call FlxSprite's update() function, to automate
// our motion and animation and stuff.
super.update(elapsed);
// Finally, update the jet particles shooting out the back of the ship.
if (jetsOn)
{
if (!_jets.emitting)
{
// If they're supposed to be on and they're not,
// turn em on and play a little sound.
_jets.start(false, 0.01);
if (isOnScreen())
FlxG.sound.play(FlxAssets.getSound("assets/sounds/jet"));
}
// Then, position the jets at the center of the Enemy,
// and point the jets the opposite way from where we're moving.
_jets.focusOn(this);
_jets.launchAngle.set(angle - 180);
_jets.velocity.set(-velocity.x - 30, -velocity.y - 30, -velocity.x + 30, -velocity.y + 30);
}
// If jets are supposed to be off, just turn em off.
else
{
_jets.kill();
}
// Finally, update the jet emitter and all its member sprites.
_jets.update(elapsed);
}
/**
* Even though we updated the jets after we updated the Enemy,
* we want to draw the jets below the Enemy, so we call _jets.draw() first.
*/
override public function draw():Void
{
_jets.draw();
super.draw();
}
/**
* This function is called when player bullets hit the Enemy.
* The enemy is told to flicker, points are awarded to the player,
* and damage is dealt to the Enemy.
*
* @param damage The amount of damage to take
*/
public function hurt(damage:Int = 1):Void
{
FlxG.sound.play(FlxAssets.getSound("assets/sounds/hit"));
FlxSpriteUtil.flicker(this, 0.2, 0.02, true);
Reg.score += 10;
_health -= damage;
if (_health <= 0)
kill();
}
/**
* Called to kill the enemy. A cool sound is played, the jets
* are turned off, bits are exploded, and points are rewarded.
*/
override public function kill():Void
{
if (!alive)
return;
FlxG.sound.play(FlxAssets.getSound("assets/sounds/asplode"));
super.kill();
FlxSpriteUtil.flicker(this, 0, 0.02, true);
_jets.kill();
_gibs.focusOn(this);
_gibs.start(true, 0, 20);
Reg.score += 200;
}
/**
* A helper function that returns the angle between
* the Enemy's midpoint and the player's midpoint.
*/
function angleTowardPlayer():Float
{
return getMidpoint(_point).degreesTo(_player.getMidpoint(_playerMidpoint));
}
}