keyboard special keys

[tomelgato]

I have a 5x4 matrix keyboard, running fine with tcmenu (just using 4 rows).

I like to use the first row to define some special actions, like changing presets. Is it possible to get a callback or similar when one of this keys is pressed (when tcmenu is active)?

Thanks!

[davetcc]

If you want a custom layout, you'll need to add the keyboard manually, see the attached guide:

https://www.thecoderscorner.com/products/arduino-libraries/tc-menu/menu-control-using-matrix-keyboard/

And the base docs:

https://www.thecoderscorner.com/products/arduino-libraries/io-abstraction/matrix-keyboard-keypad-manager/

If you want to handle some keypresses yourself, you'd just extend from MenuEditingKeyListener and override keyPressed and keyReleased to handle your special keys, passing the rest through to the base (which would call into tcMenu).

[tomelgato]

Thanks ill give it a try!

[davetcc]

Do ping back here if you run into any issues, or if there is any gap around this case in the documentation

[tomelgato]

Hello Dave! Finally i got it running.

Without your help above it would be difficult, cause the base Doc references to:
void onKeyPressed(char key, bool held) {
// do something when pressed

and with tcmenu it should be
void keyPressed(char key, bool held)

Otherwise its good, if you do not overlook a wrong case: onKeyPressed --edited to-> KeyPressed != keyPressed. This mistake took me hours to find ... lol

[tomelgato]

A complete and working example for a 5x4 keyboard incl. custom key listener extension:

#include <tcMenuKeyboard.h>

// custom definition for 5x4 keyboard
const char KEYBOARD_STD_5X4_KEYS[] PROGMEM = "WXYZ123A456B789#L0R*";
KeyboardLayout keyLayout(5, 4, KEYBOARD_STD_5X4_KEYS);

MatrixKeyboardManager keyboard;

class MyKeyboardListener : public MenuEditingKeyListener {
	public:
		void keyPressed(char key, bool held) {
			// do something when pressed
			switch (key) {
				case char('W'):
					Serial.println("W Key pressed");
                                    break;
				default:
					// pass other keys to TCMenu
					MenuEditingKeyListener::keyPressed(key,held);
					break;
			}
		}
		void keyReleased(char key) {
			// do something when released
			switch (key) {
				default:
					// pass other keys to TCMenu
					MenuEditingKeyListener::keyReleased(key);
					break;
			}
		}
} MyKbdListener;


void setupKeyboard() {
	// setup pin mappings
	keyLayout.setRowPin(0, kb_row1);
	keyLayout.setRowPin(1, kb_row2);
	keyLayout.setRowPin(2, kb_row3);
	keyLayout.setRowPin(3, kb_row4);
	keyLayout.setRowPin(4, kb_row5);
	keyLayout.setColPin(0, kb_col1);
	keyLayout.setColPin(1, kb_col2);
	keyLayout.setColPin(2, kb_col3);
	keyLayout.setColPin(3, kb_col4);

	// use the class extension
	keyboard.initialise(ioUsingArduino(), &keyLayout, &MyKbdListener);

	// repeat the pressed key after 850ms every 350ms 
	keyboard.setRepeatKeyMillis(850, 350);
}