-
Notifications
You must be signed in to change notification settings - Fork 125
/
java.mouse
930 lines (765 loc) · 22.9 KB
/
java.mouse
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
//===========================================================================
//
// Parsing Expression Grammar for Java 1.5 in Mouse 1.1 format.
// Based on Chapters 3 and 18 of Java Language Specification, Third Edition (JLS)
// at http://java.sun.com/docs/books/jls/third_edition/html/j3TOC.html.
//
//---------------------------------------------------------------------------
//
// Copyright (C) 2006,2009 by Roman R Redziejowski (www.romanredz.se).
//
// The author gives unlimited permission to copy and distribute
// this file, with or without modifications, as long as this notice
// is preserved, and any changes are properly documented.
//
// This file is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
//
//---------------------------------------------------------------------------
//
// Change log
// 2006-12-06 Posted on Internet.
// 2009-04-04 Modified to conform to Mouse syntax:
// Underscore removed from names
// \f in Space replaced by Unicode for FormFeed.
// 2009-07-10 Unused rule THREADSAFE removed.
// 2009-07-10 Copying and distribution conditions relaxed by the author.
//
//===========================================================================
//-------------------------------------------------------------------------
// Compilation Unit
//-------------------------------------------------------------------------
CompilationUnit
= Spacing? PackageDeclaration? ImportDeclaration* TypeDeclaration* EOT
;
PackageDeclaration
= Annotation* PACKAGE QualifiedIdentifier SEMI
;
ImportDeclaration
= IMPORT STATIC? QualifiedIdentifier (DOT STAR)? SEMI
;
TypeDeclaration
= Modifier*
( ClassDeclaration
/ EnumDeclaration
/ InterfaceDeclaration
/ AnnotationTypeDeclaration
)
/ SEMI
;
//-------------------------------------------------------------------------
// Class Declaration
//-------------------------------------------------------------------------
ClassDeclaration
= CLASS Identifier TypeParameters? (EXTENDS ClassType)? (IMPLEMENTS ClassTypeList)? ClassBody
;
ClassBody
= LWING ClassBodyDeclaration* RWING
;
ClassBodyDeclaration
= SEMI
/ STATIC? Block // Static or Instance Initializer
/ Modifier* MemberDecl // ClassMemberDeclaration
;
MemberDecl
= TypeParameters GenericMethodOrConstructorRest // Generic Method or Constructor
/ Type Identifier MethodDeclaratorRest // Method
/ Type VariableDeclarators // Field
/ VOID Identifier VoidMethodDeclaratorRest // Void method
/ Identifier ConstructorDeclaratorRest // Constructor
/ InterfaceDeclaration // Interface
/ ClassDeclaration // Class
/ EnumDeclaration // Enum
/ AnnotationTypeDeclaration // Annotation
;
GenericMethodOrConstructorRest
= (Type / VOID) Identifier MethodDeclaratorRest
/ Identifier ConstructorDeclaratorRest
;
MethodDeclaratorRest
= FormalParameters Dim* (THROWS ClassTypeList)? (MethodBody / SEMI)
;
VoidMethodDeclaratorRest
= FormalParameters (THROWS ClassTypeList)? (MethodBody / SEMI)
;
ConstructorDeclaratorRest
= FormalParameters (THROWS ClassTypeList)? MethodBody
;
MethodBody
= Block
;
//-------------------------------------------------------------------------
// Interface Declaration
//-------------------------------------------------------------------------
InterfaceDeclaration
= INTERFACE Identifier TypeParameters? (EXTENDS ClassTypeList)? InterfaceBody
;
InterfaceBody
= LWING InterfaceBodyDeclaration* RWING
;
InterfaceBodyDeclaration
= Modifier* InterfaceMemberDecl
/ SEMI
;
InterfaceMemberDecl
= InterfaceMethodOrFieldDecl
/ InterfaceGenericMethodDecl
/ VOID Identifier VoidInterfaceMethodDeclaratorRest
/ InterfaceDeclaration
/ AnnotationTypeDeclaration
/ ClassDeclaration
/ EnumDeclaration
;
InterfaceMethodOrFieldDecl
= Type Identifier InterfaceMethodOrFieldRest
;
InterfaceMethodOrFieldRest
= ConstantDeclaratorsRest SEMI
/ InterfaceMethodDeclaratorRest
;
InterfaceMethodDeclaratorRest
= FormalParameters Dim* (THROWS ClassTypeList)? SEMI
;
InterfaceGenericMethodDecl
= TypeParameters (Type / VOID) Identifier InterfaceMethodDeclaratorRest
;
VoidInterfaceMethodDeclaratorRest
= FormalParameters (THROWS ClassTypeList)? SEMI
;
ConstantDeclaratorsRest
= ConstantDeclaratorRest (COMMA ConstantDeclarator)*
;
ConstantDeclarator
= Identifier ConstantDeclaratorRest
;
ConstantDeclaratorRest
= Dim* EQU VariableInitializer
;
//-------------------------------------------------------------------------
// Enum Declaration
//-------------------------------------------------------------------------
EnumDeclaration
= ENUM Identifier (IMPLEMENTS ClassTypeList)? EnumBody
;
EnumBody
= LWING EnumConstants? COMMA? EnumBodyDeclarations? RWING
;
EnumConstants
= EnumConstant (COMMA EnumConstant)*
;
EnumConstant
= Annotation* TypeArguments? Identifier Arguments? ClassBody?
;
EnumBodyDeclarations
= SEMI ClassBodyDeclaration*
;
//-------------------------------------------------------------------------
// Variable Declarations
//-------------------------------------------------------------------------
LocalVariableDeclarationStatement
= FINAL? Type VariableDeclarators SEMI
;
VariableDeclarators
= VariableDeclarator (COMMA VariableDeclarator)*
;
VariableDeclarator
= Identifier Dim* (EQU VariableInitializer)?
;
//-------------------------------------------------------------------------
// Formal Parameters
//-------------------------------------------------------------------------
FormalParameters
= LPAR FormalParameterDecls? RPAR
;
FormalParameter
= (FINAL / Annotation)* Type VariableDeclaratorId
;
FormalParameterDecls
= FINAL? Annotation* Type FormalParameterDeclsRest
;
FormalParameterDeclsRest
= VariableDeclaratorId (COMMA FormalParameterDecls)?
/ ELLIPSIS VariableDeclaratorId
;
VariableDeclaratorId
= Identifier Dim*
;
//-------------------------------------------------------------------------
// Statements
//-------------------------------------------------------------------------
Block
= LWING BlockStatements RWING
;
BlockStatements
= BlockStatement*
;
BlockStatement
= LocalVariableDeclarationStatement
/ Modifier*
( ClassDeclaration
/ EnumDeclaration
)
/ Statement
;
Statement
= Block
/ ASSERT Expression (COLON Expression)? SEMI
/ IF ParExpression Statement (ELSE Statement)?
/ FOR LPAR ForInit? SEMI Expression? SEMI ForUpdate? RPAR Statement
/ FOR LPAR FormalParameter COLON Expression RPAR Statement
/ WHILE ParExpression Statement
/ DO Statement WHILE ParExpression SEMI
/ TRY Block (Catch+ Finally? / Finally)
/ SWITCH ParExpression LWING SwitchBlockStatementGroups RWING
/ SYNCHRONIZED ParExpression Block
/ RETURN Expression? SEMI
/ THROW Expression SEMI
/ BREAK Identifier? SEMI
/ CONTINUE Identifier? SEMI
/ SEMI
/ StatementExpression SEMI
/ Identifier COLON Statement
;
Catch
= CATCH LPAR FormalParameter RPAR Block
;
Finally
= FINALLY Block
;
SwitchBlockStatementGroups
= SwitchBlockStatementGroup*
;
SwitchBlockStatementGroup
= SwitchLabel BlockStatements
;
SwitchLabel
= CASE ConstantExpression COLON
/ CASE EnumConstantName COLON
/ DEFAULT COLON
;
ForInit
= (FINAL / Annotation)* Type VariableDeclarators
/ StatementExpression (COMMA StatementExpression)*
;
ForUpdate
= StatementExpression (COMMA StatementExpression)*
;
EnumConstantName
= Identifier
;
//-------------------------------------------------------------------------
// Expressions
//-------------------------------------------------------------------------
StatementExpression
= Expression
;
// This is more generous than definition in section 14.8, which allows only
// specific forms of Expression.
ConstantExpression
= Expression
;
Expression
= ConditionalExpression (AssignmentOperator ConditionalExpression)*
;
// This definition is part of the modification in JLS Chapter 18
// to minimize look ahead. In JLS Chapter 15.27, Expression is defined
// as AssignmentExpression, which is effectively defined as
// (LeftHandSide AssignmentOperator)* ConditionalExpression.
// The above is obtained by allowing ANY ConditionalExpression
// as LeftHandSide, which results in accepting statements like 5 = a.
AssignmentOperator
= EQU
/ PLUSEQU
/ MINUSEQU
/ STAREQU
/ DIVEQU
/ ANDEQU
/ OREQU
/ HATEQU
/ MODEQU
/ SLEQU
/ SREQU
/ BSREQU
;
ConditionalExpression
= ConditionalOrExpression (QUERY Expression COLON ConditionalOrExpression)*
;
ConditionalOrExpression
= ConditionalAndExpression (OROR ConditionalAndExpression)*
;
ConditionalAndExpression
= InclusiveOrExpression (ANDAND InclusiveOrExpression)*
;
InclusiveOrExpression
= ExclusiveOrExpression (OR ExclusiveOrExpression)*
;
ExclusiveOrExpression
= AndExpression (HAT AndExpression)*
;
AndExpression
= EqualityExpression (AND EqualityExpression)*
;
EqualityExpression
= RelationalExpression ((EQUAL / NOTEQUAL) RelationalExpression)*
;
RelationalExpression
= ShiftExpression ((LE / GE / LT / GT) ShiftExpression / INSTANCEOF ReferenceType)*
;
ShiftExpression
= AdditiveExpression ((SL / SR / BSR) AdditiveExpression)*
;
AdditiveExpression
= MultiplicativeExpression ((PLUS / MINUS) MultiplicativeExpression)*
;
MultiplicativeExpression
= UnaryExpression ((STAR / DIV / MOD) UnaryExpression)*
;
UnaryExpression
= PrefixOp UnaryExpression
/ LPAR Type RPAR UnaryExpression
/ Primary (Selector)* (PostfixOp)*
;
Primary
= ParExpression
/ NonWildcardTypeArguments (ExplicitGenericInvocationSuffix / THIS Arguments)
/ THIS Arguments?
/ SUPER SuperSuffix
/ Literal
/ NEW Creator
/ QualifiedIdentifier IdentifierSuffix?
/ BasicType Dim* DOT CLASS
/ VOID DOT CLASS
;
IdentifierSuffix
= LBRK ( RBRK Dim* DOT CLASS / Expression RBRK)
/ Arguments
/ DOT
( CLASS
/ ExplicitGenericInvocation
/ THIS
/ SUPER Arguments
/ NEW NonWildcardTypeArguments? InnerCreator
)
;
ExplicitGenericInvocation
= NonWildcardTypeArguments ExplicitGenericInvocationSuffix
;
NonWildcardTypeArguments
= LPOINT ReferenceType (COMMA ReferenceType)* RPOINT
;
ExplicitGenericInvocationSuffix
= SUPER SuperSuffix
/ Identifier Arguments
;
PrefixOp
= INC
/ DEC
/ BANG
/ TILDA
/ PLUS
/ MINUS
;
PostfixOp
= INC
/ DEC
;
Selector
= DOT Identifier Arguments?
/ DOT ExplicitGenericInvocation
/ DOT THIS
/ DOT SUPER SuperSuffix
/ DOT NEW NonWildcardTypeArguments? InnerCreator
/ DimExpr
;
SuperSuffix
= Arguments
/ DOT Identifier Arguments?
;
BasicType
= ( "byte"
/ "short"
/ "char"
/ "int"
/ "long"
/ "float"
/ "double"
/ "boolean"
) !LetterOrDigit Spacing?
;
Arguments
= LPAR (Expression (COMMA Expression)*)? RPAR
;
Creator
= NonWildcardTypeArguments? CreatedName ClassCreatorRest
/ NonWildcardTypeArguments? (ClassType / BasicType) ArrayCreatorRest
;
CreatedName
= Identifier NonWildcardTypeArguments? (DOT Identifier NonWildcardTypeArguments?)*
;
InnerCreator
= Identifier ClassCreatorRest
;
ArrayCreatorRest
= LBRK ( RBRK Dim* ArrayInitializer / Expression RBRK DimExpr* Dim* )
;
// This is more generous than JLS 15.10. According to that definition,
// BasicType must be followed by at least one DimExpr or by ArrayInitializer.
ClassCreatorRest
= Arguments ClassBody?
;
ArrayInitializer
= LWING (VariableInitializer (COMMA VariableInitializer)* COMMA? )? RWING
;
VariableInitializer
= ArrayInitializer
/ Expression
;
ParExpression
= LPAR Expression RPAR
;
QualifiedIdentifier
= Identifier (DOT Identifier)*
;
Dim
= LBRK RBRK
;
DimExpr
= LBRK Expression RBRK
;
//-------------------------------------------------------------------------
// Types and Modifiers
//-------------------------------------------------------------------------
Type
= (BasicType / ClassType) Dim*
;
ReferenceType
= BasicType Dim+
/ ClassType Dim*
;
ClassType
= Identifier TypeArguments? (DOT Identifier TypeArguments?)*
;
ClassTypeList
= ClassType (COMMA ClassType)*
;
TypeArguments
= LPOINT TypeArgument (COMMA TypeArgument)* RPOINT
;
TypeArgument
= ReferenceType
/ QUERY ((EXTENDS / SUPER) ReferenceType)?
;
TypeParameters
= LPOINT TypeParameter (COMMA TypeParameter)* RPOINT
;
TypeParameter
= Identifier (EXTENDS Bound)?
;
Bound
= ClassType (AND ClassType)*
;
Modifier
= Annotation
/ ( "public"
/ "protected"
/ "private"
/ "static"
/ "abstract"
/ "final"
/ "native"
/ "synchronized"
/ "transient"
/ "volatile"
/ "strictfp"
) !LetterOrDigit Spacing?
;
// This common definition of Modifier is part of the modification
// in JLS Chapter 18 to minimize look ahead. The main body of JLS has
// different lists of modifiers for different language elements.
//-------------------------------------------------------------------------
// Annotations
//-------------------------------------------------------------------------
AnnotationTypeDeclaration
= AT INTERFACE Identifier AnnotationTypeBody
;
AnnotationTypeBody
= LWING AnnotationTypeElementDeclaration* RWING
;
AnnotationTypeElementDeclaration
= Modifier* AnnotationTypeElementRest
;
AnnotationTypeElementRest
= Type Identifier AnnotationMethodOrConstantRest SEMI
/ ClassDeclaration
/ EnumDeclaration
/ InterfaceDeclaration
/ AnnotationTypeDeclaration
;
AnnotationMethodOrConstantRest
= AnnotationMethodRest
/ AnnotationConstantRest
;
AnnotationMethodRest
= LPAR RPAR DefaultValue?
;
AnnotationConstantRest
= VariableDeclarators
;
DefaultValue
= DEFAULT ElementValue
;
Annotation
= AT QualifiedIdentifier (LPAR (Identifier EQU)? ElementValue RPAR)?
;
ElementValue
= ConditionalExpression
/ Annotation
/ ElementValueArrayInitializer
;
ElementValueArrayInitializer
= LWING ElementValues? COMMA? RWING
;
ElementValues
= ElementValue (COMMA ElementValue)*
;
//=========================================================================
// Lexical Structure
//=========================================================================
//-------------------------------------------------------------------------
// JLS 3.6-7 Spacing
//-------------------------------------------------------------------------
Spacing
= ( [ \t\r\n\u000c]+ // WhiteSpace
/ "/*" (!"*/" _)* "*/" // TraditionalComment
/ "//" (![\r\n] _)* [\r\n] // EndOfLineComment
)* ;
//-------------------------------------------------------------------------
// JLS 3.8 Identifiers
//-------------------------------------------------------------------------
Identifier = !Keyword Letter LetterOrDigit* Spacing?;
Letter = [a-z] / [A-Z] / [_$] ;
LetterOrDigit = [a-z] / [A-Z] / [0-9] / [_$] ;
// These are traditional definitions of letters and digits.
// JLS defines letters and digits as Unicode characters recognized
// as such by special Java procedures, which is difficult
// to express in terms of Parsing Expressions.
//-------------------------------------------------------------------------
// JLS 3.9 Keywords
//-------------------------------------------------------------------------
Keyword
= ( "abstract"
/ "assert"
/ "boolean"
/ "break"
/ "byte"
/ "case"
/ "catch"
/ "char"
/ "class"
/ "continue"
/ "default"
/ "double"
/ "do"
/ "else"
/ "enum"
/ "extends"
/ "false"
/ "finally"
/ "final"
/ "float"
/ "for"
/ "if"
/ "implements"
/ "import"
/ "interface"
/ "int"
/ "instanceof"
/ "long"
/ "native"
/ "new"
/ "null"
/ "package"
/ "private"
/ "protected"
/ "public"
/ "return"
/ "short"
/ "static"
/ "strictfp"
/ "super"
/ "switch"
/ "synchronized"
/ "this"
/ "threadsafe"
/ "throws"
/ "throw"
/ "transient"
/ "true"
/ "try"
/ "void"
/ "volatile"
/ "while"
) !LetterOrDigit
;
ASSERT = "assert" !LetterOrDigit Spacing? ;
BREAK = "break" !LetterOrDigit Spacing? ;
CASE = "case" !LetterOrDigit Spacing? ;
CATCH = "catch" !LetterOrDigit Spacing? ;
CLASS = "class" !LetterOrDigit Spacing? ;
CONTINUE = "continue" !LetterOrDigit Spacing? ;
DEFAULT = "default" !LetterOrDigit Spacing? ;
DO = "do" !LetterOrDigit Spacing? ;
ELSE = "else" !LetterOrDigit Spacing? ;
ENUM = "enum" !LetterOrDigit Spacing? ;
EXTENDS = "extends" !LetterOrDigit Spacing? ;
FINALLY = "finally" !LetterOrDigit Spacing? ;
FINAL = "final" !LetterOrDigit Spacing? ;
FOR = "for" !LetterOrDigit Spacing? ;
IF = "if" !LetterOrDigit Spacing? ;
IMPLEMENTS = "implements" !LetterOrDigit Spacing? ;
IMPORT = "import" !LetterOrDigit Spacing? ;
INTERFACE = "interface" !LetterOrDigit Spacing? ;
INSTANCEOF = "instanceof" !LetterOrDigit Spacing? ;
NEW = "new" !LetterOrDigit Spacing? ;
PACKAGE = "package" !LetterOrDigit Spacing? ;
RETURN = "return" !LetterOrDigit Spacing? ;
STATIC = "static" !LetterOrDigit Spacing? ;
SUPER = "super" !LetterOrDigit Spacing? ;
SWITCH = "switch" !LetterOrDigit Spacing? ;
SYNCHRONIZED = "synchronized" !LetterOrDigit Spacing? ;
THIS = "this" !LetterOrDigit Spacing? ;
THROWS = "throws" !LetterOrDigit Spacing? ;
THROW = "throw" !LetterOrDigit Spacing? ;
TRY = "try" !LetterOrDigit Spacing? ;
VOID = "void" !LetterOrDigit Spacing? ;
WHILE = "while" !LetterOrDigit Spacing? ;
//-------------------------------------------------------------------------
// JLS 3.10 Literals
//-------------------------------------------------------------------------
Literal
= ( FloatLiteral
/ IntegerLiteral // May be a prefix of FloatLiteral
/ CharLiteral
/ StringLiteral
/ "true" !LetterOrDigit
/ "false" !LetterOrDigit
/ "null" !LetterOrDigit
) Spacing?
;
IntegerLiteral
= ( HexNumeral
/ OctalNumeral // May be a prefix of HexNumeral
/ DecimalNumeral // May be a prefix of OctalNumeral
) [lL]?
;
DecimalNumeral
= "0"
/ [1-9]Digit*
;
HexNumeral
= ("0x" / "0X") HexDigit+
;
HexDigit
= [a-f] / [A-F] / [0-9]
;
OctalNumeral
= "0" [0-7]+
;
FloatLiteral
= HexFloat
/ DecimalFloat
;
DecimalFloat
= Digit+ "." Digit* Exponent? [fFdD]?
/ "." Digit+ Exponent? [fFdD]?
/ Digit+ Exponent [fFdD]?
/ Digit+ Exponent? [fFdD]
;
Exponent
= [eE] [+\-]? Digit+
;
Digit = [0-9] ;
HexFloat
= HexSignificand BinaryExponent [fFdD]?
;
HexSignificand
= HexNumeral "."?
/ ("0x" / "0X") HexDigit* "." HexDigit+
;
BinaryExponent
= [pP] [+\-]? Digit+
;
CharLiteral
= "'" (Escape / !['\\] _) "'"
;
StringLiteral
= "\"" (Escape / !["\\] _)* "\""
;
Escape
= "\\" ([btnfr"'\\] / OctalEscape / UnicodeEscape)
;
OctalEscape
= [0-3][0-7][0-7]
/ [0-7][0-7]
/ [0-7]
;
UnicodeEscape
= "u" HexDigit HexDigit HexDigit HexDigit
;
// Unicode escape is not defined in JLS syntax because unicode
// characters are processed very early (see 3.10.4).
//-------------------------------------------------------------------------
// JLS 3.11-12 Separators, Operators
//-------------------------------------------------------------------------
AT = "@" Spacing?;
AND = "&"![=&] Spacing?;
ANDAND = "&&" Spacing?;
ANDEQU = "&=" Spacing?;
BANG = "!" !"=" Spacing?;
BSR = ">>>"!"=" Spacing?;
BSREQU = ">>>=" Spacing?;
COLON = ":" Spacing?;
COMMA = "," Spacing?;
DEC = "--" Spacing?;
DIV = "/" !"=" Spacing?;
DIVEQU = "/=" Spacing?;
DOT = "." Spacing?;
ELLIPSIS = "..." Spacing?;
EQU = "=" !"=" Spacing?;
EQUAL = "==" Spacing?;
GE = ">=" Spacing?;
GT = ">"![=>] Spacing?;
HAT = "^"!"=" Spacing?;
HATEQU = "^=" Spacing?;
INC = "++" Spacing?;
LBRK = "[" Spacing?;
LE = "<=" Spacing?;
LPAR = "(" Spacing?;
LPOINT = "<" Spacing?;
LT = "<"![=<] Spacing?;
LWING = "{" Spacing?;
MINUS = "-"![=\-] Spacing?;
MINUSEQU = "-=" Spacing?;
MOD = "%"!"=" Spacing?;
MODEQU = "%=" Spacing?;
NOTEQUAL = "!=" Spacing?;
OR = "|"![=|] Spacing?;
OREQU = "|=" Spacing?;
OROR = "||" Spacing?;
PLUS = "+"![=+] Spacing?;
PLUSEQU = "+=" Spacing?;
QUERY = "?" Spacing?;
RBRK = "]" Spacing?;
RPAR = ")" Spacing?;
RPOINT = ">" Spacing?;
RWING = "}" Spacing?;
SEMI = ";" Spacing?;
SL = "<<"!"=" Spacing?;
SLEQU = "<<=" Spacing?;
SR = ">>"![=>] Spacing?;
SREQU = ">>=" Spacing?;
STAR = "*"!"=" Spacing?;
STAREQU = "*=" Spacing?;
TILDA = "~" Spacing?;
EOT = !_ ;