-
Notifications
You must be signed in to change notification settings - Fork 0
/
AbstractDirectoryView.vala
3051 lines (2452 loc) · 119 KB
/
AbstractDirectoryView.vala
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
Copyright (C) 2014 elementary Developers
This program is free software: you can redistribute it and/or modify it
under the terms of the GNU Lesser General Public License version 3, as published
by the Free Software Foundation.
This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranties of
MERCHANTABILITY, SATISFACTORY QUALITY, or FITNESS FOR A PARTICULAR
PURPOSE. See the GNU General Public License for more details.
You should have received a copy of the GNU General Public License along
with this program. If not, see <http://www.gnu.org/licenses/>.
Authors : Jeremy Wootten <jeremy@elementary.org>
*/
/** Implementations of AbstractDirectoryView are
* IconView
* ListView
* ColumnView
**/
namespace FM {
public abstract class AbstractDirectoryView : Gtk.ScrolledWindow {
public enum TargetType {
STRING,
TEXT_URI_LIST,
XDND_DIRECT_SAVE0,
NETSCAPE_URL
}
protected enum ClickZone {
EXPANDER,
HELPER,
ICON,
NAME,
BLANK_PATH,
BLANK_NO_PATH,
INVALID
}
const int MAX_TEMPLATES = 32;
const Gtk.TargetEntry [] drag_targets = {
{"text/plain", 0, TargetType.STRING},
{"text/uri-list", 0, TargetType.TEXT_URI_LIST}
};
const Gtk.TargetEntry [] drop_targets = {
{"text/uri-list", 0, TargetType.TEXT_URI_LIST},
{"XdndDirectSave0", 0, TargetType.TEXT_URI_LIST},
{"_NETSCAPE_URL", 0, TargetType.TEXT_URI_LIST}
};
const Gdk.DragAction file_drag_actions = (Gdk.DragAction.COPY | Gdk.DragAction.MOVE | Gdk.DragAction.LINK);
/* Menu Handling */
const GLib.ActionEntry [] selection_entries = {
{"open", on_selection_action_open_executable},
{"open_with_app", on_selection_action_open_with_app, "s"},
{"open_with_default", on_selection_action_open_with_default},
{"open_with_other_app", on_selection_action_open_with_other_app},
{"rename", on_selection_action_rename},
{"cut", on_selection_action_cut},
{"trash", on_selection_action_trash},
{"delete", on_selection_action_delete},
{"restore", on_selection_action_restore}
};
const GLib.ActionEntry [] background_entries = {
{"new", on_background_action_new, "s"},
{"create_from", on_background_action_create_from, "s"},
{"sort_by", on_background_action_sort_by_changed, "s", "'name'"},
{"reverse", on_background_action_reverse_changed, null, "false"},
{"show_hidden", null, null, "false", change_state_show_hidden}
};
const GLib.ActionEntry [] common_entries = {
{"copy", on_common_action_copy},
{"paste_into", on_common_action_paste_into},
{"open_in", on_common_action_open_in, "s"},
{"bookmark", on_common_action_bookmark},
{"properties", on_common_action_properties}
};
GLib.SimpleActionGroup common_actions;
GLib.SimpleActionGroup selection_actions;
GLib.SimpleActionGroup background_actions;
private Marlin.ZoomLevel _zoom_level;
public Marlin.ZoomLevel zoom_level {
get {
return _zoom_level;
}
set {
if (value <= maximum_zoom &&
value >= minimum_zoom &&
value != _zoom_level) {
_zoom_level = value;
on_zoom_level_changed (value);
}
}
}
public int icon_size {
get {
return Marlin.zoom_level_to_icon_size (_zoom_level);
}
}
protected Marlin.ZoomLevel minimum_zoom = Marlin.ZoomLevel.SMALLEST;
protected Marlin.ZoomLevel maximum_zoom = Marlin.ZoomLevel.LARGEST;
/* drag support */
uint drag_scroll_timer_id = 0;
uint drag_timer_id = 0;
uint drag_enter_timer_id = 0;
int drag_x = 0;
int drag_y = 0;
int drag_button;
protected int drag_delay = Gtk.Settings.get_default ().gtk_menu_popup_delay;
protected int drag_enter_delay = 1000;
Gdk.DragAction current_suggested_action = Gdk.DragAction.DEFAULT;
Gdk.DragAction current_actions = Gdk.DragAction.DEFAULT;
unowned GLib.List<unowned GOF.File> drag_file_list = null;
GOF.File? drop_target_file = null;
/* drop site support */
bool _drop_highlight;
bool drop_highlight {
get {
return _drop_highlight;
}
set {
if (value != _drop_highlight) {
if (value)
Gtk.drag_highlight (this);
else
Gtk.drag_unhighlight (this);
}
_drop_highlight = value;
}
}
private bool drop_data_ready = false; /* whether the drop data was received already */
private bool drop_occurred = false; /* whether the data was dropped */
private bool drag_has_begun = false;
protected bool dnd_disabled = false;
private void* drag_data;
private GLib.List<GLib.File> drop_file_list = null; /* the list of URIs that are contained in the drop data */
/* support for generating thumbnails */
uint thumbnail_request = 0;
uint thumbnail_source_id = 0;
Marlin.Thumbnailer thumbnailer = null;
/* TODO Support for preview see bug #1380139 (CONFIRMED, THIS WORKS WHEN INSTANTIATED WITH "gloobus-preview", (ASSUMING IT IS INSTALLED)*/
private string? previewer = null;
/* Rename support */
protected Marlin.TextRenderer? name_renderer = null;
unowned Marlin.AbstractEditableLabel? editable_widget = null;
public string original_name = "";
/* Support for zoom by smooth scrolling */
private double total_delta_y = 0.0;
/* UI options for button press handling */
protected bool single_click_rename = false;
protected bool activate_on_blank = true;
protected bool right_margin_unselects_all = false;
public bool single_click_mode {get; set;}
protected bool should_activate = false;
protected bool should_scroll = true;
protected uint click_zone = ClickZone.ICON;
protected uint previous_click_zone = ClickZone.ICON;
/* Cursors for different areas */
private Gdk.Cursor editable_cursor;
private Gdk.Cursor activatable_cursor;
private Gdk.Cursor blank_cursor;
private Gdk.Cursor selectable_cursor;
private GLib.List<GLib.AppInfo> open_with_apps;
protected GLib.List<GOF.Directory.Async>? loaded_subdirectories = null;
/* TODO: Remove the "unowned" portion of the declaration for
selected_files and on code that repeats its type.
Selected files are originally obtained with
gtk_tree_model_get(): this function increases the reference
count of the file object.
In order to prevent the obvious memory leak when inserting
these owned objects into the unowned element container, the
objects are unreferenced upon being inserted.
This results in a container filled with weak references to
objects with reference counts of 1.
A scenario may occur that the cell holding the original file
object is destroyed, and the container is left with pointers
pointing to freed memory. Reference counting the container
elements would prevent this possibility. */
protected GLib.List<unowned GOF.File> selected_files = null;
private GLib.List<unowned GOF.File>? templates = null;
private GLib.AppInfo default_app;
private Gtk.TreePath? hover_path = null;
private bool can_trash_or_delete = true;
/* Rapid keyboard paste support */
protected bool pasting_files = false;
protected bool select_added_files = false;
private HashTable? pasted_files = null;
public bool renaming {get; protected set; default = false;}
private bool updates_frozen = false;
protected bool tree_frozen = false;
private bool in_trash = false;
private bool in_network_root = false;
protected bool is_loading;
protected bool helpers_shown;
private Gtk.Widget view;
private unowned Marlin.ClipboardManager clipboard;
protected FM.ListModel model;
protected Marlin.IconRenderer icon_renderer;
protected unowned Marlin.View.Slot slot;
protected unowned Marlin.View.Window window; /*For convenience - this can be derived from slot */
protected static DndHandler dnd_handler = new FM.DndHandler ();
public signal void path_change_request (GLib.File location, int flag = 0, bool new_root = true);
public AbstractDirectoryView (Marlin.View.Slot _slot) {
slot = _slot;
window = _slot.window;
editable_cursor = new Gdk.Cursor (Gdk.CursorType.XTERM);
activatable_cursor = new Gdk.Cursor (Gdk.CursorType.HAND1);
selectable_cursor = new Gdk.Cursor (Gdk.CursorType.ARROW);
blank_cursor = new Gdk.Cursor (Gdk.CursorType.CROSSHAIR);
clipboard = ((Marlin.Application)(window.application)).get_clipboard_manager ();
icon_renderer = new Marlin.IconRenderer ();
thumbnailer = Marlin.Thumbnailer.get ();
model = GLib.Object.@new (FM.ListModel.get_type (), null) as FM.ListModel;
Preferences.settings.bind ("single-click", this, "single_click_mode", SettingsBindFlags.GET);
/* Currently, "single-click rename" is disabled, matching existing UI
* Currently, "activate on blank" is enabled, matching existing UI
* Currently, "right margin unselects all" is disabled, matching existing UI
*/
set_up__menu_actions ();
set_up_directory_view ();
view = create_view ();
if (view != null) {
add (view);
show_all ();
connect_drag_drop_signals (view);
view.add_events (Gdk.EventMask.POINTER_MOTION_MASK);
view.motion_notify_event.connect (on_motion_notify_event);
view.leave_notify_event.connect (on_leave_notify_event);
view.enter_notify_event.connect (on_enter_notify_event);
view.key_press_event.connect (on_view_key_press_event);
view.button_press_event.connect (on_view_button_press_event);
view.button_release_event.connect (on_view_button_release_event);
view.draw.connect (on_view_draw);
}
freeze_tree (); /* speed up loading of icon view. Thawed when directory loaded */
set_up_zoom_level ();
change_zoom_level ();
}
~AbstractDirectoryView () {
debug ("ADV destruct");
loaded_subdirectories.@foreach ((dir) => {
remove_subdirectory (dir);
});
}
protected virtual void set_up_name_renderer () {
name_renderer.editable = false;
name_renderer.follow_state = true;
name_renderer.edited.connect (on_name_edited);
name_renderer.editing_canceled.connect (on_name_editing_canceled);
name_renderer.editing_started.connect (on_name_editing_started);
}
private void set_up_directory_view () {
set_policy (Gtk.PolicyType.AUTOMATIC, Gtk.PolicyType.AUTOMATIC);
set_shadow_type (Gtk.ShadowType.NONE);
size_allocate.connect_after (on_size_allocate);
button_press_event.connect (on_button_press_event);
popup_menu.connect (on_popup_menu);
unrealize.connect (() => {
clipboard.changed.disconnect (on_clipboard_changed);
});
realize.connect (() => {
clipboard.changed.connect (on_clipboard_changed);
on_clipboard_changed ();
});
scroll_event.connect (on_scroll_event);
get_vadjustment ().value_changed.connect ((alloc) => {
schedule_thumbnail_timeout ();
});
(GOF.Preferences.get_default ()).notify["show-hidden-files"].connect (on_show_hidden_files_changed);
(GOF.Preferences.get_default ()).notify["interpret-desktop-files"].connect (on_interpret_desktop_files_changed);
connect_directory_handlers (slot.directory);
model.row_deleted.connect (on_row_deleted);
model.sort_column_changed.connect (on_sort_column_changed);
model.set_sort_column_id (slot.directory.file.sort_column_id, slot.directory.file.sort_order);
}
private void set_up__menu_actions () {
selection_actions = new GLib.SimpleActionGroup ();
selection_actions.add_action_entries (selection_entries, this);
insert_action_group ("selection", selection_actions);
background_actions = new GLib.SimpleActionGroup ();
background_actions.add_action_entries (background_entries, this);
insert_action_group ("background", background_actions);
common_actions = new GLib.SimpleActionGroup ();
common_actions.add_action_entries (common_entries, this);
insert_action_group ("common", common_actions);
action_set_state (background_actions, "show_hidden", Preferences.settings.get_boolean ("show-hiddenfiles"));
}
public void zoom_in () {
zoom_level = zoom_level + 1;
}
public void zoom_out () {
zoom_level = zoom_level - 1;
}
private void set_up_zoom_level () {
zoom_level = get_set_up_zoom_level ();
model.set_property ("size", icon_size);
}
public void zoom_normal () {
zoom_level = get_normal_zoom_level ();
}
public void select_first_for_empty_selection () {
if (selected_files == null)
set_cursor (new Gtk.TreePath.from_indices (0), false, true, true);
}
public void select_glib_files (GLib.List<GLib.File> location_list, GLib.File? focus_location) {
unselect_all ();
GLib.List<GOF.File>? file_list = null;
location_list.@foreach ((loc) => {
file_list.prepend (GOF.File.@get (loc));
});
/* Because the Icon View disconnects the model while loading, we need to wait until
* the tree is thawed and the model reconnected before selecting the files */
Idle.add (() => {
bool try_again = true;
if (!tree_frozen) {
try_again = false;
file_list.@foreach ((file) => {
var iter = Gtk.TreeIter ();
if (model.get_first_iter_for_file (file, out iter)) {
Gtk.TreePath path = model.get_path (iter);
if (path != null) {
if (focus_location != null && focus_location.equal (file.location))
set_cursor (path, false, true, false); /* set cursor and select */
else
select_path (path);
}
} else {
/* model has not caught up yet - wait a bit */
try_again = true;
}
});
}
return try_again;
});
}
public unowned GLib.List<GLib.AppInfo> get_open_with_apps () {
return open_with_apps;
}
public unowned GLib.AppInfo get_default_app () {
return default_app;
}
public void set_updates_frozen (bool freeze) {
if (freeze && !updates_frozen)
freeze_updates ();
else if (!freeze && updates_frozen)
unfreeze_updates ();
}
public bool get_updates_frozen () {
return updates_frozen;
}
protected void freeze_updates () {
updates_frozen = true;
slot.directory.freeze_update = true;
action_set_enabled (selection_actions, "cut", false);
action_set_enabled (common_actions, "copy", false);
action_set_enabled (common_actions, "paste_into", false);
action_set_enabled (window.win_actions, "select_all", false);
size_allocate.disconnect (on_size_allocate);
clipboard.changed.disconnect (on_clipboard_changed);
view.enter_notify_event.disconnect (on_enter_notify_event);
view.key_press_event.disconnect (on_view_key_press_event);
}
protected void unfreeze_updates () {
updates_frozen = false;
slot.directory.freeze_update = false;
update_menu_actions ();
size_allocate.connect (on_size_allocate);
clipboard.changed.connect (on_clipboard_changed);
view.enter_notify_event.connect (on_enter_notify_event);
view.key_press_event.connect (on_view_key_press_event);
}
public new void grab_focus () {
if (view.get_realized ())
view.grab_focus ();
else { /* wait until realized */
GLib.Timeout.add (100, () => {
view.grab_focus ();
return !view.get_realized ();
});
}
}
public unowned GLib.List<unowned GOF.File> get_selected_files () {
return selected_files;
}
public bool is_frozen () {
return updates_frozen;
}
/*** Protected Methods */
protected void set_active_slot (bool scroll = true) {
slot.active (scroll);
}
protected void load_location (GLib.File location) {
path_change_request (location, Marlin.OpenFlag.DEFAULT, false);
}
protected void load_root_location (GLib.File location) {
path_change_request (location, Marlin.OpenFlag.DEFAULT, true);
}
/** Operations on selections */
protected void activate_selected_items (Marlin.OpenFlag flag = Marlin.OpenFlag.DEFAULT,
GLib.List<unowned GOF.File> selection = get_selected_files ()) {
if (updates_frozen || in_trash)
return;
uint nb_elem = selection.length ();
if (nb_elem < 1)
return;
unowned Gdk.Screen screen = Eel.gtk_widget_get_screen (this);
if (nb_elem == 1) {
activate_file (selection.data, screen, flag, true);
return;
}
if (nb_elem < 10 && (default_app == null)) {
/* launch each selected file individually ignoring selections greater than 10 */
foreach (unowned GOF.File file in selection) {
/* Prevent too rapid activation of files - causes New Tab to crash for example */
if (file.is_folder ()) {
GLib.Timeout.add (50, () => {
activate_file (file, screen, flag, false);
return false;
});
} else
file.open_single (screen, null);
}
} else if (default_app != null) {
open_files_with (default_app, selection);
}
}
protected void preview_selected_items () {
if (previewer == null) {
activate_selected_items (Marlin.OpenFlag.DEFAULT);
} else {
unowned GLib.List<unowned GOF.File>? selection = get_selected_files ();
if (selection != null) {
/*
* This is here to prevent the previewer from capturing the space bar press event and closing immediately.
* It should likely be replaced by some better solution.
*/
Thread.usleep (200000);
Gdk.Screen screen = Eel.gtk_widget_get_screen (this);
GLib.List<GLib.File> location_list = null;
GOF.File file = selection.data;
location_list.prepend (file.location);
Gdk.AppLaunchContext context = screen.get_display ().get_app_launch_context ();
try {
GLib.AppInfo previewer_app = GLib.AppInfo.create_from_commandline (previewer, null, 0);
previewer_app.launch (location_list, context as GLib.AppLaunchContext);
previewer_app.@delete ();
} catch (GLib.Error error) {
Eel.show_error_dialog (_("Failed to preview"), error.message, null);
}
}
}
}
protected void select_gof_file (GOF.File file) {
var iter = Gtk.TreeIter ();
if (!model.get_first_iter_for_file (file, out iter))
return; /* file not in model */
var path = model.get_path (iter);
set_cursor (path, false, true, false);
}
protected void add_gof_file_to_selection (GOF.File file) {
var iter = Gtk.TreeIter ();
if (!model.get_first_iter_for_file (file, out iter))
return; /* file not in model */
var path = model.get_path (iter);
select_path (path);
}
/** Directory signal handlers. */
/* Signal could be from subdirectory as well as slot directory */
protected void connect_directory_handlers (GOF.Directory.Async dir) {
assert (dir != null);
dir.file_loaded.connect (on_directory_file_loaded);
dir.file_added.connect (on_directory_file_added);
dir.file_changed.connect (on_directory_file_changed);
dir.file_deleted.connect (on_directory_file_deleted);
dir.icon_changed.connect (on_directory_file_icon_changed);
dir.done_loading.connect (on_directory_done_loading);
dir.thumbs_loaded.connect (on_directory_thumbs_loaded);
}
protected void disconnect_directory_handlers (GOF.Directory.Async dir) {
/* If the directory is still loading the file_loaded signal handler
/* will not have been disconnected */
if (dir.is_loading ())
dir.file_loaded.disconnect (on_directory_file_loaded);
dir.file_added.disconnect (on_directory_file_added);
dir.file_changed.disconnect (on_directory_file_changed);
dir.file_deleted.disconnect (on_directory_file_deleted);
dir.icon_changed.disconnect (on_directory_file_icon_changed);
dir.done_loading.disconnect (on_directory_done_loading);
dir.thumbs_loaded.disconnect (on_directory_thumbs_loaded);
}
public void change_directory (GOF.Directory.Async old_dir, GOF.Directory.Async new_dir) {
cancel_thumbnailing ();
freeze_tree ();
old_dir.cancel ();
disconnect_directory_handlers (old_dir);
block_model ();
loaded_subdirectories.@foreach ((dir) => {
remove_subdirectory (dir);
});
loaded_subdirectories = null;
model.clear ();
unblock_model ();
if (new_dir.can_load)
connect_directory_handlers (new_dir);
}
public void reload () {
slot.directory.clear_directory_info ();
change_directory (slot.directory, slot.directory);
}
protected void connect_drag_drop_signals (Gtk.Widget widget) {
/* Set up as drop site */
Gtk.drag_dest_set (widget, Gtk.DestDefaults.MOTION, drop_targets, Gdk.DragAction.ASK | file_drag_actions);
widget.drag_drop.connect (on_drag_drop);
widget.drag_data_received.connect (on_drag_data_received);
widget.drag_leave.connect (on_drag_leave);
widget.drag_motion.connect (on_drag_motion);
/* Set up as drag source */
Gtk.drag_source_set (widget, Gdk.ModifierType.BUTTON1_MASK, drag_targets, file_drag_actions);
widget.drag_begin.connect (on_drag_begin);
widget.drag_data_get.connect (on_drag_data_get);
widget.drag_data_delete.connect (on_drag_data_delete);
widget.drag_end.connect (on_drag_end);
}
protected void cancel_drag_timer () {
disconnect_drag_timeout_motion_and_release_events ();
cancel_timeout (ref drag_timer_id);
}
protected void cancel_thumbnailing () {
slot.directory.cancel ();
cancel_timeout (ref thumbnail_source_id);
if (thumbnail_request > 0) {
thumbnailer.dequeue (thumbnail_request);
thumbnail_request = 0;
}
}
protected bool is_drag_pending () {
return drag_has_begun;
}
protected bool selection_only_contains_folders (GLib.List<unowned GOF.File> list) {
bool only_folders = true;
list.@foreach ((file) => {
if (!(file.is_folder () || file.is_root_network_folder ()))
only_folders = false;
});
return only_folders;
}
/** Handle scroll events */
protected bool handle_scroll_event (Gdk.EventScroll event) {
if (updates_frozen)
return true;
if ((event.state & Gdk.ModifierType.CONTROL_MASK) > 0) {
switch (event.direction) {
case Gdk.ScrollDirection.UP:
zoom_in ();
return true;
case Gdk.ScrollDirection.DOWN:
zoom_out ();
return true;
case Gdk.ScrollDirection.SMOOTH:
double delta_x, delta_y;
event.get_scroll_deltas (out delta_x, out delta_y);
/* try to emulate a normal scrolling event by summing deltas.
* step size of 0.5 chosen to match sensitivity */
total_delta_y += delta_y;
if (total_delta_y >= 0.5) {
total_delta_y = 0;
zoom_out ();
} else if (total_delta_y <= -0.5) {
total_delta_y = 0;
zoom_in ();
}
return true;
default:
break;
}
}
return false;
}
protected void show_or_queue_context_menu (Gdk.Event event) {
if (selected_files != null)
queue_context_menu (event);
else
show_context_menu (event);
}
protected unowned GLib.List<unowned GOF.File> get_selected_files_for_transfer (GLib.List<unowned GOF.File> selection = get_selected_files ()) {
unowned GLib.List<unowned GOF.File> list = null;
selection.@foreach ((file) => {
list.prepend (file);
});
return list;
}
/*** Private methods */
/** File operations */
private void activate_file (GOF.File file, Gdk.Screen? screen, Marlin.OpenFlag flag, bool only_one_file) {
if (updates_frozen || in_trash)
return;
GLib.File location = file.get_target_location ();
if (screen == null)
screen = Eel.gtk_widget_get_screen (this);
default_app = Marlin.MimeActions.get_default_application_for_file (file);
if (file.is_folder () ||
file.get_ftype () == "inode/directory" ||
file.is_root_network_folder ()) {
switch (flag) {
case Marlin.OpenFlag.NEW_TAB:
window.add_tab (location, Marlin.ViewMode.CURRENT);
break;
case Marlin.OpenFlag.NEW_WINDOW:
window.add_window(location, Marlin.ViewMode.CURRENT);
break;
default:
if (only_one_file)
load_location (location);
break;
}
} else if (only_one_file && file.is_root_network_folder ())
load_location (location);
else if (only_one_file && file.is_executable ())
file.execute (screen, null, null);
else if (only_one_file && default_app != null)
file.open_single (screen, default_app);
else
warning ("Unable to activate this file. Default app is %s",
default_app != null ? default_app.get_name () : "null");
}
private void trash_or_delete_files (GLib.List<unowned GOF.File> file_list,
bool delete_if_already_in_trash,
bool delete_immediately) {
GLib.List<GLib.File> locations = null;
file_list.@foreach ((file) => {
locations.prepend (file.location);
});
if (locations != null) {
locations.reverse ();
if (delete_immediately)
Marlin.FileOperations.@delete (locations,
window as Gtk.Window,
after_trash_or_delete,
this);
else
Marlin.FileOperations.trash_or_delete (locations,
window as Gtk.Window,
after_trash_or_delete,
this);
}
}
private void add_file (GOF.File file, GOF.Directory.Async dir) {
model.add_file (file, dir);
if (select_added_files)
add_gof_file_to_selection (file);
}
private void new_empty_file (string? parent_uri = null) {
if (parent_uri == null)
parent_uri = slot.directory.file.uri;
/* Block the async directory file monitor to avoid generating unwanted "add-file" events */
slot.directory.block_monitor ();
Marlin.FileOperations.new_file (this as Gtk.Widget,
null,
parent_uri,
null,
null,
0,
(Marlin.CreateCallback?) create_file_done,
this);
}
private void new_empty_folder () {
Marlin.FileOperations.new_folder (null, null, slot.location, (Marlin.CreateCallback?) create_file_done, this);
}
protected void rename_file (GOF.File file_to_rename) {
unselect_all ();
select_gof_file (file_to_rename);
/* Assume writability on remote locations
* TODO Reliably determine writability with various remote protocols.
*/
if (file_to_rename.is_writable () || !slot.directory.is_local)
start_renaming_file (file_to_rename, false);
else
warning ("You do not have permission to rename this file");
}
/** File operation callbacks */
static void create_file_done (GLib.File? new_file, void* data) {
if (new_file == null)
return;
var view = data as FM.AbstractDirectoryView;
if (view == null) {
warning ("View invalid after creating file");
return;
}
var file_to_rename = GOF.File.@get (new_file);
bool local = view.slot.directory.is_local;
if (!local)
view.slot.directory.need_reload ();
/* Allow time for the file to appear in the tree model before renaming
* Wait longer for remote locations to allow for reload.
* TODO: Remove need for hard coded delay.
*/
int delay = local ? 250 : 500;
GLib.Timeout.add (delay, () => {
view.rename_file (file_to_rename);
view.slot.directory.unblock_monitor ();
return false;
});
}
/** Must pass a pointer to an instance of FM.AbstractDirectoryView as 3rd parameter when
* using this callback */
public static void after_trash_or_delete (bool user_cancel, void* data) {
var view = data as FM.AbstractDirectoryView;
if (view == null)
return;
view.can_trash_or_delete = true;
if (!view.slot.directory.is_local)
view.slot.directory.need_reload ();
}
private void trash_or_delete_selected_files (bool delete_immediately = false) {
/* This might be rapidly called multiple times for the same selection
* when using keybindings. So we remember if the current selection
* was already removed (but the view doesn't know about it yet).
*/
if (!can_trash_or_delete)
return;
unowned GLib.List<unowned GOF.File> selection = get_selected_files_for_transfer ();
if (selection != null) {
can_trash_or_delete = false;
trash_or_delete_files (selection, true, delete_immediately);
}
}
private void delete_selected_files () {
unowned GLib.List<unowned GOF.File> selection = get_selected_files_for_transfer ();
if (selection == null)
return;
GLib.List<GLib.File> locations = null;
selection.@foreach ((file) => {
locations.prepend (file.location);
});
locations.reverse ();
Marlin.FileOperations.@delete (locations, window as Gtk.Window, after_trash_or_delete, this);
}
/** Signal Handlers */
/** Menu actions */
/** Selection actions */
private void on_selection_action_rename (GLib.SimpleAction action, GLib.Variant? param) {
rename_selected_file ();
}
private void rename_selected_file () {
if (selected_files == null)
return;
if (selected_files.next != null)
/* TODO invoke batch renamer see bug #1014122*/
warning ("Cannot rename multiple files (yet) - renaming first only");
var file = selected_files.first ().data;
bool preselect_whole_name = file.is_folder ();
start_renaming_file (file, preselect_whole_name);
}
private void on_selection_action_cut (GLib.SimpleAction action, GLib.Variant? param) {
unowned GLib.List<unowned GOF.File> selection = get_selected_files_for_transfer ();
clipboard.cut_files (selection);
}
private void on_selection_action_trash (GLib.SimpleAction action, GLib.Variant? param) {
trash_or_delete_selected_files (false);
}
private void on_selection_action_delete (GLib.SimpleAction action, GLib.Variant? param) {
trash_or_delete_selected_files (true);
}
private void on_selection_action_restore (GLib.SimpleAction action, GLib.Variant? param) {
unowned GLib.List<unowned GOF.File> selection = get_selected_files_for_transfer ();
Marlin.restore_files_from_trash (selection, window);
}
private void on_selection_action_open_executable (GLib.SimpleAction action, GLib.Variant? param) {
unowned GLib.List<unowned GOF.File> selection = get_files_for_action ();
GOF.File file = selection.data as GOF.File;
unowned Gdk.Screen screen = Eel.gtk_widget_get_screen (this);
file.execute (screen, null, null);
}
private void on_selection_action_open_with_default (GLib.SimpleAction action, GLib.Variant? param) {
activate_selected_items (Marlin.OpenFlag.DEFAULT);
}
private void on_selection_action_open_with_app (GLib.SimpleAction action, GLib.Variant? param) {
var index = int.parse (param.get_string ());
open_files_with (open_with_apps.nth_data ((uint)index), get_files_for_action ());
}
private void on_selection_action_open_with_other_app () {
unowned GLib.List<unowned GOF.File> selection = get_files_for_action ();
GOF.File file = selection.data as GOF.File;
Gtk.DialogFlags flags = Gtk.DialogFlags.MODAL |
Gtk.DialogFlags.DESTROY_WITH_PARENT;
var dialog = new Gtk.AppChooserDialog (window, flags, file.location);
dialog.set_deletable (false);
var app_chooser = dialog.get_widget () as Gtk.AppChooserWidget;
app_chooser.set_show_recommended (true);
var check_default = new Gtk.CheckButton.with_label (_("Set as default"));
check_default.set_active (true);
check_default.show ();
var action_area = dialog.get_action_area () as Gtk.ButtonBox;
action_area.add (check_default);
action_area.set_child_secondary (check_default, true);
dialog.show ();
int response = dialog.run ();
if (response == Gtk.ResponseType.OK) {
var app =dialog.get_app_info ();
if (check_default.get_active ()) {
try {
app.set_as_default_for_type (file.get_ftype ());
}
catch (GLib.Error error) {
critical ("Could not set as default: %s", error.message);
}
}
open_files_with (app, selection);