-
Notifications
You must be signed in to change notification settings - Fork 106
/
SHRead.f95
221 lines (178 loc) · 6.38 KB
/
SHRead.f95
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
subroutine SHRead(filename, cilm, lmax, skip, header, error, exitstatus)
!------------------------------------------------------------------------------
!
! This subroutine will open an ascii file, and read in all of the
! spherical harmonic coefficients. If the option "header"
! is specified, then the first Length(header) records of the
! spherical harmonic file will be retuned in the array header.
!
! The file will be read until the end of the file is encountered
! or until the maximum length of cilm (as dimensioned in the calling
! program) is reached.
!
! Calling Parameters
!
! IN
! filename Character name of the ascii file.
!
! OUT
! cilm Spherical harmonic coeficients with dimensions
! (2, lmax+1, lmax+1).
! lmax Maximum spherical harmonic degree of cilm.
!
! OPTIONAL
! header Array of the first length(header) data records
! in the file. Called as header = header, or
! header = header(1:number_of_header_records).
! skip Number of lines to skip
! error Error of the spherical harmonic coefficients, assumed
! to in the format (l, m, c1lm, c2lm, error1lm, error2lm).
! exitstatus If present, instead of executing a STOP when an error
! is encountered, the variable exitstatus will be
! returned describing the error.
! 0 = No errors;
! 1 = Improper dimensions of input array;
! 2 = Improper bounds for input variable;
! 3 = Error allocating memory;
! 4 = File IO error.
!
! Copyright (c) 2005-2019, SHTOOLS
! All rights reserved.
!
!------------------------------------------------------------------------------
use ftypes
implicit none
character(*), intent(in) :: filename
integer, intent(out) :: lmax
real(dp), intent(out) :: cilm(:,:,:)
real(dp), intent(out), optional :: header(:), error(:,:,:)
integer, intent(in), optional :: skip
integer, intent(out), optional :: exitstatus
integer :: l, m, stat, ll, mm, lmax2, lstart, headlen, fu
if (present(exitstatus)) exitstatus = 0
lmax = 0
cilm = 0.0_dp
fu = 101
if (size(cilm(:,1,1)) < 2) then
print*, "Error --- SHRead"
print*, "CILM must be dimensioned (2, *, *)."
print*, "Input array is dimensioned ", size(cilm(:,1,1)), &
size(cilm(1,:,1)), size(cilm(1,1,:))
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
lmax2 = min(size(cilm(1,1,:) ) - 1, size(cilm(1,:,1) ) - 1)
open(fu, file=filename, status="old")
if (present(header)) headlen = size(header)
!--------------------------------------------------------------------------
!
! Skip lines and read header information
!
!--------------------------------------------------------------------------
if (present(skip)) then
do l = 1, skip, 1
read(fu,*, iostat=stat)
if (stat /= 0 ) then
print*, "Error --- SHRead"
print*, "Problem skipping first lines of ", filename
print*, "Line number = ", l
print*, "Number of lines to skip = ", skip
if (present(exitstatus)) then
exitstatus = 4
return
else
stop
end if
end if
end do
end if
if (present(header)) then
read(fu,*, iostat=stat) (header(l), l=1, headlen,1)
if (stat /= 0) then
print*, "Error --- SHRead"
print*, "Problem reading header line ", filename
if (present(exitstatus)) then
exitstatus = 4
return
else
stop
end if
end if
end if
!--------------------------------------------------------------------------
!
! Determine first l value
!
!--------------------------------------------------------------------------
read(fu,*, iostat=stat) ll
if (stat /= 0) then
print*, "Error --- SHRead"
print*, "Problem reading first line of ", filename
if (present(exitstatus)) then
exitstatus = 4
return
else
stop
end if
end if
lstart = ll
rewind (fu)
if (present(skip)) then
do l = 1, skip, 1
read(fu,*, iostat=stat)
end do
end if
if (present(header)) then
read(fu,*, iostat=stat) (header(l), l=1, headlen)
end if
!--------------------------------------------------------------------------
!
! Read coefficients
!
!--------------------------------------------------------------------------
do l = lstart, lmax2, 1
do m = 0, l
if (present(error)) then
read(fu,*,iostat=stat) ll, mm, cilm(1,l+1,m+1), &
cilm(2,l+1,m+1), error(1,l+1,m+1), error(2,l+1,m+1)
else
if (m == 0) then
read(fu,*,iostat=stat) ll, mm, cilm(1,l+1,m+1)
else
read(fu,*,iostat=stat) ll, mm, cilm(1,l+1,m+1), &
cilm(2,l+1,m+1)
end if
end if
if (stat < 0) then
exit
else if (stat > 0) then
print*, "Error --- SHRead"
print*, "Problem reading file ", filename
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (ll /=l .or. mm /= m) then
print*, "Error --- SHRead"
print*, "Problem reading file ", filename
print*, "Expected indices (l,m) = ", l, m
print*, "Read indices (l,m) = ", ll, mm
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
end do
if (stat < 0) exit
lmax = l
end do
close (fu)
end subroutine SHRead