-
Notifications
You must be signed in to change notification settings - Fork 106
/
SHBiasKMask.f95
395 lines (323 loc) · 13.6 KB
/
SHBiasKMask.f95
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
subroutine SHBiasKMask(tapers, lwin, k, incspectra, ldata, outcspectra, &
taper_wt, save_cg, exitstatus)
!------------------------------------------------------------------------------
!
! This subroutine will compute the expected multitaper windowed (cross-)power
! spectra using the first K tapers of the general concentration problem
! for a given input (cross-)power spectrum. Note that this routine makes the
! assumption that the known spectrum can be described as a random variable.
! If the input spectrum is a cross-power spectra, then it is assumed that the
! two fields are linearly related. The default is to apply an equal weight to
! each expected spectrum, but this can be changed by specifying the optional
! arguement taper_wt. The sum of taper_wt will be normalized to unity.
!
! Calling Parameteters
!
! IN
! tapers The coefficients of the windows ((lwin+1)**2, >= k)
! corresponding to the general concentration
! problem, where each column corresponds to the
! spherical harmonic coefficients packed according to
! SHCilmToVector.
! lwin Maximum spherical harmonic degree of the window
! coefficients.
! incspectra Knonw input (cross-)power spectrum as a function of
! degree.
! ldata Maximum degree of incspectra. Beyong this degree
! incspectra is assumed to be zero.
!
! IN (Optional)
! taper_wt Vector of length k corresponding to the weights
! applied to each spectal estimate. The sum of taper_wt
! will be normalized to unity.
! save_cg If 1, the Clebsch-Gordon coefficients will be calculated
! and saved, and then used in all subsequent calls (if
! lwin and ldata are not changed). If -1, the allocated
! memory for these terms will be deallocated.
!
! OUT
! outcspectra Biased estimate of the windowed power spectra. Maximum
! degree calculated is equal to lwin + ldata, or the
! dimension of outspectra.
!
! OPTIONAL (OUT)
! exitstatus If present, instead of executing a STOP when an error
! is encountered, the variable exitstatus will be
! returned describing the error.
! 0 = No errors;
! 1 = Improper dimensions of input array;
! 2 = Improper bounds for input variable;
! 3 = Error allocating memory;
! 4 = File IO error.
!
! Copyright (c) 2005-2019, SHTOOLS
! All rights reserved.
!
!------------------------------------------------------------------------------
use SHTOOLS, only: Wigner3j
use ftypes
implicit none
real(dp), intent(in) :: tapers(:,:), incspectra(:)
real(dp), intent(out) :: outcspectra(:)
integer(int32), intent(in) :: lwin, ldata, k
real(dp), intent(in), optional :: taper_wt(:)
integer(int32), intent(in), optional :: save_cg
integer(int32), intent(out), optional :: exitstatus
integer(int32) :: l, i, j, lmax, imin, imax, n, astat, cstart, cend
real(dp) :: wig(2*lwin+ldata+1)
real(dp), allocatable, save :: cg2(:,:,:)
real(dp), allocatable :: shh(:,:)
!$OMP threadprivate(cg2)
if (present(exitstatus)) exitstatus = 0
lmax = ldata + lwin
outcspectra = 0.0_dp
if (size(tapers(:,1)) < (lwin+1)**2 .or. size(tapers(1,:)) < k) then
print*, "Error --- SHBiasKMask"
print*, "TAPERS must be dimensioned as ((LWIN+1)**2, K) where " // &
"LWIN and K are ", LWIN, K
print*, "Input array is dimensioned ", size(tapers(:,1)), &
size(tapers(1,:))
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(incspectra) < ldata +1) then
print*, "Error --- SHBiasKMask"
print*, "INCSPECTRA must be dimensioned as (LDATA+1) where " // &
"LDATA is ", ldata
print*, "Input array is dimensioned ", size(incspectra)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
if (present(taper_wt)) then
if (size(taper_wt) < k) then
print*, "Error --- SHBiasKMask"
print*, "TAPER_WT must be dimensioned as (K) " // &
"where K is ", k
print*, "Input array is dimensioned as ", size(taper_wt)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (sum(taper_wt(1:k)) /= 1.0_dp) then
print*, "Error --- SHBiasKMask"
print*, "TAPER_WT must sum to unity."
print*, "Input array sums to ", sum(taper_wt(1:k))
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
end if
if (present(save_cg)) then
if (save_cg /= 1 .and. save_cg /= -1 .and. save_cg /= 0) then
print*, "Error --- SHBiasKMask"
print*, "SAVE_CG must be 1 (to save the Clebsch-Gordon " // &
"coefficients), -1 (to deallocate the memory)"
print*, "or 0 (to do nothing)."
print*, "Input value is ", save_cg
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
end if
end if
!--------------------------------------------------------------------------
!
! Calculate power spectra of localization windows. The coefficients
! in each column of TAPERS is ordered according to l**2+(i-1)*l+m+1.
!
!--------------------------------------------------------------------------
allocate (shh(lwin+1, k), stat = astat)
if (astat /= 0) then
print*, "Error --- SHBiasKMask"
print*, "Problem allocating internal array SHH"
if (present(exitstatus)) then
exitstatus = 3
return
else
stop
end if
end if
do l = 0, lwin
cstart = l**2 + 1
cend = l**2 + 2 * l + 1
do n = 1, k
shh(l+1, n) = sum(tapers(cstart:cend, n)**2)
end do
end do
!--------------------------------------------------------------------------
!
! Calculate the biased power spectrum
!
!--------------------------------------------------------------------------
if (present(save_cg)) then
if (save_cg == -1) then
if (allocated (cg2)) deallocate (cg2)
return
else if (save_cg == 0) then
if (present(taper_wt)) then
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
if (present(exitstatus)) then
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0)
end if
do i = imin, min(imax,ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) &
+ taper_wt(n) * shh(j+1,n) &
* incspectra(i+1) &
* (2.0_dp*l+1.0_dp) &
* wig(i-imin+1)**2
end do
end do
end do
end do
else
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
if (present(exitstatus)) then
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0)
end if
do i = imin, min(imax,ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) &
+ shh(j+1,n) &
* incspectra(i+1) &
* (2.0_dp*l+1.0_dp) &
* wig(i-imin+1)**2
end do
end do
end do
end do
outcspectra = outcspectra / dble(k)
end if
return
end if
if (allocated(cg2) .and. (size(cg2(:,1,1)) /= lmax+1 .or. &
size(cg2(1,:,1)) /= lwin+1 .or. &
size(cg2(1,1,:)) /= lmax+lwin+1) ) deallocate (cg2)
if (.not. allocated(cg2)) then
allocate (cg2(lmax+1, lwin+1, lmax+lwin+1), stat = astat)
if (astat /= 0) then
print*, "Error --- SHBiasKMask"
print*, "Problem allocating internal array CG2"
if (present(exitstatus)) then
exitstatus = 3
return
else
stop
end if
end if
cg2 = 0.0_dp
do l = 0, lmax
do j = 0, lwin
if (present(exitstatus)) then
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0)
end if
cg2(l+1,j+1,1:imax-imin+1) = (2.0_dp*l+1.0_dp) &
* wig(1:imax-imin+1)**2
end do
end do
end if
if (present(taper_wt)) then
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
imin = abs(j-l)
imax = j + l
do i = imin, min(imax, ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) + taper_wt(n) &
* shh(j+1,n) * incspectra(i+1) &
* cg2(l+1,j+1,i-imin+1)
end do
end do
end do
end do
else
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
imin = abs(j-l)
imax = j + l
do i = imin, min(imax,ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) &
+ shh(j+1,n) &
* incspectra(i+1) &
* cg2(l+1,j+1,i-imin+1)
end do
end do
end do
end do
outcspectra = outcspectra / dble(k)
end if
else
if (present(taper_wt)) then
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
if (present(exitstatus)) then
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0)
end if
do i = imin, min(imax,ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) + taper_wt(n) &
* shh(j+1,n) * incspectra(i+1) &
* (2.0_dp*l+1.0_dp) &
* wig(i-imin+1)**2
end do
end do
end do
end do
else
do l = 0, min(lmax, size(outcspectra)-1)
do j = 0, lwin
if (present(exitstatus)) then
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call Wigner3j(wig, imin, imax, j, l, 0, 0, 0)
end if
do i = imin, min(imax,ldata), 2
do n = 1, k
outcspectra(l+1) = outcspectra(l+1) &
+ shh(j+1,n) * incspectra(i+1) &
* (2.0_dp*l+1.0_dp) &
* wig(i-imin+1)**2
end do
end do
end do
end do
outcspectra = outcspectra / dble(k)
end if
end if
deallocate (shh)
end subroutine SHBiasKMask