-
Notifications
You must be signed in to change notification settings - Fork 106
/
SHBiasAdmitCorr.f95
314 lines (281 loc) · 12.2 KB
/
SHBiasAdmitCorr.f95
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
subroutine SHBiasAdmitCorr(Sgt, Sgg, Stt, lmax, tapers, lwin, K, admit, &
corr, mtdef, taper_wt, exitstatus)
!-------------------------------------------------------------------------------
!
! This subroutine will take as input the three global (unbiased) cross-power
! spectra of two functions G and T (Sgt, Sgg, and Stt), bias these using the
! first K localization windows, and then calculated the expected biased
! admittance (Sgt/Stt) and correlation (Sgt/sqrt(Sgg Stt)) spectra. Two
! manners of calculating the localized admittance and correlation are possible
! according to the optional parameter MTDEF. In one case, the multitaper
! cross-power spectra are calculated, and from these, the admittance and
! correlation. In the second, the admittance and correlation are calculated
! for each taper, and these are then averaged.
!
! The admittance and correlation functions are only calculated up to a maximum
! degree of lmax - lwin. This implicitly assumes that the cross-power spectra
! beyond lmax are simply unknown, and not zero.
!
! All cross-power spectra must be constructed using 4-pi normalized or
! orthonormalized spherical harmonic functions.
!
! Calling Parameters
!
! INPUT
! Sgt Global cross-power spectrum of G and T.
! Sgg Global power spectrum of G.
! Stt Global power spectrum of T.
! lmax Maximum spherical harmonic degree of the intput
! cross-power spectra.
! tapers A matrix of tapers obtained from SHReturnTapers.
! lwin Spectral bandwidth of the localizing window.
! K Number of tapers to use in the multitaper spectral
! estimations.
!
! OUTPUT
! admit Biased admittance between the localized G and T:
! Sgt/Stt.
! corr Biased correlation of the two functions:
! Sgt / sqrt(Sgg Stt).
!
! OPTIONAL (IN)
! mtdef 1 (default): Calculate multitaper cross-spectral
! estimates, and use these to calculate a single
! admittance and correlations.
! 2: Calculate the admittance and correlation using each
! individual taper, and then average these to get the
! admittance and correlation.
! taper_wt Vector of length numk corresponding to the weights
! applied to each spectal estimate. The sum of taper_wt
! will be normalized to unity.
!
! OPTIONAL (OUT)
! exitstatus If present, instead of executing a STOP when an error
! is encountered, the variable exitstatus will be
! returned describing the error.
! 0 = No errors;
! 1 = Improper dimensions of input array;
! 2 = Improper bounds for input variable;
! 3 = Error allocating memory;
! 4 = File IO error.
!
! Copyright (c) 2005-2019, SHTOOLS
! All rights reserved.
!
!------------------------------------------------------------------------------
use SHTOOLS, only: SHBias, SHBiasK
use ftypes
implicit none
real(dp), intent(in) :: sgt(:), sgg(:), stt(:), tapers(:,:)
integer, intent(in) :: lmax, lwin, K
real(dp), intent(out) :: admit(:), corr(:)
integer, intent(in), optional :: mtdef
real(dp), intent(in), optional :: taper_wt(:)
integer, intent(out), optional :: exitstatus
real(dp) :: sgt_bias(lmax-lwin+1), sgg_bias(lmax-lwin+1), &
stt_bias(lmax-lwin+1), shh(lwin+1)
integer :: lmax_calc, def, i
if (present(exitstatus)) exitstatus = 0
if (size(sgt) < lmax+1) then
print*, "Error --- SHBiasAdmitCorr"
print*, "SGT must be dimensioned as (LMAX+1), or more, " // &
"where LMAX is ", lmax
print*, "Input array is dimensioned ", size(sgt)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(sgg) < lmax+1) then
print*, "Error --- SHBiasAdmitCorr"
print*, "SGG must be dimensioned as (LMAX+1), or more, " // &
"where LMAX is ", lmax
print*, "Input array is dimensioned ", size(sgg)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(stt) < lmax+1) then
print*, "Error --- SHBiasAdmitCorr"
print*, "STT must be dimensioned as (LMAX+1), or more, " // &
"where LMAX is ", lmax
print*, "Input array is dimensioned ", size(stt)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(admit) < lmax-lwin+1) then
print*, "Error --- SHBiasAdmitCorr"
print*, "ADMIT must be dimensioned as (LMAX-LWIN+1) where " // &
"LMAX and LWIN are ", lmax, lwin
print*, "Input array is dimensioned ", size(admit)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(corr) < lmax-lwin+1) then
print*, "Error --- SHBiasAdmitCorr"
print*, "CORR must be dimensioned as (LMAX-LWIN+1) where " // &
"LMAX and LWIN are ", lmax, lwin
print*, "Input array is dimensioned ", size(corr)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(tapers(:,1)) < lwin+1 .or. size(tapers(1,:)) < K) then
print*, "Error --- SHBiasAdmitCorr"
print*, "TAPERS must be dimensioned as (LWIN+1, K) where lwin " // &
"and K are ", lwin, K
print*, "Iinput array is dimensioned as ", size(tapers(:,1)), &
size(tapers(1,:))
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
if (present(taper_wt)) then
if (size(taper_wt) < K) then
print*, "Error --- SHBiasAdmitCorr"
print*, "TAPER_WT must be dimensioned as K where K is ", K
print*, "Input array is dimensioned as ", size(taper_wt)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (sum(taper_wt(1:K)) /= 1.0_dp) then
print*, "Error --- SHBiasAdmitCorr"
print*, "TAPER_WT must sum to unity."
print*, "Input array sums to ", sum(taper_wt(1:K))
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
end if
end if
if (present(mtdef)) then
if (mtdef /= 1 .and. mtdef /= 2) then
print*, "Error --- SHBiasAdmitCorr"
print*, "MTDEF must be 1 or 2."
print*, "Input value is ", mtdef
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
else
def = mtdef
end if
else
def = 1
end if
lmax_calc = lmax - lwin
admit = 0.0_dp
corr = 0.0_dp
!--------------------------------------------------------------------------
!
! Calculate baissed cross-power spectra and biased admittances and
! correlations.
!
!--------------------------------------------------------------------------
if (def == 1) then
if (present(taper_wt)) then
if (present(exitstatus)) then
call SHBiasK (tapers, lwin, K, sgt, lmax, &
sgt_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBiasK (tapers, lwin, K, sgg, lmax, &
sgg_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBiasK (tapers, lwin, K, stt, lmax, &
stt_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call SHBiasK (tapers, lwin, K, sgt, lmax, &
sgt_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1)
call SHBiasK (tapers, lwin, K, sgg, lmax, &
sgg_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1)
call SHBiasK (tapers, lwin, K, stt, lmax, &
stt_bias(1:lmax_calc+1), taper_wt = taper_wt, &
save_cg = 1)
end if
else
if (present(exitstatus)) then
call SHBiasK (tapers, lwin, K, sgt, lmax,&
sgt_bias(1:lmax_calc+1), save_cg = 1, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBiasK (tapers, lwin, K, sgg, lmax, &
sgg_bias(1:lmax_calc+1), save_cg = 1, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBiasK (tapers, lwin, K, stt, lmax, &
stt_bias(1:lmax_calc+1), save_cg = 1, &
exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call SHBiasK (tapers, lwin, K, sgt, lmax,&
sgt_bias(1:lmax_calc+1), save_cg = 1)
call SHBiasK (tapers, lwin, K, sgg, lmax, &
sgg_bias(1:lmax_calc+1), save_cg = 1)
call SHBiasK (tapers, lwin, K, stt, lmax, &
stt_bias(1:lmax_calc+1), save_cg = 1)
end if
end if
admit(1:lmax_calc+1) = sgt_bias(1:lmax_calc+1) / stt_bias(1:lmax_calc+1)
corr(1:lmax_calc+1) = sgt_bias(1:lmax_calc+1) &
/ sqrt(stt_bias(1:lmax_calc+1)) &
/ sqrt(sgg_bias(1:lmax_calc+1))
else if (def == 2) then
do i = 1, K
shh(1:lwin+1) = tapers(1:lwin+1, i)**2
if (present(exitstatus)) then
call SHBias (shh, lwin, sgt, lmax, sgt_bias(1:lmax_calc+1), &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBias (shh, lwin, sgg, lmax, sgg_bias(1:lmax_calc+1), &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
call SHBias (shh, lwin, stt, lmax, stt_bias(1:lmax_calc+1), &
save_cg = 1, exitstatus = exitstatus)
if (exitstatus /= 0) return
else
call SHBias (shh, lwin, sgt, lmax, sgt_bias(1:lmax_calc+1), &
save_cg = 1)
call SHBias (shh, lwin, sgg, lmax, sgg_bias(1:lmax_calc+1), &
save_cg = 1)
call SHBias (shh, lwin, stt, lmax, stt_bias(1:lmax_calc+1), &
save_cg = 1)
end if
admit(1:lmax_calc+1) = admit(1:lmax_calc+1) &
+ sgt_bias(1:lmax_calc+1) &
/ stt_bias(1:lmax_calc+1)
corr(1:lmax_calc+1) = corr(1:lmax_calc+1) &
+ sgt_bias(1:lmax_calc+1) / &
sqrt(stt_bias(1:lmax_calc+1)) &
/ sqrt(sgg_bias(1:lmax_calc+1))
end do
admit(1:lmax_calc+1) = admit(1:lmax_calc+1) / dble(K)
corr(1:lmax_calc+1) = corr(1:lmax_calc+1) / dble(K)
end if
end subroutine SHBiasAdmitCorr