-
Notifications
You must be signed in to change notification settings - Fork 22
/
fancy_spec.fy
492 lines (401 loc) · 12.7 KB
/
fancy_spec.fy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
class FancySpec {
"""
The FancySpec class is used for defining FancySpec testsuites.
Have a look at the tests/ directory to see some examples.
"""
def initialize: @description test_obj: @test_obj (@description) {
"""
@description Description @String@ for testcase.
@test_obj Object to be tested, defaults to @description.
"""
@spec_tests = []
@before_blocks = []
@after_blocks = []
@before_all_block = {}
@after_all_block = {}
}
def FancySpec describe: test_obj with: block {
"""
Factory method for creating FancySpec instances.
Calls @block with the new FancySpec instance as the receiver, then runs it.
Example:
FancySpec describe: MyTestClass with: {
# test cases using it:with:when: here.
}
"""
spec = FancySpec new: test_obj
block call_with_receiver: spec
spec run
}
def FancySpec describe: description for: test_obj with: block {
"""
Similar to @FancySpec~describe:with:@ but also taking an explicit @test_obj.
Example:
FancySpec describe: \"My cool class\" for: MyCoolClass with: {
# test cases using it:for:when: here.
}
"""
spec = FancySpec new: description test_obj: test_obj
block call_with_receiver: spec
spec run
}
def it: spec_info_string when: spec_block {
"""
@spec_info_string Info @String@ related to the test case defined in @spec_block.
@spec_block @Block@ that holds the testcase's code (including assertions).
Example:
it: \"should be an empty Array\" when: {
arr = [1,2,3]
3 times: { arr pop }
arr empty? is: true
}
"""
test = SpecTest new: spec_info_string block: spec_block
@spec_tests << test
}
def it: spec_info_string with: method_names when: spec_block {
"""
@spec_info_string Info @String@ related to the test case defined in @spec_block.
@method_name Name of Method that this testcase is related to.
@spec_block @Block@ that holds the testcase's code (including assertions).
Example:
it: \"should be an empty Array\" with: 'empty? when: {
arr = [1,2,3]
3 times: { arr pop }
arr empty? is: true
}
# you can also pass multiple method names if the test covers more
# than one method:
it: \"tests multiple methods\" with: ['method_a, 'method_b] when: {
# do something with method_a and method_b
}
"""
test = SpecTest new: spec_info_string block: spec_block
@spec_tests << test
match @test_obj {
case Class ->
method_names to_a each: |method_name| {
has_method? = @test_obj has_method?: method_name
{ has_method? = @test_obj metaclass has_method?: method_name } unless: has_method?
unless: has_method? do: {
SpecTest method_not_found: method_name for: @test_obj
}
}
}
}
alias_method: 'it:for:when: for: 'it:with:when:
def before: block {
"""
@block @Block@ to be run before all test cases.
"""
@before_all_block = block
}
def after: block {
"""
@block @Block@ to be run after all test cases.
"""
@after_all_block = block
}
def before_each: block {
"""
@block @Block@ to be run before each test case.
"""
@before_blocks << block
}
def after_each: block {
"""
@block @Block@ to be run after each test case.
"""
@after_blocks << block
}
def run {
"""
Runs a FancySpec's test cases.
"""
@before_all_block call
@spec_tests each: |test| {
@before_blocks each: |b| {
b call_with_receiver: test
}
test run: @test_obj
@after_blocks each: |b| {
b call_with_receiver: test
}
}
@after_all_block call
# untested_methods = @test_obj methods select: |m| {
# m tests size == 0
# }
# untested_methods empty? if_false: {
# ["WARNING: These methods need tests:",
# untested_methods map: 'name . select: |m| { m whitespace? not } . join: ", "] println
# }
}
class SpecTest {
"""
FancySpec test case class.
"""
read_slot: 'info_str
@@failed_positive = <[]>
@@failed_negative = <[]>
@@failed_count = 0
@@total_tests = 0
@@total_expectations = 0
@@methods_not_found = <[]>
def SpecTest add_expectation {
@@total_expectations = @@total_expectations + 1
}
def SpecTest failed_test: test {
"""
@actual_and_expected Pair of actual and expected values for a failed test case.
Gets called when a SpecTest failed.
"""
@@failed_positive[@@current_test_obj]: $ @@failed_positive[@@current_test_obj] || { Set new }
@@failed_positive[@@current_test_obj] << test
@@failed_count = @@failed_count + 1
}
def SpecTest failed_negative_test: test {
"""
@value Value that should not have occured.
Gets called when a negative SpecTest (using @NegativeMatcher@) failed.
"""
@@failed_negative[@@current_test_obj]: $ @@failed_negative[@@current_test_obj] || { Set new }
@@failed_negative[@@current_test_obj] << test
@@failed_count = @@failed_count + 1
}
def SpecTest method_not_found: method_name for: type {
{ @@methods_not_found[type]: []} unless: $ @@methods_not_found[type]
@@methods_not_found[type] << method_name
}
def SpecTest current {
@@current
}
def SpecTest print_failures: start_time no_failures: ok_block else: error_block {
let: '*stdout* be: *stderr* in: {
@@failed_positive each: |test_obj failed_tests| {
failed_tests each: |t| {
"\n> FAILED: " ++ test_obj ++ " " ++ (t info_str) print
t print_failed_positive
}
}
@@failed_negative each: |test_obj failed_tests| {
failed_tests each: |t| {
"\n> FAILED: " ++ test_obj ++ " " ++ (t info_str) print
t print_failed_negative
}
}
unless: (@@methods_not_found empty? ) do: {
"The following methods were referenced in tests but could not be found:" println
max_size = @@methods_not_found keys map: @{ to_s size } . max
@@methods_not_found each: |type, methods| {
*stdout* printf("%-#{max_size}s : ", type)
methods map: @{ to_fancy_message } . join: ", " . println
}
}
"\nRan #{@@total_tests} tests (#{@@total_expectations} expectations) with #{@@failed_count} failures in #{Time now - start_time} seconds." println
}
if: (@@failed_count == 0) then: ok_block else: error_block
}
def initialize: @info_str block: @block {
{ @@failed_positive = <[]> } unless: @@failed_positive
{ @@failed_negative = <[]> } unless: @@failed_negative
@failed_positive = []
@failed_negative = []
}
def run: test_obj {
@@current_test_obj = test_obj
@@current = self
@@total_tests = @@total_tests + 1
try {
@block call_with_receiver: self
} catch StandardError => e {
failed: (e, "No Exception") location: (e backtrace)
}
if: failed? then: {
"f" print
} else: {
"." print
}
}
def failed: actual_and_expected location: location (nil) {
unless: location do: {
location = caller() find: |l| { l =~ /__script__/ }
}
@failed_positive << (actual_and_expected, location)
SpecTest failed_test: self
}
def failed_negative: value {
{ value = [value, 'negative_failure] } unless: $ value responds_to?: 'at:
location = caller() find: |l| { l =~ /__script__/ }
@failed_negative << (value, location)
SpecTest failed_negative_test: self
}
def failed? {
@failed_positive empty? not || { @failed_negative empty? not }
}
def print_failed_positive {
" [" ++ (@failed_positive size) ++ " unexpected values]" println
print_failed_common: @failed_positive
}
def print_failed_negative {
" [" ++ (@failed_negative size) ++ " unexpected values]" println
"Should not have gotten the following values: " println
print_failed_common: @failed_negative
}
def print_failed_common: failures {
failures each: |f| {
actual, expected = f first
locations = f second
locations to_a map: |loc| {
loc = loc gsub(/:(\d+):in `[^']+'/, " +\1")
file, line = loc split: " +"
loc = "#{file} +#{line to_i - 1}" # somehow line is off by +1
loc = loc split: (Directory pwd + "/") . second
} . compact println
unless: (expected == 'negative_failure) do: {
" Expected: #{expected inspect}" println
" Received: #{actual inspect}" println
} else: {
" " ++ (actual inspect) println
}
}
}
}
class PositiveMatcher {
"""
PositiveMatcher expects its actual value to be equal to an
expected value.
If the values are not equal, a SpecTest failure is generated.
"""
def initialize: @actual_value {
SpecTest add_expectation
}
def == expected_value {
unless: (@actual_value == expected_value) do: {
SpecTest current failed: (@actual_value, expected_value)
}
}
def != expected_value {
unless: (@actual_value != expected_value) do: {
SpecTest current failed_negative: (@actual_value, expected_value)
}
}
def raise: exception_class {
try {
@actual_value call
# make sure we raise an exception.
# if no exepction raised at this point, we have an error.
SpecTest current failed: (nil, exception_class)
} catch exception_class {
# ok
} catch StandardError => e {
SpecTest current failed: (e class, exception_class)
}
}
def raise: exception_class with: block {
try {
@actual_value call
# same here
SpecTest current failed: (nil, exception_class)
} catch exception_class => e {
block call: [e]
# ok
} catch StandardError => e {
SpecTest current failed: (e class, exception_class)
}
}
def unknown_message: msg with_params: params {
"""
Forwards any other message and parameters to the object itself
and checks the return value.
"""
unless: (@actual_value receive_message: msg with_params: params) do: {
SpecTest current failed: (@actual_value, params first)
}
}
def be: block {
unless: (block call: [@actual_value]) do: {
SpecTest current failed: (@actual_value, nil)
}
}
}
class NegativeMatcher {
"""
NegativeMatcher expects its actual value to be unequal to an
expected value.
If the values are equal, a SpecTest failure is generated.
"""
def initialize: @actual_value {
SpecTest add_expectation
}
def == expected_value {
if: (@actual_value == expected_value) then: {
SpecTest current failed_negative: @actual_value
}
}
def != expected_value {
if: (@actual_value != expected_value) then: {
SpecTest current failed: (@actual_value, expected_value)
}
}
def raise: exception_class {
try {
@actual_value call
} catch exception_class {
SpecTest current failed_negative: (exception_class, nil)
} catch StandardError {
true
# ok
}
}
def unknown_message: msg with_params: params {
"""
Forwards any other message and parameters to the object itself
and checks the return value.
"""
if: (@actual_value receive_message: msg with_params: params) then: {
SpecTest current failed_negative: @actual_value
}
}
def be: block {
if: (block call: [@actual_value]) then: {
SpecTest current failed_negative: @actual_value
}
}
}
}
class Object {
def should {
"""
Returns a @PositiveMatcher@ for self.
"""
FancySpec PositiveMatcher new: self
}
alias_method: 'is for: 'should
alias_method: 'does for: 'should
def is: expected {
is == expected
}
def is_a: class {
is_a?: class . is: true
}
def is_not: expected {
does_not == expected
}
def should_not {
"""
Returns a @NegativeMatcher@ for self.
"""
FancySpec NegativeMatcher new: self
}
alias_method: 'is_not for: 'should_not
alias_method: 'does_not for: 'should_not
}
class Block {
def raises: exception_class {
FancySpec PositiveMatcher new: self . raise: exception_class
}
def raises: exception_class with: block {
FancySpec PositiveMatcher new: self . raise: exception_class with: block
}
}