-
Notifications
You must be signed in to change notification settings - Fork 16
/
lgtreap.pas
2958 lines (2728 loc) · 80.9 KB
/
lgtreap.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{****************************************************************************
* *
* This file is part of the LGenerics package. *
* Some generic treap variants. *
* *
* Copyright(c) 2019-2021 A.Koverdyaev(avk) *
* *
* This code is free software; you can redistribute it and/or modify it *
* under the terms of the Apache License, Version 2.0; *
* You may obtain a copy of the License at *
* http://www.apache.org/licenses/LICENSE-2.0. *
* *
* Unless required by applicable law or agreed to in writing, software *
* distributed under the License is distributed on an "AS IS" BASIS, *
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. *
* See the License for the specific language governing permissions and *
* limitations under the License. *
* *
*****************************************************************************}
unit lgTreap;
{$MODE OBJFPC}{$H+}
{$INLINE ON}
{$MODESWITCH ADVANCEDRECORDS}
{$MODESWITCH NESTEDPROCVARS}
interface
uses
SysUtils, Math,
lgUtils,
lgBstUtils,
{%H-}lgHelpers,
lgStrConst;
type
{ TGLiteTreap implements randomized Cartesian BST(only);
on assignment and when passed by value, the whole treap is copied;
functor TCmpRel (comparison relation) must provide:
class function Less([const[ref]] L, R: TKey): Boolean; }
generic TGLiteTreap<TKey, TValue, TCmpRel> = record
public
type
PNode = ^TNode;
TNode = record
private
FLeft,
FRight: PNode;
FKey: TKey;
FPrio: SizeUInt;
public
Value: TValue;
property Left: PNode read FLeft;
property Right: PNode read FRight;
property Key: TKey read FKey;
end;
TUtil = specialize TGBstUtil<TKey, TNode, TCmpRel>;
TOnVisit = TUtil.TOnVisit;
TNestVisit = TUtil.TNestVisit;
TEntry = specialize TGMapEntry<TKey, TValue>;
TEntryArray = array of TEntry;
private
FRoot: PNode;
function GetCount: SizeInt;
function GetHeight: SizeInt;
class function NewNode(const aKey: TKey): PNode; static;
class function CopyTree(aRoot: PNode): PNode; static;
{ splits tree of aRoot into two subtrees, where min(R.Key) >= aKey }
class procedure SplitNode(const aKey: TKey; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class procedure AddNode(var aRoot: PNode; aNode: PNode); static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode): Boolean; static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode; out v: TValue): Boolean; static;
class operator Initialize(var aTreap: TGLiteTreap);
class operator Finalize(var aTreap: TGLiteTreap);
class operator Copy(constref aSrc: TGLiteTreap; var aDst: TGLiteTreap);
class operator AddRef(var aTreap: TGLiteTreap);
public
{ splits aTreap so that L will contain all keys < aKey and R will contain all keys >= aKey;
aTreap becomes empty }
class procedure Split(const aKey: TKey; var aTreap: TGLiteTreap; out L, R: TGLiteTreap); static;
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TEntryArray; //O(N)
function Find(const aKey: TKey): PNode; //O(LogN)
function CountOf(const aKey: TKey): SizeInt;//O(N)
function Add(const aKey: TKey): PNode; //O(LogN)
function Remove(const aKey: TKey): Boolean; //O(LogN)
function Remove(const aKey: TKey; out aValue: TValue): Boolean; //O(LogN)
{ splits treap so that aTreap will contain all elements with keys >= aKey }
procedure Split(const aKey: TKey; out aTreap: TGLiteTreap);//O(LogN)
property Root: PNode read FRoot; //O(1)
property Count: SizeInt read GetCount; //O(N)
property Height: SizeInt read GetHeight; //O(N)
end;
{ TGLiteIdxTreap implements randomized Cartesian BST which allows indexing access
(IOW rank and N-th order statistics)
on assignment and when passed by value, the whole treap is copied;
functor TCmpRel (comparison relation) must provide:
class function Less([const[ref]] L, R: TKey): Boolean; }
generic TGLiteIdxTreap<TKey, TValue, TCmpRel> = record
public
type
PNode = ^TNode;
TNode = record
private
FLeft,
FRight: PNode;
FKey: TKey;
FPrio: SizeUInt;
FSize: SizeInt;
public
Value: TValue;
property Left: PNode read FLeft;
property Right: PNode read FRight;
property Key: TKey read FKey;
property Size: SizeInt read FSize;
end;
TUtil = specialize TGIndexedBstUtil<TKey, TNode, TCmpRel>;
TOnVisit = TUtil.TOnVisit;
TNestVisit = TUtil.TNestVisit;
TEntry = specialize TGMapEntry<TKey, TValue>;
TEntryArray = array of TEntry;
private
FRoot: PNode;
function GetCount: SizeInt; inline;
function GetHeight: SizeInt;
function GetItem(aIndex: SizeInt): PNode; inline;
procedure CheckIndexRange(aIndex: SizeInt); inline;
class function NewNode(const aKey: TKey): PNode; static;
class function CopyTree(aRoot: PNode): PNode; static;
class procedure UpdateSize(aNode: PNode); static; inline;
class procedure SplitNode(const aKey: TKey; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class procedure AddNode(var aRoot: PNode; aNode: PNode); static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode): Boolean; static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode; out v: TValue): Boolean; static;
class operator Initialize(var aTreap: TGLiteIdxTreap);
class operator Finalize(var aTreap: TGLiteIdxTreap);
class operator Copy(constref aSrc: TGLiteIdxTreap; var aDst: TGLiteIdxTreap);
class operator AddRef(var aTreap: TGLiteIdxTreap); inline;
public
{ splits aTreap so that L will contain all keys < aKey and R will contain all keys >= aKey;
aTreap becomes empty }
class procedure Split(const aKey: TKey; var aTreap: TGLiteIdxTreap; out L, R: TGLiteIdxTreap); static;
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TEntryArray; //O(N)
function Find(const aKey: TKey): PNode; //O(LogN)
function IndexOf(const aKey: TKey): SizeInt; inline;//O(LogN)
function CountOf(const aKey: TKey): SizeInt; //O(LogN)
function Add(const aKey: TKey): PNode; //O(LogN)
function Remove(const aKey: TKey): Boolean; //O(LogN)
function Remove(const aKey: TKey; out aValue: TValue): Boolean;//O(LogN)
{ splits treap so that aTreap will contain all elements with keys >= aKey }
procedure Split(const aKey: TKey; out aTreap: TGLiteIdxTreap); //O(LogN)
property Root: PNode read FRoot; //O(1)
property Count: SizeInt read GetCount; //O(1)
property Height: SizeInt read GetHeight; //O(N)
property Items[aIndex: SizeInt]: PNode read GetItem; default;//O(LogN)
end;
{ TGLiteSegmentTreap implements randomized Cartesian BST with unique keys which allows
indexing access and allows find the value of the monoid function on an arbitrary
range of keys in O(log N); on assignment and when passed by value, the whole treap is copied;
functor TCmpRel (comparision relation) must provide:
class function Less([const[ref]] L, R: TKey): Boolean;
functor TValMonoid must provide:
class field/property/function Identity: TValue; - neutral element of the monoid;
associative dyadic function BinOp([const[ref]] L, R: TValue): TValue; }
generic TGLiteSegmentTreap<TKey, TValue, TCmpRel, TValMonoid> = record
public
type
TEntry = specialize TGMapEntry<TKey, TValue>;
TEntryArray = array of TEntry;
private
type
PNode = ^TNode;
TNode = record
Left,
Right: PNode;
Key: TKey;
Prio: SizeUInt;
Size: SizeInt;
CacheVal,
Value: TValue;
end;
TUtil = specialize TGIndexedBstUtil<TKey, TNode, TCmpRel>;
var
FRoot: PNode;
function GetCount: SizeInt; inline;
function GetHeight: SizeInt; inline;
function GetValue(const aKey: TKey): TValue;
procedure CheckIndexRange(aIndex: SizeInt); inline;
function GetEntry(aIndex: SizeInt): TEntry;
procedure SetValue(const aKey: TKey; const aValue: TValue);
class function NewNode(const aKey: TKey; const aValue: TValue): PNode; static;
class function CopyTree(aRoot: PNode): PNode; static;
class procedure UpdateNode(aNode: PNode); static; inline;
class procedure UpdateCache(aNode: PNode); static; inline;
class function UpdateValue(aRoot: PNode; const aKey: TKey; const aValue: TValue): Boolean; static;
class procedure SplitNode(const aKey: TKey; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class procedure AddNode(var aRoot: PNode; aNode: PNode); static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode): Boolean; static;
class function RemoveNode(const aKey: TKey; var aRoot: PNode; out v: TValue): Boolean; static;
class operator Initialize(var aTreap: TGLiteSegmentTreap);
class operator Finalize(var aTreap: TGLiteSegmentTreap);
class operator Copy(constref aSrc: TGLiteSegmentTreap; var aDst: TGLiteSegmentTreap);
class operator AddRef(var aTreap: TGLiteSegmentTreap); inline;
public
class procedure Split(const aKey: TKey; var aTreap: TGLiteSegmentTreap;
out L, R: TGLiteSegmentTreap); static;
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TEntryArray; //O(N)
function Contains(const aKey: TKey): Boolean; //O(LogN)
function Find(const aKey: TKey; out aValue: TValue): Boolean; //O(LogN)
function FindLess(const aKey: TKey; out aLess: TKey): Boolean;
function FindLessOrEqual(const aKey: TKey; out aLessOrEq: TKey): Boolean;
function FindGreater(const aKey: TKey; out aGreater: TKey): Boolean;
function FindGreaterOrEqual(const aKey: TKey; out aGreaterOrEq: TKey): Boolean;
function IndexOf(const aKey: TKey): SizeInt; inline; //O(LogN)
function Add(const aKey: TKey; const aValue: TValue): Boolean;//O(LogN)
function Add(const e: TEntry): Boolean; inline; //O(LogN)
function Remove(const aKey: TKey): Boolean; //O(LogN)
function Remove(const aKey: TKey; out aValue: TValue): Boolean; //O(LogN)
procedure Split(const aKey: TKey; out aTreap: TGLiteSegmentTreap);//O(LogN)
{ returns value of the monoid function on the segment[L, R](indices);
raises exception if L or R out of bounds }
function RangeQueryI(L, R: SizeInt): TValue; //O(LogN)
{ returns value of the monoid function on the half-open interval[L, R) }
function RangeQuery(const L, R: TKey): TValue; //O(LogN)
{ returns value of the monoid function on the half-open interval[L, R)
and the number of elements that fit into this interval in aCount }
function RangeQuery(const L, R: TKey; out aCount: SizeInt): TValue;
{ returns value of the monoid function on the segment[0, aIndex](indices);
raises exception if aIndex out of bounds }
function HeadQueryI(aIndex: SizeInt): TValue; //O(LogN)
{ returns value of the monoid function on the half-open interval[Lowest(key), aKey) }
function HeadQuery(const aKey: TKey): TValue; //O(LogN)
{ returns value of the monoid function on the half-open interval[Lowest(key), aKey)
and the number of elements that fit into this interval in aCount }
function HeadQuery(const aKey: TKey; out aCount: SizeInt): TValue;
{ returns value of the monoid function on the segment[aIndex, Pred(Count)](indices);
raises exception if aIndex out of bounds }
function TailQueryI(aIndex: SizeInt): TValue; //O(LogN)
{ returns value of the monoid function on the segment[aKey, Highest(key)] }
function TailQuery(const aKey: TKey): TValue; //O(LogN)
{ returns value of the monoid function on the segment[aKey, Highest(key)]
and the number of elements that fit into this interval in aCount }
function TailQuery(const aKey: TKey; out aCount: SizeInt): TValue;
property Count: SizeInt read GetCount; //O(1)
property Height: SizeInt read GetHeight; //O(N)
property Entries[aIndex: SizeInt]: TEntry read GetEntry;//O(LogN)
{ if not contains aKey then read returns TValMonoid.Identity }
property Values[const aKey: TKey]: TValue read GetValue write SetValue; default;//O(LogN)
end;
{ TGLiteImplicitTreap implements randomized Cartesian tree which mimics
an array with most operations in O(LogN); on assignment and when passed by value,
the whole treap is copied; }
generic TGLiteImplicitTreap<T> = record
public
type
TArray = array of T;
private
type
PNode = ^TNode;
TNode = record
private
Left,
Right: PNode;
Prio: SizeUInt;
Size: SizeInt;
Value: T;
property Key: SizeInt read Size;
end;
TUtil = specialize TGIndexedBstUtil<SizeInt, TNode, SizeInt>;
var
FRoot: PNode;
function GetCount: SizeInt; inline;
function GetHeight: SizeInt;
procedure CheckIndexRange(aIndex: SizeInt); inline;
procedure CheckInsertRange(aIndex: SizeInt); inline;
function GetItem(aIndex: SizeInt): T;
procedure SetItem(aIndex: SizeInt; const aValue: T);
class function NewNode(const aValue: T): PNode; static; inline;
class function CopyTree(aRoot: PNode): PNode; static;
class procedure UpdateSize(aNode: PNode); static; inline;
class procedure SplitNode(aIdx: SizeInt; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class procedure DeleteNode(aIndex: SizeInt; var aRoot: PNode; out aValue: T); static;
class operator Initialize(var aTreap: TGLiteImplicitTreap);
class operator Finalize(var aTreap: TGLiteImplicitTreap);
class operator Copy(constref aSrc: TGLiteImplicitTreap; var aDst: TGLiteImplicitTreap);
class operator AddRef(var aTreap: TGLiteImplicitTreap); inline;
public
class procedure Split(aIndex: SizeInt; var aTreap: TGLiteImplicitTreap;
out L, R: TGLiteImplicitTreap); static;
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TArray; //O(N)
function Add(const aValue: T): SizeInt; //O(LogN)
procedure Insert(aIndex: SizeInt; const aValue: T);//O(LogN)
procedure Insert(aIndex: SizeInt; var aTreap: TGLiteImplicitTreap);
function Delete(aIndex: SizeInt): T; //O(LogN)
procedure Split(aIndex: SizeInt; out aTreap: TGLiteImplicitTreap);
procedure Split(aIndex, aCount: SizeInt; out aTreap: TGLiteImplicitTreap);//O(LogN)
procedure Merge(var aTreap: TGLiteImplicitTreap); //O(LogN)
procedure RotateLeft(aDist: SizeInt); //O(LogN)
procedure RotateRight(aDist: SizeInt); //O(LogN)
property Count: SizeInt read GetCount; //O(1)
property Height: SizeInt read GetHeight; //O(N)
property Items[aIndex: SizeInt]: T read GetItem write SetItem; default; //O(LogN)
end;
{ TGLiteImplSegmentTreap implements randomized Cartesian tree which mimics an array;
it allows:
- add an element to the array in O(log N);
- update a single element of an array in O(log N);
- add an arbitrary range of elements to the array in O(log N);
- find the value: TResult of the monoid function on an arbitrary range
of array elements in O(log N);
type TResult must provide an assignment operator (TResult := T)
functor TMonoid must provide:
class field/property/function Identity: TResult; - neutral element of the monoid;
associative dyadic function BinOp([const[ref]] L, R: TResult): TResult;
on assignment and when passed by value, the whole treap is copied; }
generic TGLiteImplSegmentTreap<T, TResult, TMonoid> = record
public
type
TArray = array of T;
private
type
PNode = ^TNode;
TNode = record
private
Left,
Right: PNode;
Prio: SizeUInt;
Size: SizeInt;
Value: T;
CacheVal: TResult;
property Key: SizeInt read Size;
end;
TUtil = specialize TGIndexedBstUtil<SizeInt, TNode, SizeInt>;
var
FRoot: PNode;
function GetCount: SizeInt; inline;
function GetHeight: SizeInt;
procedure CheckIndexRange(aIndex: SizeInt); inline;
procedure CheckInsertRange(aIndex: SizeInt); inline;
function GetItem(aIndex: SizeInt): T;
procedure SetItem(aIndex: SizeInt; const aValue: T);
class function NewNode(const aValue: T): PNode; static;
class function CopyTree(aRoot: PNode): PNode; static;
class procedure UpdateNode(aNode: PNode); static; inline;
class procedure UpdateCache(aNode: PNode); static; inline;
class procedure UpdateValue(aIndex: SizeInt; aRoot: PNode; const aValue: T); static;
class procedure SplitNode(aIdx: SizeInt; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class procedure DeleteNode(aIndex: SizeInt; var aRoot: PNode; out aValue: T); static;
class operator Initialize(var aTreap: TGLiteImplSegmentTreap);
class operator Finalize(var aTreap: TGLiteImplSegmentTreap);
class operator Copy(constref aSrc: TGLiteImplSegmentTreap; var aDst: TGLiteImplSegmentTreap);
class operator AddRef(var aTreap: TGLiteImplSegmentTreap); inline;
public
class procedure Split(aIndex: SizeInt; var aTreap: TGLiteImplSegmentTreap;
out L, R: TGLiteImplSegmentTreap); static;
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TArray; //O(N)
function Add(const aValue: T): SizeInt; //O(LogN)
procedure Insert(aIndex: SizeInt; const aValue: T); //O(LogN)
procedure Insert(aIndex: SizeInt; var aTreap: TGLiteImplSegmentTreap); //O(LogN)
function Delete(aIndex: SizeInt): T; //O(LogN)
procedure Split(aIndex: SizeInt; out aTreap: TGLiteImplSegmentTreap); //O(LogN)
procedure Split(aIndex, aCount: SizeInt; out aTreap: TGLiteImplSegmentTreap);//O(LogN)
procedure Merge(var aTreap: TGLiteImplSegmentTreap);//O(LogN)
procedure RotateLeft(aDist: SizeInt); //O(LogN)
procedure RotateRight(aDist: SizeInt); //O(LogN)
{ returns value of the monoid function on the segment[L, R];
raises exception if L or R out of bounds }
function RangeQuery(L, R: SizeInt): TResult; //O(LogN)
{ returns value of the monoid function on the segment[0, aIndex];
raises exception if aIndex out of bounds }
function HeadQuery(aIndex: SizeInt): TResult; //O(LogN)
{ returns value of the monoid function on the segment[aIndex, Pred(Count)];
raises exception if aIndex out of bounds }
function TailQuery(aIndex: SizeInt): TResult; //O(LogN)
property Count: SizeInt read GetCount; //O(1)
property Height: SizeInt read GetHeight; //O(N)
property Items[aIndex: SizeInt]: T read GetItem write SetItem; default; //O(LogN)
end;
{ TGLiteImplicitSegTreap implements randomized Cartesian tree which mimics an array;
it allows:
- add an element to the array in O(log N);
- update a single element of an array in O(log N);
- add an arbitrary range of elements to the array in O(log N);
- reverse an arbitrary range of elements to the array in O(log N);
- modify an arbitrary range of elements of an array by some constant value in O(log N);
- find the value of the monoid function on an arbitrary range of array elements in O(log N);
functor TMonoid must provide:
class field/property/function Identity: T; - neutral element of the monoid;
associative dyadic function BinOp([const[ref]] L, R: T): T; - base monoid operation;
additional operation AddConst must be associative, and operations must satisfy the
distributive property:
function AddConst([const[ref]] aValue, aConst: T; aSize: SizeInt = 1): T;
class field/property/function ZeroConst: T; - neutral element of the additional operation;
function IsZeroConst([const[ref]] aValue: T): Boolean; - helper function;
on assignment and when passed by value, the whole treap is copied; }
generic TGLiteImplicitSegTreap<T, TMonoid> = record
public
type
TArray = array of T;
private
type
PNode = ^TNode;
TNode = record
private
const
REV_FLAG = SizeInt(SizeInt(1) shl Pred(BitSizeOf(SizeInt)));
SIZE_MASK = SizeInt(Pred(SizeUInt(REV_FLAG)));
var
FSize: SizeInt;
function GetReversed: Boolean; inline;
function GetSize: SizeInt; inline;
procedure SetReversed(aValue: Boolean); inline;
procedure SetSize(aValue: SizeInt); inline;
public
Left,
Right: PNode;
Prio: SizeUInt;
AddVal,
CacheVal,
Value: T;
property Size: SizeInt read GetSize write SetSize;
property Reversed: Boolean read GetReversed write SetReversed;
property Key: SizeInt read GetSize;
end;
var
FRoot: PNode;
function GetCount: SizeInt; inline;
function GetHeight: SizeInt;
procedure CheckIndexRange(aIndex: SizeInt); inline;
procedure CheckInsertRange(aIndex: SizeInt); inline;
function GetItem(aIndex: SizeInt): T;
procedure SetItem(aIndex: SizeInt; const aValue: T);
class function NewNode(const aValue: T): PNode; static;
class function CopyTree(aRoot: PNode): PNode; static;
class procedure UpdateNode(aNode: PNode); static; inline;
class procedure Push(aNode: PNode); static; inline;
class procedure SplitNode(aIdx: SizeInt; aRoot: PNode; out L, R: PNode); static;
class function MergeNode(L, R: PNode): PNode; static;
class operator Initialize(var aTreap: TGLiteImplicitSegTreap);
class operator Finalize(var aTreap: TGLiteImplicitSegTreap);
class operator Copy(constref aSrc: TGLiteImplicitSegTreap; var aDst: TGLiteImplicitSegTreap);
class operator AddRef(var aTreap: TGLiteImplicitSegTreap); inline;
public
class procedure Split(aIndex: SizeInt; var aTreap: TGLiteImplicitSegTreap;
out L, R: TGLiteImplicitSegTreap); static; //O(LogN)
function IsEmpty: Boolean; inline; //O(1)
procedure Clear; //O(N)
function ToArray: TArray; //O(N)
function Add(const aValue: T): SizeInt; //O(LogN)
procedure Insert(aIndex: SizeInt; const aValue: T); //O(LogN)
procedure Insert(aIndex: SizeInt; var aTreap: TGLiteImplicitSegTreap); //O(LogN)
function Delete(aIndex: SizeInt): T; //O(LogN)
function Delete(aIndex, aCount: SizeInt): SizeInt; //O(LogN)
procedure Split(aIndex: SizeInt; out aTreap: TGLiteImplicitSegTreap); //O(LogN)
procedure Split(aIndex, aCount: SizeInt; out aTreap: TGLiteImplicitSegTreap);//O(LogN)
procedure Merge(var aTreap: TGLiteImplicitSegTreap); //O(LogN)
procedure RotateLeft(aDist: SizeInt); //O(LogN)
procedure RotateRight(aDist: SizeInt); //O(LogN)
procedure Reverse; //O(LogN)
procedure Reverse(aFrom, aCount: SizeInt); //O(LogN)
procedure RangeUpdate(L, R: SizeInt; const aConst: T);//O(LogN)
{ returns value of the monoid function on the segment[L, R];
raises exception if L or R out of bounds }
function RangeQuery(L, R: SizeInt): T; //O(LogN)
{ returns value of the monoid function on the segment[0, aIndex];
raises exception if aIndex out of bounds }
function HeadQuery(aIndex: SizeInt): T; //O(LogN)
{ returns value of the monoid function on the segment[aIndex, Pred(Count)];
raises exception if aIndex out of bounds }
function TailQuery(aIndex: SizeInt): T; //O(LogN)
property Count: SizeInt read GetCount; //O(1)
property Height: SizeInt read GetHeight; //O(N)
property Items[aIndex: SizeInt]: T read GetItem write SetItem; default; //O(LogN)
end;
implementation
{$B-}{$COPERATORS ON}
{ TGLiteTreap }
function TGLiteTreap.GetCount: SizeInt;
begin
if FRoot <> nil then
exit(TUtil.GetTreeSize(FRoot));
Result := 0;
end;
function TGLiteTreap.GetHeight: SizeInt;
begin
Result := TUtil.GetHeight(FRoot);
end;
class function TGLiteTreap.NewNode(const aKey: TKey): PNode;
begin
Result := System.GetMem(SizeOf(TNode));
System.FillChar(Result^, SizeOf(TNode), 0);
Result^.FKey := aKey;
Result^.FPrio := {$IFDEF CPU64}BJNextRandom64{$ELSE}BJNextRandom{$ENDIF};
end;
class function TGLiteTreap.CopyTree(aRoot: PNode): PNode;
var
Tmp: TGLiteTreap;
procedure Visit(aNode: PNode);
begin
if aNode <> nil then
begin
Visit(aNode^.FLeft);
Tmp.Add(aNode^.Key)^.Value := aNode^.Value;
Visit(aNode^.FRight);
end;
end;
begin
Tmp.Clear;
if aRoot <> nil then
begin
Visit(aRoot);
Result := Tmp.FRoot;
Tmp.FRoot := nil;
end
else
Result := nil;
end;
class procedure TGLiteTreap.SplitNode(const aKey: TKey; aRoot: PNode; out L, R: PNode);
begin
if aRoot <> nil then
begin
if TCmpRel.Less(aRoot^.Key, aKey) then
begin
L := aRoot;
SplitNode(aKey, L^.FRight, L^.FRight, R);
end
else
begin
R := aRoot;
SplitNode(aKey, R^.FLeft, L, R^.FLeft);
end;
exit;
end;
L := nil;
R := nil;
end;
class function TGLiteTreap.MergeNode(L, R: PNode): PNode;
begin
if L = nil then
Result := R
else
if R = nil then
Result := L
else
if L^.FPrio > R^.FPrio then
begin
L^.FRight := MergeNode(L^.FRight, R);
Result := L;
end
else
begin
R^.FLeft := MergeNode(L, R^.FLeft);
Result := R;
end;
end;
class procedure TGLiteTreap.AddNode(var aRoot: PNode; aNode: PNode);
begin
if aRoot <> nil then
begin
if aRoot^.FPrio < aNode^.FPrio then
begin
SplitNode(aNode^.Key, aRoot, aNode^.FLeft, aNode^.FRight);
aRoot := aNode;
end
else
if TCmpRel.Less(aNode^.Key, aRoot^.Key) then
AddNode(aRoot^.FLeft, aNode)
else
AddNode(aRoot^.FRight, aNode);
end
else
aRoot := aNode;
end;
class function TGLiteTreap.RemoveNode(const aKey: TKey; var aRoot: PNode): Boolean;
var
Found: PNode;
begin
if aRoot <> nil then
if TCmpRel.Less(aKey, aRoot^.Key) then
exit(RemoveNode(aKey, aRoot^.FLeft))
else
if TCmpRel.Less(aRoot^.Key, aKey) then
exit(RemoveNode(aKey, aRoot^.FRight))
else
begin
Found := aRoot;
aRoot := MergeNode(aRoot^.FLeft, aRoot^.FRight);
TUtil.FreeNode(Found);
exit(True);
end;
Result := False;
end;
class function TGLiteTreap.RemoveNode(const aKey: TKey; var aRoot: PNode; out v: TValue): Boolean;
var
Found: PNode;
begin
if aRoot <> nil then
if TCmpRel.Less(aKey, aRoot^.Key) then
exit(RemoveNode(aKey, aRoot^.FLeft, v))
else
if TCmpRel.Less(aRoot^.Key, aKey) then
exit(RemoveNode(aKey, aRoot^.FRight, v))
else
begin
Found := aRoot;
aRoot := MergeNode(aRoot^.FLeft, aRoot^.FRight);
v := Found^.Value;
TUtil.FreeNode(Found);
exit(True);
end;
Result := False;
end;
class operator TGLiteTreap.Initialize(var aTreap: TGLiteTreap);
begin
aTreap.FRoot := nil;
end;
class operator TGLiteTreap.Finalize(var aTreap: TGLiteTreap);
begin
aTreap.Clear;
end;
class operator TGLiteTreap.Copy(constref aSrc: TGLiteTreap; var aDst: TGLiteTreap);
begin
aDst.Clear;
if aSrc.FRoot <> nil then
aDst.FRoot := CopyTree(aSrc.FRoot);
end;
class operator TGLiteTreap.AddRef(var aTreap: TGLiteTreap);
begin
if aTreap.FRoot <> nil then
aTreap.FRoot := CopyTree(aTreap.FRoot);
end;
class procedure TGLiteTreap.Split(const aKey: TKey; var aTreap: TGLiteTreap; out L, R: TGLiteTreap);
begin
if aTreap.FRoot = nil then
exit;
SplitNode(aKey, aTreap.FRoot, L.FRoot, R.FRoot);
aTreap.FRoot := nil;
end;
function TGLiteTreap.IsEmpty: Boolean;
begin
Result := FRoot = nil;
end;
procedure TGLiteTreap.Clear;
begin
if FRoot <> nil then
TUtil.ClearTree(FRoot);
FRoot := nil;
end;
function TGLiteTreap.ToArray: TEntryArray;
var
a: TEntryArray = nil;
I: Integer = 0;
procedure Visit(aNode: PNode);
begin
if aNode <> nil then
begin
Visit(aNode^.FLeft);
if System.Length(a) = I then
System.SetLength(a, I * 2);
a[I] := TEntry.Create(aNode^.Key, aNode^.Value);
Inc(I);
Visit(aNode^.FRight);
end;
end;
begin
if FRoot <> nil then
begin
System.SetLength(a, ARRAY_INITIAL_SIZE);
Visit(FRoot);
System.SetLength(a, I);
end;
Result := a;
end;
function TGLiteTreap.Find(const aKey: TKey): PNode;
begin
if FRoot <> nil then
exit(TUtil.FindKey(FRoot, aKey));
Result := nil;
end;
function TGLiteTreap.CountOf(const aKey: TKey): SizeInt;
var
L, M, R, Gt: PNode;
begin
if FRoot <> nil then
begin
Gt := TUtil.GetGreater(FRoot, aKey);
SplitNode(aKey, FRoot, L, R);
if Gt <> nil then
begin
SplitNode(Gt^.Key, R, M, R);
Result := TUtil.GetTreeSize(M);
FRoot := MergeNode(MergeNode(L, M), R);
end
else
begin
Result := TUtil.GetTreeSize(R);
FRoot := MergeNode(L, R);
end;
end
else
Result := 0;
end;
function TGLiteTreap.Add(const aKey: TKey): PNode;
begin
Result := NewNode(aKey);
if FRoot <> nil then
AddNode(FRoot, Result)
else
FRoot := Result;
end;
function TGLiteTreap.Remove(const aKey: TKey): Boolean;
begin
if FRoot <> nil then
Result := RemoveNode(aKey, FRoot)
else
Result := False;
end;
function TGLiteTreap.Remove(const aKey: TKey; out aValue: TValue): Boolean;
begin
if FRoot <> nil then
Result := RemoveNode(aKey, FRoot, aValue)
else
Result := False;
end;
procedure TGLiteTreap.Split(const aKey: TKey; out aTreap: TGLiteTreap);
begin
if FRoot <> nil then
SplitNode(aKey, FRoot, FRoot, aTreap.FRoot);
end;
{ TGLiteIdxTreap }
function TGLiteIdxTreap.GetCount: SizeInt;
begin
Result := TUtil.GetNodeSize(FRoot);
end;
function TGLiteIdxTreap.GetHeight: SizeInt;
begin
Result := TUtil.GetHeight(FRoot);
end;
function TGLiteIdxTreap.GetItem(aIndex: SizeInt): PNode;
begin
Result := TUtil.GetByIndex(FRoot, aIndex);
end;
procedure TGLiteIdxTreap.CheckIndexRange(aIndex: SizeInt);
begin
if SizeUInt(aIndex) >= SizeUInt(TUtil.GetNodeSize(FRoot)) then
raise EArgumentOutOfRangeException.CreateFmt(SEIndexOutOfBoundsFmt, [aIndex]);
end;
class function TGLiteIdxTreap.NewNode(const aKey: TKey): PNode;
begin
Result := System.GetMem(SizeOf(TNode));
System.FillChar(Result^, SizeOf(TNode), 0);
Result^.FKey := aKey;
Result^.FPrio := {$IFDEF CPU64}BJNextRandom64{$ELSE}BJNextRandom{$ENDIF};
Result^.FSize := 1;
end;
class function TGLiteIdxTreap.CopyTree(aRoot: PNode): PNode;
var
Tmp: TGLiteIdxTreap;
procedure Visit(aNode: PNode);
begin
if aNode <> nil then
begin
Visit(aNode^.FLeft);
Tmp.Add(aNode^.Key)^.Value := aNode^.Value;
Visit(aNode^.FRight);
end;
end;
begin
Tmp.Clear;
if aRoot <> nil then
begin
Visit(aRoot);
Result := Tmp.FRoot;
Tmp.FRoot := nil;
end
else
Result := nil;
end;
class procedure TGLiteIdxTreap.UpdateSize(aNode: PNode);
begin
with aNode^ do
begin
FSize := 1;
if Left <> nil then
FSize += Left^.FSize;
if Right <> nil then
FSize += Right^.FSize;
end;
end;
class procedure TGLiteIdxTreap.SplitNode(const aKey: TKey; aRoot: PNode; out L, R: PNode);
begin
if aRoot <> nil then
begin
if TCmpRel.Less(aRoot^.Key, aKey) then
begin
L := aRoot;
SplitNode(aKey, L^.FRight, L^.FRight, R);
end
else
begin
R := aRoot;
SplitNode(aKey, R^.FLeft, L, R^.FLeft);
end;
UpdateSize(aRoot);
exit;
end;
L := nil;
R := nil;
end;
class function TGLiteIdxTreap.MergeNode(L, R: PNode): PNode;
begin
if L = nil then
Result := R
else
if R = nil then
Result := L
else
begin
if L^.FPrio > R^.FPrio then
begin
L^.FRight := MergeNode(L^.FRight, R);
Result := L;
end
else
begin
R^.FLeft := MergeNode(L, R^.FLeft);
Result := R;
end;
UpdateSize(Result);
end;
end;
class procedure TGLiteIdxTreap.AddNode(var aRoot: PNode; aNode: PNode);
begin
if aRoot <> nil then
begin
if aRoot^.FPrio < aNode^.FPrio then
begin
SplitNode(aNode^.Key, aRoot, aNode^.FLeft, aNode^.FRight);
aRoot := aNode;
end
else
if TCmpRel.Less(aNode^.Key, aRoot^.Key) then
AddNode(aRoot^.FLeft, aNode)
else
AddNode(aRoot^.FRight, aNode);
UpdateSize(aRoot);
end
else
aRoot := aNode;
end;
class function TGLiteIdxTreap.RemoveNode(const aKey: TKey; var aRoot: PNode): Boolean;
var
Found: PNode;
begin
if aRoot = nil then exit(False);
if TCmpRel.Less(aKey, aRoot^.Key) then
begin
Result := RemoveNode(aKey, aRoot^.FLeft);
if Result and (aRoot <> nil) then
UpdateSize(aRoot);
end
else
if TCmpRel.Less(aRoot^.Key, aKey) then
begin
Result := RemoveNode(aKey, aRoot^.FRight);
if Result and (aRoot <> nil) then
UpdateSize(aRoot);
end
else
begin
Found := aRoot;
aRoot := MergeNode(aRoot^.FLeft, aRoot^.FRight);
TUtil.FreeNode(Found);
Result := True;
end;
end;
class function TGLiteIdxTreap.RemoveNode(const aKey: TKey; var aRoot: PNode; out v: TValue): Boolean;
var
Found: PNode;
begin
if aRoot = nil then exit(False);
if TCmpRel.Less(aKey, aRoot^.Key) then
begin
Result := RemoveNode(aKey, aRoot^.FLeft, v);
if Result and (aRoot <> nil) then
UpdateSize(aRoot);
end
else
if TCmpRel.Less(aRoot^.Key, aKey) then
begin
Result := RemoveNode(aKey, aRoot^.FRight, v);
if Result and (aRoot <> nil) then
UpdateSize(aRoot);
end
else
begin
Found := aRoot;
aRoot := MergeNode(aRoot^.FLeft, aRoot^.FRight);
v := Found^.Value;
TUtil.FreeNode(Found);
Result := True;
end;
end;
class operator TGLiteIdxTreap.Initialize(var aTreap: TGLiteIdxTreap);
begin
aTreap.FRoot := nil;
end;
class operator TGLiteIdxTreap.Finalize(var aTreap: TGLiteIdxTreap);
begin
aTreap.Clear;
end;
class operator TGLiteIdxTreap.Copy(constref aSrc: TGLiteIdxTreap; var aDst: TGLiteIdxTreap);
begin
aDst.Clear;
if aSrc.FRoot <> nil then
aDst.FRoot := CopyTree(aSrc.FRoot);
end;
class operator TGLiteIdxTreap.AddRef(var aTreap: TGLiteIdxTreap);
begin
if aTreap.FRoot <> nil then
aTreap.FRoot := CopyTree(aTreap.FRoot);
end;
class procedure TGLiteIdxTreap.Split(const aKey: TKey; var aTreap: TGLiteIdxTreap;
out L, R: TGLiteIdxTreap);