[神器983]アイシクルブレードを作成

Asset/data/asset/functions/artifact/0983.icicle_blade/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/0983.icicle_blade/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:983} run function asset:artifact/0983.icicle_blade/give/2.give

Asset/data/asset/functions/artifact/0983.icicle_blade/give/2.give.mcfunction

@@ -0,0 +1,59 @@
+#> asset:artifact/0983.icicle_blade/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/0983.icicle_blade/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 983
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:ender_eye"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"アイシクルブレード","color":"aqua","bold":true,"underlined":true}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['[{"text":"前方の敵に無数の氷の刃を放つ","color":"aqua"}]','[{"text":"氷の刃は敵の肉を切り裂き、血を凍らせる","color":"aqua"}]']
+# MP以外の消費物 (TextComponentString) (オプション)
+    # data modify storage asset:artifact CostText set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value [170]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Water]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "never"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value 5
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 5
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# 神器のクールダウン (int) (オプション)
+    # data modify storage asset:artifact LocalCooldown set value
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora","Nyaptov", "Urban"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/0983.icicle_blade/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/0983.icicle_blade/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:983} run function asset:artifact/0983.icicle_blade/trigger/2.check_condition

Asset/data/asset/functions/artifact/0983.icicle_blade/trigger/2.check_condition.mcfunction

@@ -0,0 +1,12 @@
+#> asset:artifact/0983.icicle_blade/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/0983.icicle_blade/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/0983.icicle_blade/trigger/3.main

Asset/data/asset/functions/artifact/0983.icicle_blade/trigger/3.main.mcfunction

@@ -0,0 +1,46 @@
+#> asset:artifact/0983.icicle_blade/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/0983.icicle_blade/trigger/2.check_condition
+
+#> private
+# @private
+    #declare score_holder $Random
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+
+# 演出
+    playsound item.trident.throw player @a ~ ~ ~ 1 2
+    playsound minecraft:entity.glow_squid.squirt player @a ~ ~ ~ 1 2
+    playsound minecraft:block.glass.break neutral @a ~ ~ ~ 1 1.3
+
+# パーティクルランダム
+    # 疑似乱数取得
+        execute store result score $Random Temporary run function lib:random/
+    # ほしい範囲に剰余算
+        scoreboard players operation $Random Temporary %= $11 Const
+    # メッセージ出力
+        execute if score $Random Temporary matches 0 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle1
+        execute if score $Random Temporary matches 1 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle2
+        execute if score $Random Temporary matches 2 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle3
+        execute if score $Random Temporary matches 3 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle4
+        execute if score $Random Temporary matches 4 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle5
+        execute if score $Random Temporary matches 5 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle6
+        execute if score $Random Temporary matches 6 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle7
+        execute if score $Random Temporary matches 7 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle8
+        execute if score $Random Temporary matches 8 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle9
+        execute if score $Random Temporary matches 9 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle10
+        execute if score $Random Temporary matches 10 positioned ~ ~1 ~ run function asset:artifact/0983.icicle_blade/trigger/slash/particle11
+
+# 半円状に判定を出す
+    tag @e[type=#lib:living,tag=Enemy,distance=..5] add RB.Hit
+    execute as @e[type=#lib:living,tag=Enemy,tag=RB.Hit,distance=..6] positioned ^ ^ ^-100 run tag @s[type=#lib:living,tag=Enemy,tag=RB.Hit,distance=..100] remove RB.Hit
+    execute as @e[type=#lib:living,tag=Enemy,tag=RB.Hit,distance=..6] at @s run function asset:artifact/0983.icicle_blade/trigger/4.damage
+
+
+    # リセット
+        scoreboard players reset $Random Temporary

Asset/data/asset/functions/artifact/0983.icicle_blade/trigger/4.damage.mcfunction

@@ -0,0 +1,24 @@
+#> asset:artifact/0983.icicle_blade/trigger/4.damage
+#
+#
+#
+# @within function asset:artifact/0983.icicle_blade/trigger/3.main
+
+
+# 演出
+    particle snowflake ~ ~0.5 ~ 0 1 0 0 5 normal
+
+# ダメージを与える
+    # 与えるダメージ
+        data modify storage lib: Argument.Damage set value 170f
+    # 属性
+        data modify storage lib: Argument.AttackType set value "Physical"
+        data modify storage lib: Argument.ElementType set value "Water"
+    # 補正function
+        execute as @a[tag=this] run function lib:damage/modifier
+
+    # 対象に
+        function lib:damage/
+# リセット
+    function lib:damage/reset
+    tag @s remove RB.Hit

Asset/data/asset/functions/artifact/0983.icicle_blade/trigger/_index.d.mcfunction

@@ -0,0 +1,6 @@
+#> asset:artifact/0983.icicle_blade/trigger/_index.d
+# @private
+
+#> tag
+# @within function asset:artifact/0983.icicle_blade/trigger/**
+    #declare tag RB.Hit