Medium transformations do not work well with presentation output records

[scymtym]

In the following example, the rectangles and presentations are initially painted surprisingly (all presentations in the first rectangle). Forcing a redisplay places each presentation in "its" rectangles. Forcing another repaint, e.g. by changing the window size, goes back to the initial state.

(cl:defpackage #:presentation-test
  (:use
   #:clim-lisp))

(cl:in-package #:presentation-test)

(clim:define-presentation-type presentation ())

(clim:define-presentation-method clim:present ((object t)
                                               (type   presentation)
                                               (stream t)
                                               (view   t)
                                               &key)
  (clim:draw-rectangle* stream 0 0 100 20 :filled nil)

  (clim:present #1=5 (clim:presentation-type-of #1#) :stream stream :view view)
  (write-string "-" stream)
  (clim:present #2=6 (clim:presentation-type-of #2#) :stream stream :view view))

(clim:define-application-frame test ()
  ()
  (:panes
   (application :application
                :scroll-bars      nil
                :display-function (lambda (frame pane)
                                    (clim:present :foo 'presentation :stream pane)
                                    (clim:with-translation (pane 100 100)
                                      (clim:present :foo 'presentation :stream pane))
                                    (clim:with-translation (pane 100 200)
                                      (clim:present :foo 'presentation :stream pane))))
   (interactor :interactor))
  (:layouts (:default
             (clim:vertically ()
               (clim:scrolling () application)
               interactor))))

(bt:make-thread (lambda () (clim:run-frame-top-level (clim:make-application-frame 'test))))

[dkochmanski]

The problem comes from the fact that all default presentation methods present use stream protocol primitives (princ, prin1, write-string and such). That is understandable because default view on which they are specialized is textual-view, so they can't assume graphics output (and transformations) are available. In particular that means that the stream cursor position is used as defined in stream protocol (so the text is printed at the current cursor position). That's why during display they are placed at left top corner. This is (arguably) correct.

Later behavior is a result of a bug. When we record text output medium transformation is recorded too, but the soes calls draw-text* directly on medium (and not on a stream) and separately adds the output record (in order to concatenate consecutive text output records). So during display we draw without transformation, but replay is triggered with the transformation applied.

When you resize the window (make it bigger) you in fact trigger redisplay, that's why you observe the behavior repeating. It is not repaint but redisplay.

I've identified two bugs:

• one is that we do such underhanded draw on a medium (instead of a stream)
• another one is related to subsequent write-output (I'm still not sure what's going on)
• I think that there is something fishy going on with recording transformation (remotely related to this issue)

Since I don't want to miss the second issue (which may root deeper and may reveal another can of worms), I'm not making a PR with fix yet. You may compile this function to trigger the "arguably correct" behavior (that is to have a consistent behavior intended for textual-view):

(in-package climi)
(defmethod stream-write-output ((stream standard-extended-output-stream)
                                line string-width
                                &optional (start 0) end)
  (declare (ignore string-width))
  (with-identity-transformation (stream)
    (with-slots (baseline vspace) stream
      (multiple-value-bind (cx cy) (stream-cursor-position stream)
        (draw-text* stream line
                    cx (+ cy baseline)
                    :transformation +identity-transformation+
                    :start start :end end)))))

I'll get to this (eventually). Here comes a potential project idea: define default presentation methods for a graphical-view. Also finding out if it is possible to marry text stream protocol with transformations is a fine idea.

[dkochmanski]

Now things are consistent between redisplay and repaint (so there is no transformation issue in draw-text). To ensure, that output records are placed as desired, either use draw-text* as means to present the object (in that case it will be a subject of a transformation), or change the cursor position to match the translation, like here:

(cl:defpackage #:presentation-test
  (:use
   #:clim-lisp))

(cl:in-package #:presentation-test)

(clim:define-presentation-type presentation ())

(clim:define-presentation-method clim:present ((object t)
                                               (type   presentation)
                                               (stream t)
                                               (view   t)
                                               &key)
  (clim:draw-rectangle* stream 0 0 100 20 :filled nil)
  (clim:present #1=5 (clim:presentation-type-of #1#) :stream stream :view view)
  (write-string "-" stream)
  (clim:present #2=6 (clim:presentation-type-of #2#) :stream stream :view view))

(clim:define-application-frame test ()
  ()
  (:panes
   (application :application
                :display-time :command-loop
                :scroll-bars      nil
                :display-function (lambda (frame pane)
                                    (clim:present :foo 'presentation :stream pane)
                                    (setf (clim:stream-cursor-position pane)
                                          (values 100 100))
                                    (clim:with-translation (pane 100 100)
                                      (clim:present :foo 'presentation :stream pane))
                                    (setf (clim:stream-cursor-position pane)
                                          (values 100 200))
                                    (clim:with-translation (pane 100 200)
                                      (clim:present :foo 'presentation :stream pane))))
   (interactor :interactor))
  (:layouts (:default
             (clim:vertically ()
               (clim:scrolling () application)
               interactor))))

(define-test-command (com-redisplay :name t) ())

(bt:make-thread (lambda () (clim:run-frame-top-level (clim:make-application-frame 'test))))