Revert some changes to accommodate minimum version

- Revert `FILE_SET` for `Vulkan::Headers`
- Guard `Vulkan::VulkanHppModule` behind version test

CMakeLists.txt

@@ -5,7 +5,7 @@
 #
 # SPDX-License-Identifier: Apache-2.0
 # ~~~
-cmake_minimum_required(VERSION 3.28 FATAL_ERROR)
+cmake_minimum_required(VERSION 3.15)
 
 # NOTE: Parsing the version like this is suboptimal but neccessary due to our release process:
 # https://github.com/KhronosGroup/Vulkan-Headers/pull/346
@@ -38,23 +38,26 @@ vlk_get_header_version()
 
 project(VULKAN_HEADERS LANGUAGES C VERSION ${VK_VERSION_STRING})
 
-add_library(Vulkan-Headers)
+add_library(Vulkan-Headers INTERFACE)
 add_library(Vulkan::Headers ALIAS Vulkan-Headers)
-target_sources(Vulkan-Headers
-    PUBLIC
-        FILE_SET headers TYPE HEADERS
-            BASE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include"
-)
-
-add_library(Vulkan-Module)
-add_library(Vulkan::VulkanHppModule ALIAS Vulkan-Module)
-target_sources(Vulkan-Module
-    PUBLIC
-        FILE_SET module CXX_MODULES
-            BASE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include"
-            FILES "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan.cppm"
-)
-target_compile_features(Vulkan-Module PUBLIC cxx_std_20)
+target_include_directories(Vulkan-Headers INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
+
+if (CMAKE_VERSION VERSION_GREATER_EQUAL "3.28")
+    add_library(Vulkan-Module)
+    add_library(Vulkan::VulkanHppModule ALIAS Vulkan-Module)
+    target_sources(Vulkan-Module
+        PUBLIC
+            FILE_SET module CXX_MODULES
+                BASE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include"
+                FILES "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan.cppm"
+    )
+    target_compile_features(Vulkan-Module PUBLIC cxx_std_20)
+endif ()
+
+if (CMAKE_VERSION VERSION_LESS "3.21")
+    # https://cmake.org/cmake/help/latest/variable/PROJECT_IS_TOP_LEVEL.html
+    string(COMPARE EQUAL ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} PROJECT_IS_TOP_LEVEL)
+endif()
 
 if (PROJECT_IS_TOP_LEVEL)
     option(BUILD_TESTS "Build the tests")
@@ -66,23 +69,23 @@ if (PROJECT_IS_TOP_LEVEL)
     include(GNUInstallDirs)
     include(CMakePackageConfigHelpers)
 
+    install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vk_video" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+    install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
     # Preserve source permissions https://github.com/KhronosGroup/Vulkan-Headers/issues/336
     install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/registry" DESTINATION "${CMAKE_INSTALL_DATADIR}/vulkan" USE_SOURCE_PERMISSIONS)
 
-    install(TARGETS Vulkan-Headers
-        EXPORT VulkanHeadersConfig
-        FILE_SET headers
-        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
-    )
-    install(TARGETS Vulkan-Module
-        EXPORT VulkanHeadersConfig
-        FILE_SET module
-        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/include/vulkan"
-    )
-    install(EXPORT VulkanHeadersConfig
-        NAMESPACE "Vulkan::"
-        DESTINATION "share/cmake/VulkanHeaders"
-    )
+    set_target_properties(Vulkan-Headers PROPERTIES EXPORT_NAME "Headers")
+    install(TARGETS Vulkan-Headers EXPORT VulkanHeadersConfig INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+
+    if (CMAKE_VERSION VERSION_GREATER_EQUAL "3.28")
+        install(TARGETS Vulkan-Module
+            EXPORT VulkanHeadersConfig
+            FILE_SET module
+            DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/include/vulkan"
+        )
+    endif()
+
+    install(EXPORT VulkanHeadersConfig NAMESPACE "Vulkan::" DESTINATION "share/cmake/VulkanHeaders")
 
     set(version_config "${CMAKE_CURRENT_BINARY_DIR}/generated/VulkanHeadersConfigVersion.cmake")
     write_basic_package_version_file("${version_config}" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)