-
Notifications
You must be signed in to change notification settings - Fork 125
/
opaDocJoin.opa
144 lines (117 loc) · 3.87 KB
/
opaDocJoin.opa
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
/*
Copyright © 2011 MLstate
This file is part of OPA.
OPA is free software: you can redistribute it and/or modify it under the
terms of the GNU Affero General Public License, version 3, as published by
the Free Software Foundation.
OPA is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Affero General Public License for
more details.
You should have received a copy of the GNU Affero General Public License
along with OPA. If not, see <http://www.gnu.org/licenses/>.
*/
/**
* Joining comments and types annotation
**/
/**
* {1 About this module}
*
* Comments are read from opa files by opadoc, and types annotation are read
* from {b api} files, which have been produced by {b opa --api}.
*
* This module is used for binding comments and types annotation,
* in an association based on the elements positions.
**/
import stdlib.io.file
OpaDocJoin = {{
/**
* {2 Utils: get}
**/
/**
* Get the position from a comment or an api element
**/
get_pos(x) =
match x : Join.mix with
| { api = { ~pos ; ... } }
| { comment = { ~pos ; ... } } -> pos
/**
* Get the origin file from a comment or an api element
**/
get_file(x)=
match x : Join.mix with
| { api = { ~fname ; ...} }
| { comment = {~fname ...} } -> fname
/**
* {2 Utils: make}
**/
/**
* Build a mixed join element from a comment
**/
comment(x) = { comment = x } : Join.mix
/**
* Build a mixed join element from an api
**/
api(x) = { api = x } : Join.mix
/**
* Build a list of mixed join element from a list of comments
**/
from_comments(x) = List.map(comment, x)
/**
* Build a list of mixed join element from a list of apis
**/
from_apis(x) = List.map(api, x)
/**
* Build a list of mixed join element from the comments and apis
**/
join_all(comments, apis) =
lc = from_comments(comments)
lt = from_apis(apis)
lc ++ lt
/**
* {2 Utils: association}
**/
/**
* Given a list a mixed elements (comments and api), build a map
* of mixed elements indexed by the original filenames.
**/
file_separation(all_join : list(Join.mix)) =
// list ==> stringmap of list, indexed by filename
upd(mix, map) =
f = OpaDocUtils.uri_of_path(get_file(mix))
new_list = List.cons(mix, StringMap.get(f, map) ? [])
StringMap.add(f, new_list, map)
List.foldl(upd, all_join, StringMap.empty)
/**
* Given a list of [Join.mix] elements from the same file, compute
* the association between elements, by grouping comments with api
* whenever it is possible.
**/
associate_one_file(l : list(Join.mix)) : Join.joined =
// sort the list so that the order correspond to the order of definitions
// in the original file.
l = List.sort_by(get_pos, l)
rec aux(res, l) =
match l with
| [] -> res
/*
FIXME: when the patas is implemented in qml,
simplify the following patterns
e.g.
[ {~comment= { cat={Glob} ; ... }} | rl ]
*/
| [ {~comment= { cat={Glob} ; content=_ ; fname=_ ; pos=_ }} | rl ] ->
aux([{support=none comment=some(comment)} | res], rl)
| [ {~comment= { cat={Assoc} ; content=_ ; fname=_ ; pos=_ }}, {~api} | rl ] ->
aux([{support=some(api) comment=some(comment)} | res], rl)
| [ {~api} | rl ] ->
aux([{support=some(api) comment=none} | res], rl)
| [ {~comment= { cat={Assoc} ; content=_ ; fname=_ ; pos=_ }} | rl ] ->
aux([{support=none comment=some(comment)} | res], rl)
aux([], l)
/**
* Given a map of [Join.mix] elements indexed by origin filename,
* perform the association between elements for each files.
**/
associate(byfilemap) = StringMap.map(associate_one_file, byfilemap)
}}