Enhance grpc finding in GAE cmake (#2184)

Signed-off-by: Tao He <sighingnow@gmail.com>

analytical_engine/CMakeLists.txt

@@ -210,8 +210,15 @@ if (ENABLE_JAVA_SDK)
     include_directories(SYSTEM ${JAVA_INCLUDE_PATH2})
 endif()
 
-include("cmake/FindGRPC.cmake")
-include_directories(${GRPC_INCLUDE_DIR})
+find_package(gRPC QUIET)
+if(gRPC_FOUND)
+    set(GRPC_LIBRARIES gRPC::gpr gRPC::grpc gRPC::grpc++)
+    get_target_property(GRPC_CPP_PLUGIN gRPC::grpc_cpp_plugin LOCATION)
+    get_target_property(GRPC_INCLUDE_DIR gRPC::grpc INTERFACE_INCLUDE_DIRECTORIES)
+else()
+    include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/FindGRPC.cmake)
+    set(GRPC_LIBRARIES ${GPR_LIBRARY} ${GRPC_LIBRARY} ${GRPC_GRPC++_LIBRARY})
+endif()
 
 # Generate proto
 execute_process(COMMAND python3 python/graphscope/proto/proto_generator.py "${PROJECT_SOURCE_DIR}" --cpp
@@ -224,11 +231,9 @@ file(GLOB CORE_RPC_SRC_FILES "core/server/*.cc")
 add_library(gs_proto SHARED ${PROTO_CPP_FILES})
 set_source_files_properties(${PROTO_CPP_FILES} PROPERTIES COMPILE_FLAGS -Wno-array-bounds)
 target_include_directories(gs_proto PRIVATE "${PROJECT_SOURCE_DIR}/proto")
-target_link_libraries(gs_proto
+target_link_libraries(gs_proto PUBLIC
         ${Protobuf_LIBRARIES}
-        ${GRPC_LIBRARY}
-        ${GRPC_GRPC++_LIBRARY}
-        ${GRPC_GRPC++_REFLECTION_LIBRARY}
+        ${GRPC_LIBRARIES}
     )
 
 add_library(gs_util SHARED "core/flags.cc" "core/launcher.cc")

analytical_engine/cmake/FindGRPC.cmake

@@ -4,129 +4,97 @@
 #
 # The original repository is open-sourced with the MIT license.
 #
-#
 # Locate and configure the gRPC library
 #
 # Adds the following targets:
 #
+#  gRPC::gpr - GPR library
 #  gRPC::grpc - gRPC library
 #  gRPC::grpc++ - gRPC C++ library
 #  gRPC::grpc++_reflection - gRPC C++ reflection library
 #  gRPC::grpc_cpp_plugin - C++ generator plugin for Protocol Buffers
 #
 
-#
-# Generates C++ sources from the .proto files
-#
-# grpc_generate_cpp (<SRCS> <HDRS> <DEST> [<ARGN>...])
-#
-#  SRCS - variable to define with autogenerated source files
-#  HDRS - variable to define with autogenerated header files
-#  DEST - directory where the source files will be created
-#  ARGN - .proto files
-#
-function(GRPC_GENERATE_CPP SRCS HDRS DEST)
-  if(NOT ARGN)
-    message(SEND_ERROR "Error: GRPC_GENERATE_CPP() called without any proto files")
-    return()
-  endif()
-
-  if(GRPC_GENERATE_CPP_APPEND_PATH)
-    # Create an include path for each file specified
-    foreach(FIL ${ARGN})
-      get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
-      get_filename_component(ABS_PATH ${ABS_FIL} PATH)
-      list(FIND _protobuf_include_path ${ABS_PATH} _contains_already)
-      if(${_contains_already} EQUAL -1)
-          list(APPEND _protobuf_include_path -I ${ABS_PATH})
-      endif()
-    endforeach()
-  else()
-    set(_protobuf_include_path -I ${CMAKE_CURRENT_SOURCE_DIR})
-  endif()
-
-  if(DEFINED PROTOBUF_IMPORT_DIRS)
-    foreach(DIR ${PROTOBUF_IMPORT_DIRS})
-      get_filename_component(ABS_PATH ${DIR} ABSOLUTE)
-      list(FIND _protobuf_include_path ${ABS_PATH} _contains_already)
-      if(${_contains_already} EQUAL -1)
-          list(APPEND _protobuf_include_path -I ${ABS_PATH})
-      endif()
-    endforeach()
-  endif()
-
-  set(${SRCS})
-  set(${HDRS})
-  foreach(FIL ${ARGN})
-    get_filename_component(ABS_FIL ${FIL} ABSOLUTE)
-    get_filename_component(FIL_WE ${FIL} NAME_WE)
-
-    list(APPEND ${SRCS} "${DEST}/${FIL_WE}.grpc.pb.cc")
-    list(APPEND ${HDRS} "${DEST}/${FIL_WE}.grpc.pb.h")
-
-    add_custom_command(
-      OUTPUT "${DEST}/${FIL_WE}.grpc.pb.cc"
-             "${DEST}/${FIL_WE}.grpc.pb.h"
-      COMMAND protobuf::protoc
-      ARGS --grpc_out ${DEST} ${_protobuf_include_path} --plugin=protoc-gen-grpc=${GRPC_CPP_PLUGIN} ${ABS_FIL}
-      DEPENDS ${ABS_FIL} protobuf::protoc gRPC::grpc_cpp_plugin
-      COMMENT "Running C++ gRPC compiler on ${FIL}"
-      VERBATIM )
-  endforeach()
-
-  set_source_files_properties(${${SRCS}} ${${HDRS}} PROPERTIES GENERATED TRUE)
-  set(${SRCS} ${${SRCS}} PARENT_SCOPE)
-  set(${HDRS} ${${HDRS}} PARENT_SCOPE)
-endfunction()
-
-# By default have GRPC_GENERATE_CPP macro pass -I to protoc
-# for each directory where a proto file is referenced.
-if(NOT DEFINED GRPC_GENERATE_CPP_APPEND_PATH)
-  set(GRPC_GENERATE_CPP_APPEND_PATH TRUE)
-endif()
-
 # Find gRPC include directory
 find_path(GRPC_INCLUDE_DIR grpc/grpc.h)
 mark_as_advanced(GRPC_INCLUDE_DIR)
 
+# Find gGPR library
+find_library(GPR_LIBRARY NAMES gpr)
+mark_as_advanced(GRPC_GPR_LIBRARY)
+add_library(gRPC::gpr UNKNOWN IMPORTED)
+set_target_properties(gRPC::gpr PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
+    INTERFACE_LINK_LIBRARIES "-lpthread;-ldl"
+    IMPORTED_LOCATION ${GPR_LIBRARY}
+)
+
 # Find gRPC library
 find_library(GRPC_LIBRARY NAMES grpc)
 mark_as_advanced(GRPC_LIBRARY)
-#add_library(gRPC::grpc UNKNOWN IMPORTED)
-#set_target_properties(gRPC::grpc PROPERTIES
-#    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
-#    INTERFACE_LINK_LIBRARIES "-lpthread;-ldl"
-#    IMPORTED_LOCATION ${GRPC_LIBRARY}
-#)
+add_library(gRPC::grpc UNKNOWN IMPORTED)
+set_target_properties(gRPC::grpc PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
+    INTERFACE_LINK_LIBRARIES gRPC::gpr
+    IMPORTED_LOCATION ${GRPC_LIBRARY}
+)
 
 # Find gRPC C++ library
 find_library(GRPC_GRPC++_LIBRARY NAMES grpc++)
 mark_as_advanced(GRPC_GRPC++_LIBRARY)
-#add_library(gRPC::grpc++ UNKNOWN IMPORTED)
-#set_target_properties(gRPC::grpc++ PROPERTIES
-#    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
-#    INTERFACE_LINK_LIBRARIES gRPC::grpc
-#    IMPORTED_LOCATION ${GRPC_GRPC++_LIBRARY}
-#)
+add_library(gRPC::grpc++ UNKNOWN IMPORTED)
+set_target_properties(gRPC::grpc++ PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
+    INTERFACE_LINK_LIBRARIES gRPC::grpc
+    IMPORTED_LOCATION ${GRPC_GRPC++_LIBRARY}
+)
 
 # Find gRPC C++ reflection library
 find_library(GRPC_GRPC++_REFLECTION_LIBRARY NAMES grpc++_reflection)
 mark_as_advanced(GRPC_GRPC++_REFLECTION_LIBRARY)
-#add_library(gRPC::grpc++_reflection UNKNOWN IMPORTED)
-#set_target_properties(gRPC::grpc++_reflection PROPERTIES
-#    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
-#    INTERFACE_LINK_LIBRARIES gRPC::grpc++
-#    IMPORTED_LOCATION ${GRPC_GRPC++_REFLECTION_LIBRARY}
-#)
+add_library(gRPC::grpc++_reflection UNKNOWN IMPORTED)
+set_target_properties(gRPC::grpc++_reflection PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES ${GRPC_INCLUDE_DIR}
+    INTERFACE_LINK_LIBRARIES gRPC::grpc++
+    IMPORTED_LOCATION ${GRPC_GRPC++_REFLECTION_LIBRARY}
+)
 
 # Find gRPC CPP generator
 find_program(GRPC_CPP_PLUGIN NAMES grpc_cpp_plugin)
 mark_as_advanced(GRPC_CPP_PLUGIN)
-#add_executable(gRPC::grpc_cpp_plugin IMPORTED)
-#set_target_properties(gRPC::grpc_cpp_plugin PROPERTIES
-#    IMPORTED_LOCATION ${GRPC_CPP_PLUGIN}
-#)
+add_executable(gRPC::grpc_cpp_plugin IMPORTED)
+set_target_properties(gRPC::grpc_cpp_plugin PROPERTIES
+    IMPORTED_LOCATION ${GRPC_CPP_PLUGIN}
+)
+
+file(
+    WRITE "${CMAKE_BINARY_DIR}/get_gRPC_version.cc"
+[====[
+#include <grpc++/grpc++.h>
+#include <iostream>
+int main() {
+  std::cout << grpc::Version(); // no newline to simplify CMake module
+  return 0;
+}
+]====])
+
+try_run(
+    _gRPC_GET_VERSION_STATUS
+    _gRPC_GET_VERSION_COMPILE_STATUS
+    "${CMAKE_BINARY_DIR}"
+    "${CMAKE_BINARY_DIR}/get_gRPC_version.cc"
+    CMAKE_FLAGS
+    -DCMAKE_CXX_STANDARD=11
+    LINK_LIBRARIES
+    gRPC::grpc++
+    gRPC::grpc
+    COMPILE_OUTPUT_VARIABLE _gRPC_GET_VERSION_COMPILE_OUTPUT
+    RUN_OUTPUT_VARIABLE gRPC_VERSION)
+
+file(REMOVE "${CMAKE_BINARY_DIR}/get_gRPC_version.cc")
 
 include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(gRPC DEFAULT_MSG
-    GRPC_LIBRARY GRPC_INCLUDE_DIR GRPC_GRPC++_REFLECTION_LIBRARY GRPC_CPP_PLUGIN)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(gRPC
+  FOUND_VAR gRPC_FOUND
+  REQUIRED_VARS GRPC_LIBRARY GPR_LIBRARY GRPC_INCLUDE_DIR GRPC_GRPC++_REFLECTION_LIBRARY GRPC_CPP_PLUGIN
+  VERSION_VAR gRPC_VERSION)