fix: collect all test reports

build.gradle

@@ -35,11 +35,26 @@ repositories {
 
 apply plugin: 'nebula-aggregate-javadocs'
 
-// a task to run all tests and combine them in one report
-task testReport(type: TestReport) {
-    print("System.getenv(\"CI\"): " + System.getenv("CI"))
-    print(" - System.getenv(\"versionTag\"): " + System.getenv("versionTag"))
+// A resolvable configuration to collect test reports data
+configurations {
+    testReportData {
+        canBeResolved = true
+        canBeConsumed = false
+        attributes {
+            attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.DOCUMENTATION))
+            attribute(DocsType.DOCS_TYPE_ATTRIBUTE, objects.named(DocsType, 'test-report-data'))
+        }
+    }
+}
+
+dependencies {
+    testReportData project('main')
+    testReportData project(':processor')
+    testReportData project(':core')
+}
+
+tasks.register('testReport', TestReport) {
     destinationDir = file("$buildDir/reports/allTests")
-    // Combine all 'test' task results into a single HTML report
-    reportOn subprojects.collect { it.tasks.withType(Test) }
+    // Use test results from testReportData configuration
+    testResultDirs.from(configurations.testReportData)
 }

core/build.gradle

@@ -66,3 +66,16 @@ compileJava {
 compileTestJava {
     options.compilerArgs << '-parameters'
 }
+
+// Share the test report data to be aggregated for the whole project
+configurations {
+    binaryTestResultsElements {
+        canBeResolved = false
+        canBeConsumed = true
+        attributes {
+            attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.DOCUMENTATION))
+            attribute(DocsType.DOCS_TYPE_ATTRIBUTE, objects.named(DocsType, 'test-report-data'))
+        }
+        outgoing.artifact(test.binaryResultsDirectory)
+    }
+}

main/build.gradle

@@ -87,3 +87,15 @@ test {
     }
 }
 
+// Share the test report data to be aggregated for the whole project
+configurations {
+    binaryTestResultsElements {
+        canBeResolved = false
+        canBeConsumed = true
+        attributes {
+            attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.DOCUMENTATION))
+            attribute(DocsType.DOCS_TYPE_ATTRIBUTE, objects.named(DocsType, 'test-report-data'))
+        }
+        outgoing.artifact(test.binaryResultsDirectory)
+    }
+}

processor/build.gradle

@@ -36,3 +36,16 @@ test {
         events "passed", "skipped", "failed"
     }
 }
+
+// Share the test report data to be aggregated for the whole project
+configurations {
+    binaryTestResultsElements {
+        canBeResolved = false
+        canBeConsumed = true
+        attributes {
+            attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.DOCUMENTATION))
+            attribute(DocsType.DOCS_TYPE_ATTRIBUTE, objects.named(DocsType, 'test-report-data'))
+        }
+        outgoing.artifact(test.binaryResultsDirectory)
+    }
+}