Don't instantiate nixpkgs in Flake

flake.nix

@@ -23,5 +23,19 @@
   outputs = inputs:
     inputs.flake-parts.lib.mkFlake
     {inherit inputs;}
-    {imports = [./nix];};
+    {
+      imports = [
+        inputs.pre-commit-hooks.flakeModule
+
+        ./nix/dev.nix
+        ./nix/distribution.nix
+      ];
+
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+    };
 }

nix/dev.nix

@@ -1,37 +1,33 @@
 {
-  inputs,
-  self,
-  ...
-}: {
   perSystem = {
-    system,
+    config,
+    lib,
     pkgs,
     ...
   }: {
-    checks = {
-      pre-commit-check = inputs.pre-commit-hooks.lib.${system}.run {
-        src = self;
-        hooks = {
-          markdownlint.enable = true;
+    pre-commit.settings = {
+      hooks = {
+        markdownlint.enable = true;
 
-          alejandra.enable = true;
-          deadnix.enable = true;
-          nil.enable = true;
+        alejandra.enable = true;
+        deadnix.enable = true;
+        nil.enable = true;
 
-          clang-format = {
-            enable = true;
-            types_or = ["c" "c++" "java" "json" "objective-c"];
-          };
+        clang-format = {
+          enable = true;
+          types_or = ["c" "c++" "java" "json" "objective-c"];
         };
-
-        tools.clang-tools = pkgs.clang-tools_16;
       };
+
+      tools.clang-tools = lib.mkForce pkgs.clang-tools_16;
     };
 
     devShells.default = pkgs.mkShell {
-      inherit (self.checks.${system}.pre-commit-check) shellHook;
+      shellHook = ''
+        ${config.pre-commit.installationScript}
+      '';
 
-      inputsFrom = [self.packages.${system}.prismlauncher-unwrapped];
+      inputsFrom = [config.packages.prismlauncher-unwrapped];
       buildInputs = with pkgs; [ccache ninja];
     };
 

nix/distribution.nix

@@ -1,30 +1,44 @@
 {
   inputs,
   self,
-  version,
   ...
 }: {
-  perSystem = {pkgs, ...}: {
-    packages = {
-      inherit (pkgs) prismlauncher-qt5-unwrapped prismlauncher-qt5 prismlauncher-unwrapped prismlauncher;
-      default = pkgs.prismlauncher;
+  perSystem = {
+    lib,
+    pkgs,
+    ...
+  }: {
+    packages = let
+      ourPackages = lib.fix (final: self.overlays.default ({inherit (pkgs) darwin;} // final) pkgs);
+    in {
+      inherit
+        (ourPackages)
+        prismlauncher-qt5-unwrapped
+        prismlauncher-qt5
+        prismlauncher-unwrapped
+        prismlauncher
+        ;
+      default = ourPackages.prismlauncher;
     };
   };
 
   flake = {
     overlays.default = final: prev: let
-      # Helper function to build prism against different versions of Qt.
-      mkPrism = qt:
-        qt.callPackage ./package.nix {
-          inherit (inputs) libnbtplusplus;
-          inherit (prev.darwin.apple_sdk.frameworks) Cocoa;
-          inherit self version;
-        };
+      version = builtins.substring 0 8 self.lastModifiedDate or "dirty";
+
+      # common args for prismlauncher evaluations
+      unwrappedArgs = {
+        inherit (inputs) libnbtplusplus;
+        inherit (final.darwin.apple_sdk.frameworks) Cocoa;
+        inherit self version;
+      };
     in {
-      prismlauncher-qt5-unwrapped = mkPrism final.libsForQt5;
-      prismlauncher-qt5 = prev.prismlauncher-qt5.override {prismlauncher-unwrapped = final.prismlauncher-qt5-unwrapped;};
-      prismlauncher-unwrapped = mkPrism final.qt6Packages;
-      prismlauncher = prev.prismlauncher.override {inherit (final) prismlauncher-unwrapped;};
+      prismlauncher-qt5-unwrapped = prev.libsForQt5.callPackage ./pkg unwrappedArgs;
+      prismlauncher-qt5 = prev.libsForQt5.callPackage ./pkg/wrapper.nix {
+        prismlauncher-unwrapped = final.prismlauncher-qt5-unwrapped;
+      };
+      prismlauncher-unwrapped = prev.qt6Packages.callPackage ./pkg unwrappedArgs;
+      prismlauncher = prev.qt6Packages.callPackage ./pkg/wrapper.nix {inherit (final) prismlauncher-unwrapped;};
     };
   };
 }

nix/pkg/wrapper.nix

@@ -0,0 +1,91 @@
+{
+  lib,
+  stdenv,
+  symlinkJoin,
+  prismlauncher-unwrapped,
+  wrapQtAppsHook,
+  qtbase, # needed for wrapQtAppsHook
+  qtsvg,
+  qtwayland,
+  xorg,
+  libpulseaudio,
+  libGL,
+  glfw,
+  openal,
+  jdk8,
+  jdk17,
+  gamemode,
+  flite,
+  mesa-demos,
+  udev,
+  msaClientID ? null,
+  gamemodeSupport ? stdenv.isLinux,
+  textToSpeechSupport ? stdenv.isLinux,
+  jdks ? [jdk17 jdk8],
+  additionalLibs ? [],
+  additionalPrograms ? [],
+}: let
+  prismlauncherFinal = prismlauncher-unwrapped.override {
+    inherit msaClientID gamemodeSupport;
+  };
+in
+  symlinkJoin {
+    name = "prismlauncher-${prismlauncherFinal.version}";
+
+    paths = [prismlauncherFinal];
+
+    nativeBuildInputs = [
+      wrapQtAppsHook
+    ];
+
+    buildInputs =
+      [
+        qtbase
+        qtsvg
+      ]
+      ++ lib.optional (lib.versionAtLeast qtbase.version "6" && stdenv.isLinux) qtwayland;
+
+    postBuild = ''
+      wrapQtAppsHook
+    '';
+
+    qtWrapperArgs = let
+      runtimeLibs =
+        (with xorg; [
+          libX11
+          libXext
+          libXcursor
+          libXrandr
+          libXxf86vm
+        ])
+        ++ [
+          # lwjgl
+          libpulseaudio
+          libGL
+          glfw
+          openal
+          stdenv.cc.cc.lib
+
+          # oshi
+          udev
+        ]
+        ++ lib.optional gamemodeSupport gamemode.lib
+        ++ lib.optional textToSpeechSupport flite
+        ++ additionalLibs;
+
+      runtimePrograms =
+        [
+          xorg.xrandr
+          mesa-demos # need glxinfo
+        ]
+        ++ additionalPrograms;
+    in
+      ["--prefix PRISMLAUNCHER_JAVA_PATHS : ${lib.makeSearchPath "bin/java" jdks}"]
+      ++ lib.optionals stdenv.isLinux [
+        "--set LD_LIBRARY_PATH /run/opengl-driver/lib:${lib.makeLibraryPath runtimeLibs}"
+        # xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
+        "--prefix PATH : ${lib.makeBinPath runtimePrograms}"
+      ];
+
+    inherit (prismlauncherFinal) meta;
+  }