-
Notifications
You must be signed in to change notification settings - Fork 37
/
CoreEditorMediator.as
1921 lines (1781 loc) · 67 KB
/
CoreEditorMediator.as
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package awaybuilder.view.mediators
{
import away3d.animators.AnimationSetBase;
import away3d.animators.AnimatorBase;
import away3d.animators.SkeletonAnimationSet;
import away3d.animators.SkeletonAnimator;
import away3d.animators.VertexAnimationSet;
import away3d.animators.VertexAnimator;
import away3d.animators.data.Skeleton;
import away3d.animators.nodes.AnimationNodeBase;
import away3d.cameras.Camera3D;
import away3d.cameras.lenses.LensBase;
import away3d.cameras.lenses.OrthographicLens;
import away3d.cameras.lenses.OrthographicOffCenterLens;
import away3d.cameras.lenses.PerspectiveLens;
import away3d.containers.ObjectContainer3D;
import away3d.core.base.Geometry;
import away3d.core.base.ISubGeometry;
import away3d.core.base.Object3D;
import away3d.core.base.SubGeometry;
import away3d.core.base.SubMesh;
import away3d.entities.Mesh;
import away3d.entities.TextureProjector;
import away3d.errors.AnimationSetError;
import away3d.library.assets.NamedAssetBase;
import away3d.lights.DirectionalLight;
import away3d.lights.LightBase;
import away3d.lights.PointLight;
import away3d.lights.shadowmaps.CascadeShadowMapper;
import away3d.lights.shadowmaps.CubeMapShadowMapper;
import away3d.lights.shadowmaps.NearDirectionalShadowMapper;
import away3d.lights.shadowmaps.ShadowMapperBase;
import away3d.materials.ColorMaterial;
import away3d.materials.ColorMultiPassMaterial;
import away3d.materials.MaterialBase;
import away3d.materials.MultiPassMaterialBase;
import away3d.materials.SinglePassMaterialBase;
import away3d.materials.SkyBoxMaterial;
import away3d.materials.TextureMaterial;
import away3d.materials.TextureMultiPassMaterial;
import away3d.materials.lightpickers.LightPickerBase;
import away3d.materials.lightpickers.StaticLightPicker;
import away3d.materials.methods.AlphaMaskMethod;
import away3d.materials.methods.BasicAmbientMethod;
import away3d.materials.methods.BasicDiffuseMethod;
import away3d.materials.methods.BasicNormalMethod;
import away3d.materials.methods.BasicSpecularMethod;
import away3d.materials.methods.CascadeShadowMapMethod;
import away3d.materials.methods.CelDiffuseMethod;
import away3d.materials.methods.CelSpecularMethod;
import away3d.materials.methods.ColorMatrixMethod;
import away3d.materials.methods.ColorTransformMethod;
import away3d.materials.methods.DitheredShadowMapMethod;
import away3d.materials.methods.EffectMethodBase;
import away3d.materials.methods.EnvMapAmbientMethod;
import away3d.materials.methods.EnvMapMethod;
import away3d.materials.methods.FilteredShadowMapMethod;
import away3d.materials.methods.FogMethod;
import away3d.materials.methods.FresnelEnvMapMethod;
import away3d.materials.methods.FresnelSpecularMethod;
import away3d.materials.methods.GradientDiffuseMethod;
import away3d.materials.methods.HardShadowMapMethod;
import away3d.materials.methods.HeightMapNormalMethod;
import away3d.materials.methods.LightMapDiffuseMethod;
import away3d.materials.methods.LightMapMethod;
import away3d.materials.methods.NearShadowMapMethod;
import away3d.materials.methods.OutlineMethod;
import away3d.materials.methods.ProjectiveTextureMethod;
import away3d.materials.methods.RefractionEnvMapMethod;
import away3d.materials.methods.RimLightMethod;
import away3d.materials.methods.ShadingMethodBase;
import away3d.materials.methods.ShadowMapMethodBase;
import away3d.materials.methods.SimpleShadowMapMethodBase;
import away3d.materials.methods.SimpleWaterNormalMethod;
import away3d.materials.methods.SoftShadowMapMethod;
import away3d.materials.methods.SubsurfaceScatteringDiffuseMethod;
import away3d.materials.methods.WrapDiffuseMethod;
import away3d.primitives.CapsuleGeometry;
import away3d.primitives.ConeGeometry;
import away3d.primitives.CubeGeometry;
import away3d.primitives.CylinderGeometry;
import away3d.primitives.PlaneGeometry;
import away3d.primitives.SkyBox;
import away3d.primitives.SphereGeometry;
import away3d.primitives.TorusGeometry;
import away3d.textures.BitmapCubeTexture;
import away3d.textures.BitmapTexture;
import away3d.textures.CubeTextureBase;
import away3d.textures.Texture2DBase;
import awaybuilder.controller.document.ReplaceDocumentDataCommand;
import awaybuilder.controller.events.ConcatenateDataOperationEvent;
import awaybuilder.controller.events.DocumentModelEvent;
import awaybuilder.controller.events.ReplaceDocumentDataEvent;
import awaybuilder.controller.events.SceneReadyEvent;
import awaybuilder.controller.scene.events.AnimationEvent;
import awaybuilder.controller.scene.events.SceneEvent;
import awaybuilder.model.AssetsModel;
import awaybuilder.model.DocumentModel;
import awaybuilder.model.vo.DeleteStateVO;
import awaybuilder.model.vo.DroppedAssetVO;
import awaybuilder.model.vo.scene.AnimationNodeVO;
import awaybuilder.model.vo.scene.AnimationSetVO;
import awaybuilder.model.vo.scene.AnimatorVO;
import awaybuilder.model.vo.scene.AssetVO;
import awaybuilder.model.vo.scene.CameraVO;
import awaybuilder.model.vo.scene.ContainerVO;
import awaybuilder.model.vo.scene.CubeTextureVO;
import awaybuilder.model.vo.scene.EffectVO;
import awaybuilder.model.vo.scene.ExtraItemVO;
import awaybuilder.model.vo.scene.GeometryVO;
import awaybuilder.model.vo.scene.LensVO;
import awaybuilder.model.vo.scene.LightPickerVO;
import awaybuilder.model.vo.scene.LightVO;
import awaybuilder.model.vo.scene.MaterialVO;
import awaybuilder.model.vo.scene.MeshVO;
import awaybuilder.model.vo.scene.ObjectVO;
import awaybuilder.model.vo.scene.ShadingMethodVO;
import awaybuilder.model.vo.scene.ShadowMapperVO;
import awaybuilder.model.vo.scene.ShadowMethodVO;
import awaybuilder.model.vo.scene.SharedEffectVO;
import awaybuilder.model.vo.scene.SharedLightVO;
import awaybuilder.model.vo.scene.SkeletonVO;
import awaybuilder.model.vo.scene.SkyBoxVO;
import awaybuilder.model.vo.scene.SubGeometryVO;
import awaybuilder.model.vo.scene.SubMeshVO;
import awaybuilder.model.vo.scene.TextureProjectorVO;
import awaybuilder.model.vo.scene.TextureVO;
import awaybuilder.utils.scene.CameraManager;
import awaybuilder.utils.scene.Scene3DManager;
import awaybuilder.utils.scene.modes.CameraMode;
import awaybuilder.utils.scene.modes.GizmoMode;
import awaybuilder.view.components.CoreEditor;
import awaybuilder.view.scene.controls.CameraGizmo3D;
import awaybuilder.view.scene.controls.ContainerGizmo3D;
import awaybuilder.view.scene.controls.LightGizmo3D;
import awaybuilder.view.scene.controls.TextureProjectorGizmo3D;
import awaybuilder.view.scene.events.Scene3DManagerEvent;
import awaybuilder.view.scene.representations.ISceneRepresentation;
import flash.display.BitmapData;
import flash.events.ErrorEvent;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.events.UncaughtErrorEvent;
import flash.geom.ColorTransform;
import flash.geom.Matrix;
import flash.geom.Vector3D;
import flash.ui.Keyboard;
import flash.utils.setTimeout;
import mx.collections.ArrayCollection;
import mx.controls.Alert;
import mx.core.FlexGlobals;
import mx.managers.FocusManager;
import org.robotlegs.mvcs.Mediator;
import spark.collections.Sort;
public class CoreEditorMediator extends Mediator
{
[Inject]
public var view:CoreEditor;
[Inject]
public var assets:AssetsModel;
[Inject]
public var document:DocumentModel;
private var _scenegraphSort:Sort = new Sort();
private var _scenegraph:ArrayCollection;
private var _scenegraphSelected:Vector.<Object>;
private var _currentAnimation:AnimationNodeVO;
private var _currentAnimator:AnimatorVO;
override public function onRegister():void
{
FlexGlobals.topLevelApplication.loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
addContextListener(AnimationEvent.PLAY, contect_playHandler);
addContextListener(AnimationEvent.STOP, contect_stopHandler);
addContextListener(AnimationEvent.SEEK, contect_seekHandler);
addContextListener(AnimationEvent.PAUSE, contect_pauseHandler);
addContextListener(SceneEvent.TRANSLATE, eventDispatcher_translateHandler);
addContextListener(SceneEvent.TRANSLATE_PIVOT, eventDispatcher_translateHandler);
addContextListener(SceneEvent.SCALE, eventDispatcher_translateHandler);
addContextListener(SceneEvent.ROTATE, eventDispatcher_translateHandler);
addContextListener(SceneEvent.CHANGE_MESH, eventDispatcher_changeMeshHandler);
addContextListener(SceneEvent.CHANGE_SUBMESH, eventDispatcher_changeMeshHandler);
addContextListener(SceneEvent.CHANGE_LIGHT, eventDispatcher_changeLightHandler);
addContextListener(SceneEvent.CHANGE_MATERIAL, eventDispatcher_changeMaterialHandler);
addContextListener(SceneEvent.CHANGE_LIGHTPICKER, eventDispatcher_changeLightPickerHandler);
addContextListener(SceneEvent.CHANGE_CONTAINER, eventDispatcher_changeContainerHandler);
addContextListener(SceneEvent.CHANGE_SHADOW_METHOD, eventDispatcher_changeShadowMethodHandler);
addContextListener(SceneEvent.CHANGE_SHADING_METHOD, eventDispatcher_changeShadingMethodHandler);
addContextListener(SceneEvent.CHANGE_EFFECT_METHOD, eventDispatcher_changeEffectMethodHandler);
addContextListener(SceneEvent.CHANGE_SHADOW_MAPPER, eventDispatcher_changeShadowMapperHandler);
addContextListener(SceneEvent.CHANGE_CUBE_TEXTURE, eventDispatcher_changeCubeTextureHandler);
addContextListener(SceneEvent.CHANGE_TEXTURE, eventDispatcher_changeTextureHandler);
addContextListener(SceneEvent.CHANGE_GEOMETRY, eventDispatcher_changeGeometryHandler);
addContextListener(SceneEvent.CHANGE_SKYBOX, eventDispatcher_changeSkyboxHandler);
addContextListener(SceneEvent.CHANGE_ANIMATOR, eventDispatcher_changeAnimatorHandler);
addContextListener(SceneEvent.CHANGE_TEXTURE_PROJECTOR, eventDispatcher_changeTextureProjectorHandler);
addContextListener(SceneEvent.CHANGE_CAMERA, eventDispatcher_changeCameraHandler);
addContextListener(SceneEvent.CHANGE_LENS, eventDispatcher_changeLensHandler);
addContextListener(SceneEvent.CHANGE_SKELETON, eventDispatcher_changeSkeletonHandler);
addContextListener(SceneEvent.CHANGE_ANIMATION_SET, eventDispatcher_changeAnimationSetHandler);
addContextListener(SceneEvent.CHANGE_ANIMATION_NODE, eventDispatcher_changeAnimationNodeHandler);
addContextListener(SceneEvent.REPARENT_LIGHTS, eventDispatcher_reparentLightsHandler);
addContextListener(SceneEvent.REPARENT_ANIMATIONS, eventDispatcher_reparentAnimationHandler);
addContextListener(SceneEvent.REPARENT_MATERIAL_EFFECT, eventDispatcher_reparentMaterialEffectHandler);
addContextListener(SceneEvent.ADD_NEW_TEXTURE, eventDispatcher_addNewTextureHandler);
addContextListener(SceneEvent.ADD_NEW_TEXTURE_PROJECTOR, eventDispatcher_addNewTextureHandler);
addContextListener(SceneEvent.ADD_NEW_CUBE_TEXTURE, eventDispatcher_addNewCubeTextureHandler);
addContextListener(SceneEvent.ADD_NEW_MESH, eventDispatcher_addNewMeshHandler);
addContextListener(SceneEvent.ADD_NEW_CONTAINER, eventDispatcher_addNewContinerHandler);
addContextListener(SceneEvent.ADD_NEW_MATERIAL, eventDispatcher_addNewMaterialToSubmeshHandler);
addContextListener(SceneEvent.ADD_NEW_LIGHTPICKER, eventDispatcher_addNewLightpickerToMaterialHandler);
addContextListener(SceneEvent.ADD_NEW_SHADOW_METHOD, eventDispatcher_addNewShadowMethodHandler);
addContextListener(SceneEvent.ADD_NEW_EFFECT_METHOD, eventDispatcher_addNewEffectMethodHandler);
addContextListener(SceneEvent.ADD_NEW_LIGHT, eventDispatcher_addNewLightHandler);
addContextListener(SceneEvent.CONTAINER_CLICKED, eventDispatcher_containerClicked);
addContextListener(DocumentModelEvent.OBJECTS_UPDATED, context_objectsUpdatedHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.READY, scene_readyHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.MESH_SELECTED, scene_meshSelectedHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.OBJECT_SELECTED_FROM_VIEW, scene_meshSelectedFromViewHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.TRANSFORM, scene_transformHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.TRANSFORM_RELEASE, scene_transformReleaseHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.ZOOM_DISTANCE_DELTA, eventDispatcher_zoomDistanceDeltaHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.ZOOM_TO_DISTANCE, eventDispatcher_zoomToDistanceHandler);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.SWITCH_TRANSFORM_ROTATE, eventDispatcher_itemSwitchesToRotateMode);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.SWITCH_TRANSFORM_TRANSLATE, eventDispatcher_itemSwitchesToTranslateMode);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.SWITCH_CAMERA_TRANSFORMS, eventDispatcher_itemSwitchesToCameraTransformMode);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.ENABLE_TRANSFORM_MODES, eventDispatcher_enableAllTransformModes);
Scene3DManager.instance.addEventListener(Scene3DManagerEvent.UPDATE_BREADCRUMBS, eventDispatcher_updateBreadcrumbs);
Scene3DManager.init( view.viewScope );
addContextListener(SceneEvent.SELECT, eventDispatcher_itemsSelectHandler);
addContextListener(SceneEvent.DELETE, eventDispatcher_itemsDeleteHandler);
addContextListener(SceneEvent.FOCUS_SELECTION, eventDispatcher_itemsFocusHandler);
view.stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler);
view.stage.addEventListener(KeyboardEvent.KEY_UP, keyUpHandler);
}
//----------------------------------------------------------------------
//
// view handlers
//
//----------------------------------------------------------------------
private function keyDownHandler(e:KeyboardEvent):void
{
if (e.keyCode == Keyboard.ALTERNATE) CameraManager.panning = true;
switch (e.keyCode)
{
case Keyboard.W:
case Keyboard.UP:
CameraManager.moveForward(CameraManager.speed);
e.stopImmediatePropagation();
break;
case Keyboard.S:
case Keyboard.DOWN:
CameraManager.moveBackward(CameraManager.speed);
e.stopImmediatePropagation();
break;
case Keyboard.A:
case Keyboard.LEFT:
CameraManager.moveLeft(CameraManager.speed);
e.stopImmediatePropagation();
break;
case Keyboard.D:
case Keyboard.RIGHT:
CameraManager.moveRight(CameraManager.speed);
e.stopImmediatePropagation();
break;
case Keyboard.SHIFT:
CameraManager.running = true;
e.stopImmediatePropagation();
break;
case Keyboard.CONTROL:
Scene3DManager.multiSelection = true;
e.stopImmediatePropagation();
break;
}
}
private function keyUpHandler(e:KeyboardEvent):void
{
if (e.keyCode == Keyboard.ALTERNATE) CameraManager.panning = false;
switch (e.keyCode)
{
case Keyboard.W:
case Keyboard.S:
case Keyboard.UP:
case Keyboard.DOWN:
CameraManager.moveForward(0);
e.stopImmediatePropagation();
break;
case Keyboard.A:
case Keyboard.D:
case Keyboard.LEFT:
case Keyboard.RIGHT:
CameraManager.moveLeft(0);
e.stopImmediatePropagation();
break;
case Keyboard.SHIFT:
CameraManager.running = false;
e.stopImmediatePropagation();
break;
case Keyboard.CONTROL:
Scene3DManager.multiSelection = false;
e.stopImmediatePropagation();
break;
}
}
private function view_enterFrameHandler(event:Event):void
{
if( _currentAnimator && _currentAnimation )
{
var animator:AnimatorBase;
switch (_currentAnimator.type){
case "SkeletonAnimator":
animator = assets.GetObject(_currentAnimator ) as SkeletonAnimator;
break;
case "VertexAnimator":
animator = assets.GetObject(_currentAnimator ) as VertexAnimator;
break;
}
if( animator.activeState)
{
var time:int = animator.time*animator.playbackSpeed;
if ( animator.time >= _currentAnimation.totalDuration )
{
time %= _currentAnimation.totalDuration;
}
if ( time < 0)
{
time += _currentAnimation.totalDuration;
}
_currentAnimation.currentPosition = time;
}
}
}
//----------------------------------------------------------------------
//
// context handlers
//
//----------------------------------------------------------------------
private function contect_playHandler(event:AnimationEvent):void
{
var animator:AnimatorBase;
switch (event.animator.type){
case "SkeletonAnimator":
animator = assets.GetObject( event.animator ) as SkeletonAnimator;
break;
case "VertexAnimator":
animator = assets.GetObject( event.animator ) as VertexAnimator;
break;
}
animator.updatePosition = false;
event.animation.isPlaying = true;
if( event.animation == event.animator.activeAnimationNode )
{
animator.start();
}
else
{
switch (event.animator.type){
case "SkeletonAnimator":
SkeletonAnimator(animator).play(event.animation.name, null, event.animation.currentPosition);
break;
case "VertexAnimator":
VertexAnimator(animator).play(event.animation.name, null, event.animation.currentPosition);
break;
}
event.animator.activeAnimationNode = event.animation;
}
_currentAnimation = event.animation;
_currentAnimator = event.animator;
this.view.addEventListener(Event.ENTER_FRAME, view_enterFrameHandler );
}
private function contect_pauseHandler(event:AnimationEvent):void
{
var animator:AnimatorBase;
switch (event.animator.type){
case "SkeletonAnimator":
animator = assets.GetObject( event.animator ) as SkeletonAnimator;
break;
case "VertexAnimator":
animator = assets.GetObject( event.animator ) as VertexAnimator;
break;
}
event.animation.isPlaying = false;
animator.stop();
this.view.removeEventListener(Event.ENTER_FRAME, view_enterFrameHandler );
}
private function contect_stopHandler(event:AnimationEvent):void
{
if( !_currentAnimator || !_currentAnimation ) return;
var animator:AnimatorBase;
switch (_currentAnimator.type){
case "SkeletonAnimator":
animator = assets.GetObject( _currentAnimator ) as SkeletonAnimator;
break;
case "VertexAnimator":
animator = assets.GetObject( _currentAnimator ) as VertexAnimator;
break;
}
_currentAnimation.isPlaying = false;
animator.stop();
animator.time = 0;
this.view.removeEventListener(Event.ENTER_FRAME, view_enterFrameHandler );
_currentAnimation.currentPosition = 0;
_currentAnimator = null;
_currentAnimation = null;
}
private function contect_seekHandler(event:AnimationEvent):void
{
var animator:AnimatorBase;
switch (event.animator.type){
case "SkeletonAnimator":
animator = assets.GetObject( event.animator ) as SkeletonAnimator;
break;
case "VertexAnimator":
animator = assets.GetObject( event.animator ) as VertexAnimator;
break;
}
event.animation.isPlaying = false;
if( event.animation != event.animator.activeAnimationNode )
{
switch (event.animator.type){
case "SkeletonAnimator":
SkeletonAnimator(animator).play(event.animation.name, null, event.animation.currentPosition);
break;
case "VertexAnimator":
VertexAnimator(animator).play(event.animation.name, null, event.animation.currentPosition);
break;
}
animator.stop();
event.animator.activeAnimationNode = event.animation;
}
_currentAnimation = event.animation;
_currentAnimator = event.animator;
var time:int = event.animation.currentPosition;
if ( time >= _currentAnimation.totalDuration )
{
time %= _currentAnimation.totalDuration;
}
if ( time < 0)
{
time += _currentAnimation.totalDuration;
}
animator.time = time;
}
private function context_objectsUpdatedHandler(event:DocumentModelEvent):void
{
if( _currentAnimator )
{
contect_stopHandler( null );
}
}
private function eventDispatcher_reparentLightsHandler(event:SceneEvent):void
{
for each( var item:DroppedAssetVO in event.newValue )
{
if( (item.value is LightVO) && item.newParent && (item.newParent is LightPickerVO) ) {
applyLightPicker( item.newParent as LightPickerVO );
}
}
}
private function eventDispatcher_reparentMaterialEffectHandler(event:SceneEvent):void
{
for each( var item:DroppedAssetVO in event.newValue )
{
if( (item.value is EffectVO) && item.newParent && (item.newParent is MaterialVO) ) {
applyMaterial( item.newParent as MaterialVO );
}
}
}
private function eventDispatcher_reparentAnimationHandler(event:SceneEvent):void
{
for each( var item:DroppedAssetVO in event.newValue )
{
if( item.value is AnimationNodeVO && item.newParent && item.newParent is AnimationSetVO ) {
var newAnimationSet:AnimationSetBase = assets.GetObject(item.newParent) as AnimationSetBase;
try
{
newAnimationSet.addAnimation( assets.GetObject(item.value) as AnimationNodeBase );
}
catch( e:AnimationSetError )
{
trace( e.message );
trace( "// TODO: handle animations update" );
}
}
}
}
private function eventDispatcher_translateHandler(event:SceneEvent):void
{
for each( var obj:ObjectVO in event.items )
{
var lightObject:LightVO = obj as LightVO;
if( lightObject )
{
applyLight( lightObject );
}
else
{
applyObject( obj );
}
}
Scene3DManager.updateDefaultCameraFarPlane();
}
private function applyLens( asset:LensVO ):void
{
var obj:LensBase = assets.GetObject( asset ) as LensBase;
var perspectiveLens:PerspectiveLens = obj as PerspectiveLens;
if( perspectiveLens )
{
perspectiveLens.fieldOfView = asset.value;
}
var orthographicLens:OrthographicLens = obj as OrthographicLens;
if( orthographicLens )
{
orthographicLens.projectionHeight = asset.value;
}
var orthographicOffCenterLens:OrthographicOffCenterLens = obj as OrthographicOffCenterLens;
if( orthographicOffCenterLens )
{
orthographicOffCenterLens.minX = asset.minX;
orthographicOffCenterLens.maxX = asset.maxX;
orthographicOffCenterLens.minY = asset.minY;
orthographicOffCenterLens.maxY = asset.maxY;
}
}
private function applyCamera( asset:CameraVO ):void
{
var obj:Camera3D = assets.GetObject( asset ) as Camera3D;
obj.lens = assets.GetObject(asset.lens) as LensBase;
applyObject( asset );
}
private function applyTextureProjector( asset:TextureProjectorVO ):void
{
var obj:TextureProjector = assets.GetObject( asset ) as TextureProjector;
obj.fieldOfView = asset.fov;
obj.aspectRatio = asset.aspectRatio;
obj.texture = assets.GetObject(asset.texture) as Texture2DBase;
applyObject( asset );
Scene3DManager.updateTextureProjectorBitmap(obj, asset.texture.bitmapData);
}
private function applySkyBox( asset:SkyBoxVO ):void
{
var obj:SkyBox = assets.GetObject( asset ) as SkyBox;
SkyBoxMaterial(obj.material).cubeMap = assets.GetObject(asset.cubeMap) as CubeTextureBase;
obj.name = asset.name;
}
private function applyEffectMethod( asset:EffectVO ):void
{
var obj:EffectMethodBase = assets.GetObject( asset ) as EffectMethodBase;
applyName( obj, asset );
if( obj is ColorMatrixMethod )
{
var colorMatrixMethod:ColorMatrixMethod = obj as ColorMatrixMethod;
colorMatrixMethod.colorMatrix = [ asset.r, asset.g, asset.b, asset.a, asset.rO, asset.rG, asset.gG, asset.bG, asset.aG, asset.gO, asset.rB, asset.gB, asset.bB, asset.aB, asset.bO, asset.rA, asset.gA, asset.bA, asset.aA, asset.aO,];
}
else if( obj is FogMethod )
{
var fogMethod:FogMethod = obj as FogMethod;
fogMethod.fogColor = asset.color;
fogMethod.minDistance = asset.minDistance;
fogMethod.maxDistance = asset.maxDistance;
}
else if( obj is AlphaMaskMethod )
{
var alphaMaskMethod:AlphaMaskMethod = obj as AlphaMaskMethod;
alphaMaskMethod.texture = assets.GetObject( asset.texture ) as Texture2DBase;
alphaMaskMethod.useSecondaryUV = asset.useSecondaryUV;
}
else if( obj is ColorTransformMethod )
{
var colorTransformMethod:ColorTransformMethod = obj as ColorTransformMethod;
colorTransformMethod.colorTransform = new ColorTransform( asset.r, asset.g, asset.b, asset.a, asset.rO, asset.gO, asset.bO, asset.aO );
}
else if( obj is EnvMapMethod )
{
var envMapMethod:EnvMapMethod = obj as EnvMapMethod;
envMapMethod.mask = assets.GetObject( asset.texture ) as Texture2DBase;
envMapMethod.alpha = asset.alpha;
envMapMethod.envMap = assets.GetObject( asset.cubeTexture ) as CubeTextureBase;
}
else if( obj is FresnelEnvMapMethod )
{
var fresnelEnvMapMethod:FresnelEnvMapMethod = obj as FresnelEnvMapMethod;
fresnelEnvMapMethod.envMap = assets.GetObject( asset.cubeTexture ) as CubeTextureBase;
fresnelEnvMapMethod.alpha = asset.alpha;
}
else if( obj is LightMapMethod )
{
var lightMapMethod:LightMapMethod = obj as LightMapMethod;
lightMapMethod.texture = assets.GetObject( asset.texture ) as Texture2DBase;
// lightMapMethod.useSecondaryUV = assets.useSecondaryUV;
lightMapMethod.blendMode = asset.mode;
}
else if( obj is OutlineMethod )
{
var outlineMethod:OutlineMethod = obj as OutlineMethod;
outlineMethod.outlineColor = asset.color;
outlineMethod.showInnerLines = asset.showInnerLines;
outlineMethod.outlineSize = asset.size;
// outlineMethod.dedicatedMeshes
}
else if( obj is ProjectiveTextureMethod )
{
var projectiveTextureMethod:ProjectiveTextureMethod = obj as ProjectiveTextureMethod;
}
else if( obj is RefractionEnvMapMethod )
{
var refractionEnvMapMethod:RefractionEnvMapMethod = obj as RefractionEnvMapMethod;
refractionEnvMapMethod.envMap = assets.GetObject( asset.cubeTexture ) as CubeTextureBase;
refractionEnvMapMethod.dispersionR = asset.r;
refractionEnvMapMethod.dispersionG = asset.g;
refractionEnvMapMethod.dispersionB = asset.b;
refractionEnvMapMethod.refractionIndex = asset.refraction;
refractionEnvMapMethod.alpha = asset.alpha;
}
else if( obj is RimLightMethod )
{
var rimLightMethod:RimLightMethod = obj as RimLightMethod;
rimLightMethod.color = asset.color;
rimLightMethod.power = asset.power;
rimLightMethod.strength = asset.strength;
}
}
private function applyShadingMethod( asset:ShadingMethodVO ):void
{
var obj:ShadingMethodBase = assets.GetObject( asset ) as ShadingMethodBase;
switch( true )
{
case(obj is EnvMapAmbientMethod):
{
var envMapAmbientMethod:EnvMapAmbientMethod = obj as EnvMapAmbientMethod;
envMapAmbientMethod.envMap = assets.GetObject( asset.envMap ) as CubeTextureBase;
break;
}
case(obj is GradientDiffuseMethod):
{
var gradientDiffuseMethod:GradientDiffuseMethod = obj as GradientDiffuseMethod;
gradientDiffuseMethod.gradient = assets.GetObject( asset.texture ) as Texture2DBase;
break;
}
case(obj is WrapDiffuseMethod):
{
var wrapDiffuseMethod:WrapDiffuseMethod = obj as WrapDiffuseMethod;
wrapDiffuseMethod.wrapFactor = asset.value;
break;
}
case(obj is LightMapDiffuseMethod):
{
var lightMapDiffuseMethod:LightMapDiffuseMethod = obj as LightMapDiffuseMethod;
lightMapDiffuseMethod.blendMode = asset.blendMode;
lightMapDiffuseMethod.lightMapTexture = assets.GetObject( asset.texture ) as Texture2DBase;
lightMapDiffuseMethod.baseMethod = assets.GetObject( asset.baseMethod ) as BasicDiffuseMethod;
break;
}
case(obj is CelDiffuseMethod):
{
var celDiffuseMethod:CelDiffuseMethod = obj as CelDiffuseMethod;
celDiffuseMethod.levels = asset.value;
celDiffuseMethod.smoothness = asset.smoothness;
celDiffuseMethod.baseMethod = assets.GetObject( asset.baseMethod ) as BasicDiffuseMethod;
break;
}
case(obj is SubsurfaceScatteringDiffuseMethod):
{
var subsurfaceScatterDiffuseMethod:SubsurfaceScatteringDiffuseMethod = obj as SubsurfaceScatteringDiffuseMethod;
subsurfaceScatterDiffuseMethod.scattering = asset.scattering;
subsurfaceScatterDiffuseMethod.translucency = asset.translucency;
subsurfaceScatterDiffuseMethod.baseMethod = assets.GetObject( asset.baseMethod ) as BasicDiffuseMethod;
break;
}
case(obj is CelSpecularMethod):
{
var celSpecularMethod:CelSpecularMethod = obj as CelSpecularMethod;
celSpecularMethod.specularCutOff = asset.value;
celSpecularMethod.smoothness = asset.smoothness;
celSpecularMethod.baseMethod = assets.GetObject( asset.baseMethod ) as BasicSpecularMethod;
break;
}
case(obj is FresnelSpecularMethod):
{
var fresnelSpecularMethod:FresnelSpecularMethod = obj as FresnelSpecularMethod;
fresnelSpecularMethod.basedOnSurface = asset.basedOnSurface;
fresnelSpecularMethod.normalReflectance = asset.value;
fresnelSpecularMethod.fresnelPower = asset.fresnelPower;
fresnelSpecularMethod.baseMethod = assets.GetObject( asset.baseMethod ) as BasicSpecularMethod;
break;
}
case(obj is HeightMapNormalMethod):
{
var heightMapNormalMethod:HeightMapNormalMethod = obj as HeightMapNormalMethod;
break;
}
case(obj is SimpleWaterNormalMethod):
{
var simpleWaterNormalMethod:SimpleWaterNormalMethod = obj as SimpleWaterNormalMethod;
simpleWaterNormalMethod.normalMap = assets.GetObject( asset.texture ) as Texture2DBase;
break;
}
}
}
private function applyShadowMethod( asset:ShadowMethodVO ):void
{
var obj:ShadowMapMethodBase = assets.GetObject( asset ) as ShadowMapMethodBase;
applyName( obj, asset );
if( obj is HardShadowMapMethod )
{
var hardShadowMapMethod:HardShadowMapMethod = obj as HardShadowMapMethod;
hardShadowMapMethod.alpha = asset.alpha;
hardShadowMapMethod.epsilon = asset.epsilon;
}
else if( obj is FilteredShadowMapMethod )
{
var filteredShadowMapMethod:FilteredShadowMapMethod = obj as FilteredShadowMapMethod;
filteredShadowMapMethod.alpha = asset.alpha;
filteredShadowMapMethod.epsilon = asset.epsilon;
}
else if( obj is SoftShadowMapMethod )
{
var softShadowMapMethod:SoftShadowMapMethod = obj as SoftShadowMapMethod;
softShadowMapMethod.numSamples = asset.samples;
softShadowMapMethod.range = asset.range;
softShadowMapMethod.alpha = asset.alpha;
softShadowMapMethod.epsilon = asset.epsilon;
}
else if( obj is DitheredShadowMapMethod )
{
var ditheredShadowMapMethod:DitheredShadowMapMethod = obj as DitheredShadowMapMethod;
ditheredShadowMapMethod.numSamples = asset.samples;
ditheredShadowMapMethod.range = asset.range;
ditheredShadowMapMethod.alpha = asset.alpha;
ditheredShadowMapMethod.epsilon = asset.epsilon;
}
else if( obj is CascadeShadowMapMethod )
{
var cascadeShadowMapMethod:CascadeShadowMapMethod = obj as CascadeShadowMapMethod;
cascadeShadowMapMethod.baseMethod = assets.GetObject( asset.baseMethod ) as SimpleShadowMapMethodBase;
}
else if( obj is NearShadowMapMethod )
{
var nearShadowMapMethod:NearShadowMapMethod = obj as NearShadowMapMethod;
nearShadowMapMethod.baseMethod = assets.GetObject( asset.baseMethod ) as SimpleShadowMapMethodBase;
}
}
private function applyAnimator( asset:AnimatorVO ):void
{
var obj:AnimatorBase = assets.GetObject( asset ) as AnimatorBase;
applyName( obj, asset );
obj.playbackSpeed = asset.playbackSpeed;
var newAnimatorBase:AnimatorBase;
var newAnimationSet:AnimationSetBase = assets.GetObject( asset.animationSet ) as AnimationSetBase;
var skeletonAnimator:SkeletonAnimator = obj as SkeletonAnimator;
if( skeletonAnimator )
{
var newSkeleton:Skeleton = assets.GetObject( asset.skeleton ) as Skeleton;
if( skeletonAnimator.skeleton != newSkeleton )
{
newAnimatorBase = new SkeletonAnimator( newAnimationSet as SkeletonAnimationSet, newSkeleton );
}
}
else
{
if( obj.animationSet != newAnimationSet )
{
newAnimatorBase = new VertexAnimator( newAnimationSet as VertexAnimationSet );
}
}
if( newAnimatorBase )
{
assets.ReplaceObject( obj, newAnimatorBase );
// TODO: use document, not assets
var meshes:Vector.<Object> = assets.GetObjectsByType( Mesh, "animator", obj ) as Vector.<Object>;
for each(var mesh:Mesh in meshes)
{
if( newAnimatorBase is SkeletonAnimator )
mesh.animator = SkeletonAnimator(newAnimatorBase);
if( newAnimatorBase is VertexAnimator )
mesh.animator = VertexAnimator(newAnimatorBase);
var vo:MeshVO = assets.GetAsset( mesh ) as MeshVO;
vo.animator = assets.GetAsset( newAnimatorBase ) as AnimatorVO;
}
}
}
private function applyContainer( asset:ContainerVO ):void
{
var obj:ObjectContainer3D = assets.GetObject( asset ) as ObjectContainer3D;
applyObject( asset );
obj.extra = new Object();
for each( var extra:ExtraItemVO in asset.extras )
{
obj.extra[extra.name] = extra.value;
}
}
private function applyObject( asset:ObjectVO ):void
{
var obj:Object3D = Object3D( assets.GetObject(asset) );
obj.name = asset.name;
obj.pivotPoint = new Vector3D( asset.pivotX, asset.pivotY, asset.pivotZ );
obj.x = asset.x;
obj.y = asset.y;
obj.z = asset.z;
obj.scaleX = asset.scaleX;
obj.scaleY = asset.scaleY;
obj.scaleZ = asset.scaleZ;
obj.rotationX = asset.rotationX;
obj.rotationY = asset.rotationY;
obj.rotationZ = asset.rotationZ;
}
private function applyLight( asset:LightVO ):void
{
var light:LightBase = assets.GetObject( asset ) as LightBase;
light.ambient = asset.ambient;
light.ambientColor = asset.ambientColor;
light.diffuse = asset.diffuse;
light.color = asset.color;
light.specular = asset.specular;
if( asset.shadowMapper )
{
light.shadowMapper = assets.GetObject( asset.shadowMapper ) as ShadowMapperBase;
}
applyObject( asset );
var directionalLight:DirectionalLight = light as DirectionalLight;
if( directionalLight )
{
var y:Number = -Math.sin( asset.elevationAngle*Math.PI/180);
var x:Number = Math.sin(Math.PI/2 - asset.elevationAngle*Math.PI/180)*Math.sin( asset.azimuthAngle*Math.PI/180);
var z:Number = Math.sin(Math.PI/2 - asset.elevationAngle*Math.PI/180)*Math.cos( asset.azimuthAngle*Math.PI/180);
directionalLight.direction = new Vector3D( x, y, z);
}
var pointLight:PointLight = light as PointLight;
if( pointLight )
{
pointLight.radius = asset.radius;
pointLight.fallOff = asset.fallOff;
}
}
private function applyMesh( asset:MeshVO ):void
{
var obj:Mesh = assets.GetObject( asset ) as Mesh;
applyContainer( asset );
obj.castsShadows = asset.castsShadows;
obj.geometry = assets.GetObject( asset.geometry ) as Geometry;
var animator:AnimatorBase = assets.GetObject( asset.animator ) as AnimatorBase;
if( animator is SkeletonAnimator )
{
var skeletonAnimator:SkeletonAnimator = animator as SkeletonAnimator;
var skeletonAnimationSet:SkeletonAnimationSet = skeletonAnimator.animationSet as SkeletonAnimationSet;
if( skeletonAnimationSet && skeletonAnimationSet.jointsPerVertex != asset.jointsPerVertex )
{
var newSkeletonAnimationSet:SkeletonAnimationSet = new SkeletonAnimationSet( asset.jointsPerVertex );
for each( var node:AnimationNodeBase in skeletonAnimationSet.animations )
{
newSkeletonAnimationSet.addAnimation( node );
}
assets.ReplaceObject( skeletonAnimationSet, newSkeletonAnimationSet );
var newAnimator:SkeletonAnimator = new SkeletonAnimator( newSkeletonAnimationSet, SkeletonAnimator(animator).skeleton );
assets.ReplaceObject( animator, newAnimator );
skeletonAnimator = newAnimator;
}
obj.animator = skeletonAnimator;
}
else if( animator is VertexAnimator )
{
var vertexAnimator:VertexAnimator = animator as VertexAnimator;
obj.animator = vertexAnimator;
}
else
{
obj.animator = null;
}
for( var i:int = 0; i < obj.subMeshes.length; i++ )
{
assets.ReplaceObject( assets.GetObject( asset.subMeshes.getItemAt(i) as AssetVO ), obj.subMeshes[i] );
}
for each( var sub:SubMeshVO in asset.subMeshes )
{
applySubMesh( sub );
}
}
private function applyLightPicker( asset:LightPickerVO ):void
{
var picker:StaticLightPicker = assets.GetObject( asset ) as StaticLightPicker;
var lights:Array = [];
for each( var light:SharedLightVO in asset.lights )
{
lights.push( assets.GetObject(light.linkedAsset) );
}
picker.lights = lights;
}
private function applySubMesh( asset:SubMeshVO ):void
{
var submesh:SubMesh = SubMesh( assets.GetObject(asset) );
submesh.material = MaterialBase( assets.GetObject(asset.material) );
}
private function applyMaterial( asset:MaterialVO ):void
{
var m:MaterialBase = MaterialBase( assets.GetObject(asset) );
var classType:Class;
var oldMaterial:MaterialBase;
if( asset.diffuseTexture )
{
if( asset.type == MaterialVO.SINGLEPASS )
{
classType = TextureMaterial;
}
else
{
classType = TextureMultiPassMaterial;
}
}
else
{
if( asset.type == MaterialVO.SINGLEPASS )
{
classType = ColorMaterial;
}
else
{
classType = ColorMultiPassMaterial;
}
}
if( !(m is classType) )
{
oldMaterial = m;
m = new classType();
}
m.alphaPremultiplied = asset.alphaPremultiplied;
m.repeat = asset.repeat;