The VFP functions At() and AtC() do not work properly

[Karl1155]

In both funcs it´s necessary to:

• add 1 to the search result
• and exit the loop as soon the search result is 0

FUNCTION Start() AS VOID
	
	? "AtC()" 
	? AtC_Current("Bu", "abucabucbba", 2 ) //  shows 1 instead of 6 
	? AtC_Current("Bu", "abucabucbba", 1 ) //  shows 1 instead of 2		
	? AtC_Current("Bu", "abucabucbba", 12 ) // shows 1 instead of 0   
	
	?
	? AtC_Fix("Bu", "abucabucbba", 2 ) 	  // ok, 6
	? AtC_Fix("Bu", "abucabucbba", 1 ) 	  // ok, 2	
	? AtC_Fix("Bu", "abucabucbba", 12 )  // ok, 0 	
	?

	? "At()" 
	? At_Current("b", "abucabucbba", 3 ) //  shows 1 instead of 9 
	? At_Current("bu", "abucabucbba", 1 ) //  shows 1 instead of 2		
	? At_Current("bu", "abucabucbba", 12 ) // shows 1 instead of 0 
	
	?
	? At_Fix("b", "abucabucbba", 3 )	  // ok, 9 
	? At_Fix("bu", "abucabucbba", 1 ) 	  // ok, 2	
	? At_Fix("bu", "abucabucbba", 12 )  // ok , 0	

	RETURN   


// --------- XSharpPublic/Runtime/XSharp.VFP/ToDo-A.prg  ----------

FUNCTION At_Current(cSearchExpression AS STRING, cExpressionSearched AS STRING, nOccurrence := 1 AS DWORD) AS DWORD
	LOCAL position := 0 AS DWORD
	IF ( cExpressionSearched != NULL .AND. cSearchExpression != NULL )
		IF cExpressionSearched:Length != 0 .AND. cSearchExpression:Length != 0
			DO WHILE nOccurrence  > 0
				position := (DWORD) cExpressionSearched:IndexOf(cSearchExpression, (INT) position,StringComparison.Ordinal) 
				nOccurrence -= 1
			ENDDO
		END IF
	ENDIF
	RETURN position	
	
FUNCTION AtC_Current(cSearchExpression AS STRING, cExpressionSearched AS STRING, nOccurrence := 1 AS DWORD) AS DWORD
	LOCAL position := 0 AS DWORD
	IF ( cExpressionSearched != NULL .AND. cSearchExpression != NULL )
		IF cExpressionSearched:Length != 0 .AND. cSearchExpression:Length != 0
			DO WHILE nOccurrence  > 0
				position := (DWORD) cExpressionSearched:IndexOf(cSearchExpression, (INT) position,StringComparison.OrdinalIgnoreCase) 
				nOccurrence -= 1
			ENDDO
		END IF
	ENDIF
	RETURN position	 
	
// ------------------  Fixes ------------------------------------	
	
FUNCTION At_Fix(cSearchExpression AS STRING, cExpressionSearched AS STRING, nOccurrence := 1 AS DWORD) AS DWORD
	LOCAL position := 0 AS DWORD
	IF ( cExpressionSearched != NULL .AND. cSearchExpression != NULL )
		IF cExpressionSearched:Length != 0 .AND. cSearchExpression:Length != 0
			DO WHILE nOccurrence  > 0
				IF ( position := (DWORD) cExpressionSearched:IndexOf(cSearchExpression, (INT) position,StringComparison.Ordinal) + 1) == 0
					EXIT
				ENDIF	
				nOccurrence -= 1
			ENDDO
		END IF
	ENDIF
	RETURN position	
	
FUNCTION AtC_Fix(cSearchExpression AS STRING, cExpressionSearched AS STRING, nOccurrence := 1 AS DWORD) AS DWORD
	LOCAL position := 0 AS DWORD
	IF ( cExpressionSearched != NULL .AND. cSearchExpression != NULL )
		IF cExpressionSearched:Length != 0 .AND. cSearchExpression:Length != 0
			DO WHILE nOccurrence  > 0
				IF ( position := (DWORD) cExpressionSearched:IndexOf(cSearchExpression, (INT) position,StringComparison.OrdinalIgnoreCase) + 1) == 0
					EXIT
				ENDIF				  
				nOccurrence -= 1
			ENDDO
		END IF
	ENDIF
	RETURN position

Karl-Heinz

[cpyrgas]

Thanks Karl-Heinz and sorry for the delay getting back to you. I have made the changes and also added a few tests. You cannot see the changes yet because my repository is messed up right now, but they are done.