-
Notifications
You must be signed in to change notification settings - Fork 125
/
input.opa
371 lines (332 loc) · 11.8 KB
/
input.opa
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
/*
Copyright © 2011 MLstate
This file is part of OPA.
OPA is free software: you can redistribute it and/or modify it under the
terms of the GNU Affero General Public License, version 3, as published by
the Free Software Foundation.
OPA is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Affero General Public License for
more details.
You should have received a copy of the GNU Affero General Public License
along with OPA. If not, see <http://www.gnu.org/licenses/>.
*/
/**
* Elvis Inputs
*
* @category UI
* @author David Rajchenbach-Teller, 2011
* @destination PUBLIC
* @stability EXPERIMENTAL
*/
/**
* {1 Polymorphic text input}
*
* A simple text field, holding a value of polymorphic type.
*
* Expected syntactic sugar:
*
* <EInput id=#foo default_value="Please enter some text" />
*
* Translated into:
*
* foo = let()
* ...
* bind(foo, EInput.make({EInput.default_options with default_value = "Please enter some text"}))
*/
/**
* {1 Theming}
*
* The input always has classes "mlstate", "elvis", "input".
* At start, the field also has class "init". This class disappears once the field is modified.
* When filled with something incorrect, it has class "incorrect". When filled with something correct, it has class "correct".
* If enabled, it has class "enabled", otherwise "disabled"
*/
/**
* {1 Sources for this elvis}
*/
type EInput.sources('value) =
{
changed_value: Event.source({old:option('value) new:option('value) text:string})
/**
* An event sent when the text is being modified.
* Use this e.g. for auto-completion.
*/
changing_text: Event.source(string)
changed_focus: Event.source({received}/{lost})
}
type EInput.options('value) =
{
welcome_text: string
default_value: option('value)
value_accept: string -> option('value)
/**
* Determine how the value should be displayed.
* Used to initialize the elvis, or when the value is set with [set_value].
*/
value_display: option('value) -> string
size_columns: int
is_enabled: bool
is_password: bool
unfocus_validates: bool
newline_validates: bool
tab_validates: bool
}
@abstract type EInput.implementation('value) =
{
/**
* A reference to the dom node containing the real input
*/
dom_input: dom
/**
* A reference to the dom node containing the welcome pseudo-input
*/
dom_welcome: dom
state: Client.reference((string, option('value)))
options: EInput.options('value)
}
type EInput.elvis('a) = Elvis.elvis(EInput.sources('a), EInput.implementation('a))
@client EInput = {{
/**
* {2 Constructors}
*/
simple(): EInput.elvis(string) =
(
make(default_options)
)
make(options: EInput.options('a)): EInput.elvis('a) =
(
value_accept = options.value_accept
default_text = options.value_display(options.default_value)
id_input = "einput_{Random.string(32)}"
dom_input = Dom.select_id(id_input)
id_welcome = "einput_welcome_{Random.string(32)}"
dom_welcome = Dom.select_id(id_welcome)
//Setup sources
changed_value_net = Network.empty()
changing_text_net = Network.empty()
changed_focus_net = Network.empty()
//Handle validation (and UI side effects)
state = Client_reference.create(("", {none}))
validator(text:string): void =
(
old = Client_reference.get(state)
if old.f1 != text then
new = value_accept(text)
do match new with
| {none} -> //Value rejected, set class correspondingly
do Dom.remove_class(dom_input, class_init)
do Dom.remove_class(dom_input, class_correct)
do Dom.add_class(dom_input, class_incorrect)
void
| {some = _} -> //Value accepted, set class correspondingly
do Dom.remove_class(dom_input, class_init)
do Dom.remove_class(dom_input, class_incorrect)
do Dom.add_class(dom_input, class_correct)
void
do Client_reference.set(state, (text, new))
do Network.broadcast({old=old.f2 ~new ~text}, changed_value_net)
void
)
//Propagate information that input is changing
text = Client_reference.create(default_text)
input_changed(_) =
(
new_text = Dom.get_value(dom_input)
if new_text != Client_reference.get(text) then
(
do Network.broadcast(new_text, changing_text_net)
do Client_reference.set(text, new_text)
void
)
)
display(theme) =
(
theme_name = Elvis.Theme.get_classes(theme)
//Handle substitution between a placeholder input containing a welcome text and an input actually used for input
focus_real_input(enable) =
(
if enable then
(
do Dom.hide(dom_welcome)
do Dom.show(dom_input)
_ = Dom.give_focus(dom_input)
void
) else (
if Dom.get_value(dom_input) == "" then//No text entered, restore placeholder
do Dom.hide(dom_input)
do Dom.show(dom_welcome)
void
)
)
xhtml = <input id={id_welcome}
class="{theme_name} mlstate elvis input {class_init} {if options.is_enabled then class_enabled else class_disabled}"
size={options.size_columns}
value={options.welcome_text}
onready={_ -> Dom.set_enabled(dom_welcome, options.is_enabled)}
//Setup substitution
onfocus={_ -> focus_real_input({true})}
type="text"
/>
<input id={id_input}
class="{theme_name} mlstate elvis input {class_init} {if options.is_enabled then class_enabled else class_disabled}"
size={options.size_columns}
value={default_text}
onready={_ -> Dom.set_enabled(dom_input, options.is_enabled)}
//Setup substitution
style="display:none"
onblur={_ -> do Network.broadcast({lost}, changed_focus_net); focus_real_input({false})}
onfocus={_ -> Network.broadcast({received}, changed_focus_net)}
//Setup validation of input
onchange={_ -> if options.unfocus_validates then validator(Dom.get_value(dom_input))}
options:onchange="stop_propagation"
onnewline={_ -> validator(Dom.get_value(dom_input))}
options:onnewline="stop_propagation"
//Setup input change monitoring
oninput={input_changed}
options:oninput="stop_propagation"
onkeyup={input_changed}
options:onkeyup="stop_propagation"
onpaste={input_changed}
options:onpaste="stop_propagation"
//Setup password
type={if options.is_password then "password" else "text"}
/>
dom = Dom.of_xhtml(xhtml)
~{dom xhtml}
)
sources : EInput.sources('a) =
{
changed_value = (changed_value_net)
changing_text = (changing_text_net)
changed_focus = (changed_focus_net)
}
implem : EInput.implementation('a) =
({
~dom_input
~dom_welcome
~state
~options
})
Elvis.make(sources, implem, display)
)
/**
* A default set of options
*/
default_options: EInput.options(string) =
{default_value = {none}
welcome_text = ""
value_accept = Option.some
value_display(x) = x?""
size_columns = 20
is_enabled = {true}
is_password = {false}
unfocus_validates = {true}
newline_validates = {true}
tab_validates = {true}
}
int_options: EInput.options(int) =
{default_value = {none}
welcome_text = ""
value_accept = Parser.try_parse(Rule.integer, _)
value_display(x)= match x with {none} -> "" | ~{some} -> String.of_int(some)
size_columns = 20
is_enabled = {true}
is_password = {false}
unfocus_validates = {true}
newline_validates = {true}
tab_validates = {true}
}
password_options: EInput.options(string) =
{default_value = {none}
welcome_text = "password"
value_accept = Option.some
value_display(x) = x?""
size_columns = 20
is_enabled = {true}
is_password = {true}
unfocus_validates = {true}
newline_validates = {true}
tab_validates = {true}
}
/**
* {2 Accessors}
*/
/**
* Reset the contents of this input
*
* @param trigger If true, inform sources of the change, otherwise remain silent.
*/
reset(einput:EInput.elvis('a), trigger:bool): void =
(
implem = (Elvis.implem(einput))
options = implem.options
do set_text(einput, options.value_display(options.default_value), false)
do set_value(einput, options.default_value, trigger)
void
)
/**
* {3 Get/set the polymorphic value behind this input}
*/
get_value(einput:EInput.elvis('a)): option('a) =
(
Client_reference.get((Elvis.implem(einput)).state).f2
)
set_value(einput:EInput.elvis('a), value:option('a), trigger:bool): void =
(
implem = (Elvis.implem(einput))
options = implem.options
dom = Dom.resolve(implem.dom_input)
old_value = Client_reference.get(implem.state)
do Client_reference.set(implem.state, (options.value_display(value), value))
do Dom.set_value(dom, options.value_display(value))
do if trigger then
Event.trigger(Elvis.sources(einput).changed_value, {old = old_value.f2 text=options.value_display(value) new = value})
void
)
/**
* {3 Get/set the text of this input}
*/
get_text(einput: EInput.elvis('a)): string =
(
Dom.get_value((Elvis.implem(einput)).dom_input)
)
/**
* @param as_user If true, simulate a user entering new content, updating sources, etc. Otherwise, just update the text.
*/
set_text(einput:EInput.elvis('a), text:string, as_user:bool): void =
(
implem = (Elvis.implem(einput))
do Dom.set_value(implem.dom_input, text)
do if as_user then Dom.trigger(implem.dom_input, {change})
void
)
/**
* {3 Get/set editability of this input}
*/
is_editable(einput:EInput.elvis('a)): bool =
(
implem = (Elvis.implem(einput))
Dom.is_enabled(implem.dom_input)
)
set_editable(einput:EInput.elvis('a), editable:bool): void =
(
implem = (Elvis.implem(einput))
dom = Dom.resolve(Dom.unsplit([implem.dom_input, implem.dom_welcome]))
do Dom.set_enabled(dom, editable)
do if editable then
do Dom.remove_class(dom, class_disabled)
do Dom.add_class(dom, class_enabled)
void
else
do Dom.remove_class(dom, class_enabled)
do Dom.add_class(dom, class_disabled)
void
void
)
@private class_init = "init"
@private class_correct = "correct"
@private class_incorrect = "incorrect"
@private class_enabled = "enabled"
@private class_disabled = "disabled"
}}