-
Notifications
You must be signed in to change notification settings - Fork 106
/
SHSjkPG.f95
184 lines (142 loc) · 6.11 KB
/
SHSjkPG.f95
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
complex*16 function SHSjkPG(incspectra, l, m, mprime, hj_real, hk_real, &
mj, mk, lwin, hkcc)
!------------------------------------------------------------------------------
!
! This function will compute the expected windowed cross-power spectra for
! two fields, which are windowed by tapers j and k. This corresponds to the
! variable:
!
! m(j) m2(k)*
! < Phi Gamma >
! l l
!
! This routine will only work with tapers that are solutions to the spherical
! cap concentration problem.
!
! Calling Parameteters
!
! IN
! incspectra Knonw input (cross) power spectra
! as a function of degree.
! l, m, mprime Angular degree and order.
! hj, hk Real vectors of length lwin+1 containing the
! the real spherical harmonic coefficients of the
! spherical cap concentration problem.
! mj, mk Angular order of the two windows
! lwin Spherical harmonic bandwidth of the windows.
! hkcc If 1, the complex conjugate of the second window hk
! will be taken. If 2, it will remain as is.
!
! Dependencies: Wigner3j.
!
! Copyright (c) 2016, SHTOOLS
! All rights reserved.
!
!------------------------------------------------------------------------------
use SHTOOLS, only: Wigner3j
implicit none
real*8, intent(in) :: incspectra(:), hj_real(:), hk_real(:)
integer, intent(in) :: lwin, l, m, mprime, mj, mk, hkcc
integer :: i, l1, l3, imin, imax, m1, m3, m2, &
l10min, l10max, l1min, l1max, l30min, l30max, l3min, l3max
complex*16 :: hj(lwin+1), hk(lwin+1), tj(lwin+1), tk(lwin+1), sum2, &
sum3, sum4
real*8 :: wl10(lwin+l+1), wl30(lwin+l+1), wl1(lwin+l+1), wl3(lwin+l+1), sum1
if (size(hj_real) < lwin+1) then
print*, "Error --- SHSjkPG"
print*, "HJ_REAL must be dimensioned as (LWIN+1), where LWIN is ", lwin
print*, "Input array is dimensioned ", size(hj_real)
stop
else if (size(hk_real) < lwin+1) then
print*, "Error --- SHSjkPG"
print*, "HK_REAL must be dimensioned as (LWIN+1), where LWIN is ", lwin
print*, "Input array is dimensioned ", size(hk_real)
stop
else if(size(incspectra(:)) < l+lwin+1) then
print*, "Error --- SHSjkPG"
print*, "INCSPECTRA must be dimensioned as (L+LWIN+1), where " // &
"L and LWIN are ", l, lwin
print*, "Input array is dimensioned ", size(incspectra)
stop
else if (hkcc > 2 .or. hkcc < 1) then
print*, "Error --- SHSjkPG"
print*, "HKCC must be either 1 or 2."
print*, "Input parameter is equal to ", hkcc
stop
end if
SHSjkPG = dcmplx(0.0d0, 0.0d0)
if (l < abs(m) .or. l < abs(mprime)) return
!--------------------------------------------------------------------------
!
! Convert real coefficients to comlex form. This is only done for m>0.
! Negative orders are obtained from the relationship
! f_{lm} = (-1)^m f_{l-m}^*
!
!--------------------------------------------------------------------------
if (mj == 0) then
hj(1:lwin+1) = dcmplx(hj_real(1:lwin+1), 0.0d0)
else if (mj > 0) then
hj(1:lwin+1) = dcmplx(hj_real(1:lwin+1), 0.0d0) / sqrt(2.0d0)
else
hj(1:lwin+1) = dcmplx(0.0d0, -hj_real(1:lwin+1)) / sqrt(2.0d0)
end if
if (mk == 0) then
hk(1:lwin+1) = dcmplx(hk_real(1:lwin+1), 0.0d0)
elseif (mk > 0) then
hk(1:lwin+1) = dcmplx(hk_real(1:lwin+1), 0.0d0) / sqrt(2.0d0)
else
hk(1:lwin+1) = dcmplx(0.0d0, -hk_real(1:lwin+1)) / sqrt(2.0d0)
end if
if (hkcc == 1) hk = dconjg(hk)
!--------------------------------------------------------------------------
!
! Calculate function
!
!--------------------------------------------------------------------------
do l1 = abs(mj), lwin, 1
sum4 = dcmplx(0.0d0, 0.0d0)
call Wigner3j(wl10, l10min, l10max, l, l1, 0, 0, 0)
do l3 = abs(mj), lwin, 1
sum3 = dcmplx(0.0d0,0.0d0)
if (mod(l1+l3,2) == 0) then
call Wigner3j(wl30, l30min, l30max, l, l3, 0, 0, 0)
do m1 = -abs(mj), abs(mj), max(2*abs(mj), 1)
sum2 = dcmplx(0.0d0,0.0d0)
if (m1 < 0) then
tj = conjg(hj) * (-1)**m1
else
tj = hj
end if
do m3 = -abs(mk), abs(mk), max(2*abs(mk), 1)
sum1 = 0.0d0
if (m - m1 == mprime - m3) then
if (m3 < 0) then
tk = conjg(hk) * (-1)**m3
else
tk = hk
end if
m2 = m - m1
call Wigner3j(wl1, l1min, l1max, l, l1, m2, -m, m1)
call Wigner3j(wl3, l3min, l3max, l, l3, m2, &
-mprime, m3)
imin = max(l1min, l3min)
imax = min(l1max, l3max)
if (mod(imin+l1+l,2) /= 0) imin = imin + 1
! both mod(i+l1+l,2) and mod(i+l3+l,2) must be 0
do i = imin, imax, 2
sum1 = sum1 + incspectra(i+1) * wl10(i-l10min+1) * &
wl30(i-l30min+1) * wl1(i-l1min+1) &
* wl3(i-l3min+1)
enddo
end if
sum2 = sum2 + sum1 * tk(l3+1)
end do
sum3 = sum3 + sum2 * tj(l1+1)
end do
end if
sum4 = sum4 + sum3 * sqrt(2.0d0 * l3 + 1.0d0)
end do
SHSjkPG = SHSjkPG + sum4 * sqrt(2.0d0*l1+1.0d0)
end do
SHSjkPG = SHSjkPG * (2.0d0 * l + 1.0d0)
end function SHSjkPG