firmware-qcom-sm8350-hdk: package proprietary firmware for SM8350-HDK

Package proprietary firmware for the SM8350 HDK (aka HDK888) board. By default
the empty package will be built. To specify the location for the
NHLOS.bin and/or propritary.tar.gz, add the following lines to the local.conf:

NHLOS_URI:pn-firmware-qcom-sm8350-hdk = "file:///PATH/NON-HLOS-sm8350-hdk-1.0.bin"
ADRENO_URI:pn-firmware-qcom-sm8350-hdk = "file:///PATH/proprietary-sm8350-hdk-1.1.tar.gz;striplevel=5;fwpath=vendor/firmware"

Signed-off-by: Dmitry Baryshkov <dmitry.baryshkov@linaro.org>

recipes-bsp/firmware/firmware-qcom-sm8350-hdk.bb

@@ -0,0 +1,42 @@
+# Provide base URI of NON-HLOS.bin file.  Use "file://" if those files are
+# provided locally.
+# Alernatively NHLOS_URI:pn-firmware-qcom-sm8350 = "..." can be added to the
+# local.conf file
+NHLOS_URI ?= ""
+
+DESCRIPTION = "QCOM Firmware for SM8350 HDK (aka HDK888) board"
+
+LICENSE = "CLOSED"
+
+FW_QCOM_NAME = "sm8350"
+
+require recipes-bsp/firmware/firmware-qcom.inc
+require recipes-bsp/firmware/firmware-qcom-nhlos.inc
+require recipes-bsp/firmware/firmware-qcom-adreno.inc
+
+do_install() {
+    if [ -n "${NHLOS_URI}" ] ; then
+        install -d ${D}${FW_QCOM_PATH}
+        for fw in adsp cdsp modem
+        do
+            install -m 0644 ${B}/$fw.mbn ${D}${FW_QCOM_PATH}
+        done
+        # No mba.mbn
+        #install -m 0644 ${B}/firmware/image/mba.mbn ${D}${FW_QCOM_PATH}
+        install -m 0644 ${B}/firmware/image/*.jsn ${D}${FW_QCOM_PATH}
+    fi
+    if [ -n "${ADRENO_URI}" ] ; then
+        for fw in a660_zap a615_zap
+        do
+            install -m 0644 ${B}/$fw.mbn ${D}${FW_QCOM_PATH}
+        done
+    fi
+}
+
+SPLIT_FIRMWARE_PACKAGES = "\
+    linux-firmware-qcom-${FW_QCOM_NAME}-audio \
+    linux-firmware-qcom-${FW_QCOM_NAME}-compute \
+    linux-firmware-qcom-${FW_QCOM_NAME}-modem \
+    linux-firmware-qcom-${FW_QCOM_NAME}-sensors \
+    linux-firmware-qcom-${FW_QCOM_NAME}-zap-shader \
+"

recipes-bsp/packagegroups/packagegroup-firmware-sm8350-hdk.bb

@@ -0,0 +1,16 @@
+SUMMARY = "Firmware packages for the SM8350-HDK (aka HDK888) board"
+
+inherit packagegroup
+
+RRECOMMENDS:${PN} += " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'linux-firmware-qcom-adreno-a660', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'linux-firmware-qca', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'wifi', 'linux-firmware-ath11k', '', d)} \
+    firmware-qcom-sm8350-hdk \
+    linux-firmware-qcom-sm8350-audio \
+    linux-firmware-qcom-sm8350-compute \
+    linux-firmware-qcom-sm8350-modem \
+    linux-firmware-qcom-sm8350-sensors \
+    linux-firmware-qcom-sm8350-zap-shader \
+    linux-firmware-qcom-vpu-2.0 \
+"