-
Notifications
You must be signed in to change notification settings - Fork 68
/
SV3_1aParser.g4
3537 lines (2681 loc) · 108 KB
/
SV3_1aParser.g4
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
Copyright 2019 Alain Dargelas
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/
parser grammar SV3_1aParser;
options { tokenVocab = SV3_1aLexer; }
@parser::members {
void getCallingContext(antlr4::ParserRuleContext* ctx, std::vector<size_t>& context) {
antlr4::ParserRuleContext* current = ctx;
while (current != nullptr) {
context.push_back(current->getRuleIndex());
current = dynamic_cast<antlr4::ParserRuleContext*>(current->parent);
}
}
bool isInterfaceGenerator(antlr4::ParserRuleContext* ctx) {
std::vector<size_t> parent_ids(20);
getCallingContext(ctx, parent_ids);
bool isModuleOrProgramBlock = false;
for (size_t rule_type : parent_ids) {
if (!isModuleOrProgramBlock) {
if (rule_type == RuleChecker_declaration) {
return false;
}
switch(rule_type) {
case RuleModule_declaration:
case RuleProgram_declaration:
isModuleOrProgramBlock = true;
}
// First thing we found was an interface declration
if (rule_type == RuleInterface_declaration) {
return true;
}
}
// At this point we're either a program or a module, and trying to make
// sure that we don't have an interface in our ancestor chain. Spec says
// if we do we must return true
if (rule_type == RuleInterface_declaration) {
return true;
}
}
return false;
}
bool isCheckerGenerator(antlr4::ParserRuleContext* ctx) {
std::vector<size_t> parent_ids(20);
getCallingContext(ctx, parent_ids);
// In the SV Spec it states that a Checker Generator is only valid if the
// generate block is both checker.
for (size_t rule_type : parent_ids) {
switch (rule_type) {
case RuleModule_declaration:
case RuleInterface_declaration:
case RuleProgram_declaration:
return false;
}
if (rule_type == RuleChecker_declaration) {
return true;
}
}
return false;
}
bool isModuleGenerator(antlr4::ParserRuleContext* ctx) {
std::vector<size_t> parent_ids(20);
getCallingContext(ctx, parent_ids);
bool isGenerateInAModuleDeclaration = false;
// In the SV Spec it states that a Module Generator is only valid if the
// generate block is both within a module, and that module is not a child
// of an interface block. This code will first make sure the generate
// block is in a module, and then verify it is not a child of an interface
// block.
for (size_t rule_type : parent_ids) {
if (!isGenerateInAModuleDeclaration) {
switch (rule_type) {
case RuleChecker_declaration:
case RuleInterface_declaration:
return false;
}
// Treat programs as modules
if (rule_type == RuleModule_declaration || rule_type == RuleProgram_declaration) {
isGenerateInAModuleDeclaration = true;
}
}
// We are in a module, and only return false if we find an interface
// declaration in our ancestors.
if (rule_type == RuleInterface_declaration) {
return false;
}
}
return true;
}
}
top_level_rule : null_rule source_text EOF ; // SV files
top_level_library_rule : null_rule library_text EOF ; // .map files
library_text : ( library_descriptions )* ;
library_descriptions : library_declaration
| include_statement
| config_declaration
| SEMICOLON
;
library_declaration :
LIBRARY identifier file_path_spec ( COMMA file_path_spec )*
( INCDIR file_path_spec ( COMMA file_path_spec )* )? SEMICOLON ;
file_path_spec : (Simple_identifier | DIV | DOT | STAR | DOTSTAR | QMARK)+;
include_statement : INCLUDE file_path_spec SEMICOLON ;
source_text : ( timeunits_declaration )? ( description )* ;
null_rule : ; // Placeholder rule that create the "0" VObject, DO NOT REMOVE
description
: module_declaration
| udp_declaration
| interface_declaration
| program_declaration
| package_declaration
| surelog_macro_not_defined
| ( attribute_instance )* ( package_item
| bind_directive )
| config_declaration
| top_directives
;
module_nonansi_header : ( attribute_instance )* module_keyword ( lifetime )?
identifier ( package_import_declaration )* ( parameter_port_list )?
list_of_ports SEMICOLON ;
module_ansi_header : ( attribute_instance )* module_keyword ( lifetime )?
identifier ( package_import_declaration )* ( parameter_port_list )?
(list_of_port_declarations )? SEMICOLON ;
module_declaration
: module_nonansi_header ( timeunits_declaration )? ( module_item )*
ENDMODULE ( COLON identifier )?
| module_ansi_header ( timeunits_declaration )? ( non_port_module_item )*
ENDMODULE ( COLON identifier )?
| ( attribute_instance )* module_keyword ( lifetime )? identifier
OPEN_PARENS DOT STAR CLOSE_PARENS SEMICOLON
( timeunits_declaration )? ( module_item )* ENDMODULE
( COLON identifier )?
| EXTERN module_nonansi_header
| EXTERN module_ansi_header
;
module_keyword
: MODULE
| MACROMODULE
;
interface_nonansi_header :
( attribute_instance )* INTERFACE ( lifetime )? interface_identifier
( package_import_declaration )*( parameter_port_list )? list_of_ports SEMICOLON ;
interface_ansi_header :
( attribute_instance )* INTERFACE ( lifetime )? interface_identifier
( package_import_declaration )* ( parameter_port_list )? ( list_of_port_declarations )? SEMICOLON ;
interface_declaration
: interface_nonansi_header ( timeunits_declaration )? ( interface_item )*
ENDINTERFACE ( COLON interface_identifier )?
| interface_ansi_header ( timeunits_declaration )? ( non_port_interface_item )*
ENDINTERFACE ( COLON interface_identifier )?
| ( attribute_instance )? INTERFACE interface_identifier
OPEN_PARENS DOT STAR CLOSE_PARENS SEMICOLON
( timeunits_declaration )? ( interface_item )*
ENDINTERFACE ( COLON interface_identifier )?
| EXTERN interface_nonansi_header
| EXTERN interface_ansi_header
;
program_nonansi_header :
( attribute_instance ) PROGRAM ( lifetime )? identifier
( package_import_declaration )* ( parameter_port_list )? list_of_ports SEMICOLON ;
program_ansi_header :
( attribute_instance )* PROGRAM ( lifetime )? identifier
( package_import_declaration )* ( parameter_port_list )? ( list_of_port_declarations )? SEMICOLON ;
checker_declaration :
CHECKER identifier ( OPEN_PARENS checker_port_list? CLOSE_PARENS )? SEMICOLON
( ( attribute_instance )* checker_or_generate_item )* ENDCHECKER ( COLON identifier )?
;
program_declaration
: program_nonansi_header ( timeunits_declaration )? ( program_item )*
ENDPROGRAM ( COLON identifier )?
| program_ansi_header ( timeunits_declaration )? ( non_port_program_item )*
ENDPROGRAM ( COLON identifier )?
| ( attribute_instance )* PROGRAM identifier
OPEN_PARENS DOT STAR CLOSE_PARENS SEMICOLON
( timeunits_declaration )? ( program_item )*
ENDPROGRAM ( COLON identifier )?
| EXTERN program_nonansi_header
| EXTERN program_ansi_header
;
class_declaration
: ( VIRTUAL )? CLASS ( lifetime )? identifier ( parameter_port_list )?
( EXTENDS class_type ( OPEN_PARENS list_of_arguments CLOSE_PARENS )? )?
( IMPLEMENTS interface_class_type ( COMMA interface_class_type )* )?
SEMICOLON
( class_item )*
ENDCLASS ( COLON identifier )?
;
interface_class_type :
ps_identifier ( parameter_value_assignment )? ;
interface_class_declaration :
INTERFACE CLASS identifier ( parameter_port_list )?
( EXTENDS interface_class_type ( COMMA interface_class_type )* )? SEMICOLON ( interface_class_item )*
ENDCLASS ( COLON identifier )?
;
interface_class_item : type_declaration
| ( attribute_instance )* interface_class_method SEMICOLON
| local_parameter_declaration SEMICOLON
| parameter_declaration SEMICOLON
| SEMICOLON
;
interface_class_method :
PURE VIRTUAL method_prototype ;
package_declaration
: ( attribute_instance )* PACKAGE identifier SEMICOLON
( timeunits_declaration )? ( ( attribute_instance )* package_item )*
ENDPACKAGE ( COLON identifier )?
;
timeunits_declaration
: TIMEUNIT time_literal DIV time_literal SEMICOLON # TimeUnitsDecl_TimeUnitDiv
| TIMEUNIT time_literal SEMICOLON # TimeUnitsDecl_TimeUnit
| TIMEPRECISION time_literal SEMICOLON # TimeUnitsDecl_TimePrecision
| TIMEUNIT time_literal SEMICOLON TIMEPRECISION
time_literal SEMICOLON # TimeUnitsDecl_TimeUnitTimePrecision
| TIMEPRECISION time_literal SEMICOLON TIMEUNIT
time_literal SEMICOLON # TimeUnitsDecl_TimePrecisionTimeUnit
;
parameter_port_list
: POUND OPEN_PARENS list_of_param_assignments
( COMMA parameter_port_declaration )* CLOSE_PARENS
| POUND OPEN_PARENS parameter_port_declaration
( COMMA parameter_port_declaration )* CLOSE_PARENS
| POUND OPEN_PARENS CLOSE_PARENS
;
parameter_port_declaration
: parameter_declaration
| local_parameter_declaration
| data_type list_of_param_assignments
| TYPE list_of_type_assignments
;
list_of_ports : OPEN_PARENS port ( COMMA port )* CLOSE_PARENS ;
list_of_port_declarations : OPEN_PARENS ( ( attribute_instance )*
ansi_port_declaration ( COMMA ( attribute_instance )*
ansi_port_declaration )* )? CLOSE_PARENS ;
port_declaration
: ( attribute_instance )* ( inout_declaration
| input_declaration
| output_declaration
| ref_declaration
| interface_port_declaration );
port
: (port_expression)?
| DOT identifier OPEN_PARENS (port_expression)? CLOSE_PARENS
;
port_expression :
port_reference
| OPEN_CURLY port_reference ( COMMA port_reference )* CLOSE_CURLY
;
port_reference : identifier constant_select ;
port_direction
: INPUT
| OUTPUT
| INOUT
| REF
;
net_port_header : ( port_direction )? net_port_type ;
variable_port_header : ( port_direction )? variable_port_type ;
interface_port_header
: interface_identifier ( DOT identifier )?
| INTERFACE ( DOT identifier )?
;
ansi_port_declaration
: ( net_port_header | interface_port_header ) identifier
( unpacked_dimension )* ( ASSIGN_OP constant_expression )?
| ( variable_port_header )? identifier variable_dimension*
( ASSIGN_OP constant_expression )?
| ( net_port_header | variable_port_header) DOT identifier OPEN_PARENS
( expression )? CLOSE_PARENS
;
elaboration_system_task
: DOLLAR Simple_identifier ( ( OPEN_PARENS number ( COMMA list_of_arguments )? CLOSE_PARENS )? SEMICOLON
| ( OPEN_PARENS list_of_arguments CLOSE_PARENS )? SEMICOLON )
;
module_common_item
: module_or_generate_item_declaration
| module_instantiation
| assertion_item
| bind_directive
| continuous_assign
| net_alias
| initial_construct
| final_construct
| always_construct
| loop_generate_construct
| conditional_generate_construct
| elaboration_system_task
| system_task
;
module_item
: port_declaration SEMICOLON
| non_port_module_item
;
module_or_generate_item
: ( attribute_instance )* ( parameter_override
| gate_instantiation
| udp_instantiation
| module_instantiation
| module_common_item
) ;
module_or_generate_item_declaration
: package_or_generate_item_declaration
| genvar_declaration
| clocking_declaration
| DEFAULT CLOCKING identifier SEMICOLON
| DEFAULT DISABLE IFF expression_or_dist SEMICOLON
;
non_port_module_item
: generate_region
| module_or_generate_item
| specify_block
| ( attribute_instance )* specparam_declaration
| program_declaration
| module_declaration
| timeunits_declaration
| system_task SEMICOLON
| surelog_macro_not_defined
| pragma_directive
;
parameter_override : DEFPARAM list_of_defparam_assignments SEMICOLON ;
bind_directive : BIND identifier (COLON? identifier constant_bit_select (COMMA identifier constant_bit_select)*)? bind_instantiation ;
bind_instantiation
: module_instantiation
| checker_instantiation
;
interface_or_generate_item
: ( attribute_instance )* ( module_common_item
| MODPORT modport_item ( COMMA modport_item )* SEMICOLON
| extern_tf_declaration )
;
extern_tf_declaration
: EXTERN method_prototype SEMICOLON
| EXTERN FORKJOIN task_prototype SEMICOLON
;
interface_item
: port_declaration SEMICOLON
| non_port_interface_item
;
non_port_interface_item
: generated_interface_instantiation
| ( attribute_instance )* specparam_declaration
| interface_or_generate_item
| program_declaration
| interface_declaration
| timeunits_declaration
| surelog_macro_not_defined
;
program_item
: port_declaration SEMICOLON
| non_port_program_item
;
non_port_program_item
: ( attribute_instance )* ( continuous_assign
| module_or_generate_item_declaration
| specparam_declaration
| initial_construct
| final_construct
| concurrent_assertion_item )
| timeunits_declaration
| program_generate_item
| surelog_macro_not_defined
;
program_generate_item :
loop_generate_construct
| conditional_generate_construct
| generate_region
| elaboration_system_task
;
checker_port_list :
checker_port_item ( COMMA checker_port_item )* ;
checker_port_item :
attribute_instance* (INPUT | OUTPUT)? property_formal_type identifier
variable_dimension* ( ASSIGN_OP property_actual_arg )? ;
checker_or_generate_item
: checker_or_generate_item_declaration
| initial_construct
| always_construct
| final_construct
| assertion_item
| continuous_assign
| checker_generate_item
;
checker_or_generate_item_declaration
: RAND* data_declaration
| function_declaration
| checker_declaration
| assertion_item_declaration
| covergroup_declaration
| overload_declaration
| genvar_declaration
| clocking_declaration
| DEFAULT CLOCKING identifier SEMICOLON
| DEFAULT DISABLE IFF expression_or_dist SEMICOLON
| SEMICOLON
| surelog_macro_not_defined
;
checker_generate_item
: loop_generate_construct
| conditional_generate_construct
| generate_region
| elaboration_system_task
;
class_item
: ( attribute_instance )* ( class_property
| class_method
| class_constraint
| type_declaration
| class_declaration
| covergroup_declaration )
| local_parameter_declaration SEMICOLON
| parameter_declaration SEMICOLON
| surelog_macro_not_defined
| SEMICOLON
;
class_property
: ( const_type )? ( property_qualifier )* data_declaration
| const_type ( class_item_qualifier )* data_type identifier
( ASSIGN_OP constant_expression )? SEMICOLON
;
pure_virtual_qualifier : PURE VIRTUAL ;
extern_qualifier : EXTERN ;
class_method
: ( method_qualifier )* (task_declaration | function_declaration | class_constructor_declaration)
| pure_virtual_qualifier ( class_item_qualifier )* method_prototype SEMICOLON
| extern_qualifier ( method_qualifier )* ( method_prototype SEMICOLON | class_constructor_prototype )
;
class_constructor_prototype : FUNCTION NEW ( OPEN_PARENS ( tf_port_list )? CLOSE_PARENS )?;
class_constraint
: constraint_prototype
| constraint_declaration
;
class_item_qualifier
: STATIC # ClassItemQualifier_Static
| PROTECTED # ClassItemQualifier_Protected
| LOCAL # ClassItemQualifier_Local
;
property_qualifier
: RAND # PropQualifier_Rand
| RANDC # PropQualifier_Randc
| class_item_qualifier # PropQualifier_ClassItem
;
method_qualifier
: VIRTUAL # MethodQualifier_Virtual
| class_item_qualifier # MethodQualifier_ClassItem
;
method_prototype
: task_prototype
| function_prototype
;
super_dot_new : SUPER DOT NEW ;
class_constructor_declaration
: FUNCTION ( class_scope )? NEW ( OPEN_PARENS ( tf_port_list )? CLOSE_PARENS )? SEMICOLON
( block_item_declaration )*
( super_dot_new ( OPEN_PARENS list_of_arguments CLOSE_PARENS )? SEMICOLON )?
( function_statement_or_null )*
ENDFUNCTION ( COLON NEW )? ;
constraint_declaration : ( STATIC )? CONSTRAINT identifier constraint_block ;
constraint_block : OPEN_CURLY ( constraint_block_item )* CLOSE_CURLY ;
constraint_block_item
: SOLVE solve_before_list BEFORE solve_before_list SEMICOLON
| constraint_expression
;
solve_before_list :
constraint_primary ( COMMA constraint_primary )* ;
constraint_primary :
( implicit_class_handle DOT | class_scope )? ( dollar_root_keyword )? identifier (( OPEN_BRACKET constant_expression CLOSE_BRACKET )* DOT identifier)* select ;
constraint_expression
: SOFT? expression_or_dist SEMICOLON
| uniqueness_constraint SEMICOLON
| expression IMPLY constraint_set
| IF OPEN_PARENS expression CLOSE_PARENS constraint_set
( ELSE constraint_set )?
| FOREACH OPEN_PARENS ps_or_hierarchical_array_identifier OPEN_BRACKET loop_variables
CLOSE_BRACKET CLOSE_PARENS constraint_set
| DISABLE SOFT constraint_primary SEMICOLON
;
uniqueness_constraint :
UNIQUE OPEN_CURLY open_range_list CLOSE_CURLY ;
constraint_set
: constraint_expression
| OPEN_CURLY ( constraint_expression )* CLOSE_CURLY
;
dist_list : dist_item ( COMMA dist_item )* ;
dist_item : value_range ( dist_weight )? ;
/* Replaced by COLON DIV : ASSIGN_RANGE : ':/' ; */
dist_weight
: ASSIGN_VALUE expression # DistWeight_AssignValue
| COLON DIV expression # DistWeight_AssignRange
;
constraint_prototype : (extern_qualifier | pure_keyword )? ( STATIC )? CONSTRAINT identifier SEMICOLON ;
extern_constraint_declaration :
( STATIC )? CONSTRAINT class_scope identifier constraint_block ;
identifier_list : identifier ( COMMA identifier )* ;
package_item
: package_or_generate_item_declaration
| specparam_declaration
| anonymous_program
| package_export_declaration
| timeunits_declaration
;
package_or_generate_item_declaration
: net_declaration
| data_declaration
| task_declaration
| function_declaration
| checker_declaration
| dpi_import_export
| extern_constraint_declaration
| class_declaration
| interface_class_declaration
| class_constructor_declaration
| parameter_declaration SEMICOLON
| local_parameter_declaration SEMICOLON
| covergroup_declaration
| overload_declaration
| assertion_item_declaration
| SEMICOLON
;
anonymous_program : PROGRAM SEMICOLON ( anonymous_program_item )* ENDPROGRAM ;
anonymous_program_item
: task_declaration
| function_declaration
| class_declaration
| covergroup_declaration
| class_constructor_declaration
| SEMICOLON
| surelog_macro_not_defined
;
local_parameter_declaration
: LOCALPARAM ( data_type_or_implicit | TYPE ) list_of_param_assignments
;
parameter_declaration
: PARAMETER ( data_type_or_implicit | TYPE ) list_of_param_assignments
;
specparam_declaration :
SPECPARAM ( packed_dimension )? list_of_specparam_assignments SEMICOLON ;
inout_declaration : INOUT net_port_type list_of_port_identifiers ;
input_declaration
: INPUT ( net_port_type list_of_port_identifiers
| variable_port_type? list_of_variable_identifiers )
;
output_declaration
: OUTPUT ( net_port_type list_of_port_identifiers
| variable_port_type? list_of_variable_port_identifiers )
;
interface_port_declaration
: interface_identifier list_of_interface_identifiers
| interface_identifier DOT identifier
list_of_interface_identifiers
;
ref_declaration : REF variable_port_type list_of_variable_identifiers ;
data_declaration
: ( const_type )? ( ( lifetime )? variable_declaration | var_type ( lifetime )? variable_impl_declaration )
| type_declaration
| package_import_declaration
| net_type_declaration
;
variable_impl_declaration : ( data_type_or_implicit
| signing ( packed_dimension )*
| ( packed_dimension )+
)
list_of_variable_decl_assignments SEMICOLON ;
variable_declaration : ( data_type
| signing ( packed_dimension )*
| ( packed_dimension )+
)
list_of_variable_decl_assignments SEMICOLON ;
package_import_declaration :
IMPORT package_import_item ( COMMA package_import_item )* SEMICOLON ;
package_import_item
: identifier COLONCOLON ( identifier | STAR )
;
package_export_declaration
: EXPORT STARCOLONCOLONSTAR SEMICOLON
| EXPORT package_import_item ( COMMA package_import_item )? SEMICOLON
;
genvar_declaration : GENVAR identifier_list SEMICOLON ;
net_declaration
: net_type ( drive_strength | charge_strength )? ( VECTORED | SCALARED )?
data_type_or_implicit ( delay3 )? list_of_net_decl_assignments SEMICOLON
| identifier delay_control? list_of_net_decl_assignments SEMICOLON
| INTERCONNECT implicit_data_type ( pound_delay_value )? identifier unpacked_dimension*
( COMMA identifier unpacked_dimension* )? SEMICOLON
;
type_declaration
: TYPEDEF
(
( (data_type | net_type) identifier variable_dimension* )
| ( identifier constant_bit_select DOT identifier identifier )
| ( ( enum_keyword | struct_keyword | union_keyword | class_keyword | interface_class_keyword )? identifier )
)
SEMICOLON
;
enum_keyword : ENUM;
struct_keyword : STRUCT;
union_keyword : UNION;
class_keyword : CLASS;
interface_class_keyword : INTERFACE CLASS;
net_type_declaration
: NETTYPE
(
( data_type identifier ( WITH ( package_scope | class_scope )? identifier )? )
| ( ( package_scope | class_scope )? identifier identifier )
)
SEMICOLON
;
lifetime
: STATIC # Lifetime_Static
| AUTOMATIC # Lifetime_Automatic
;
casting_type
: simple_type
| primary_literal
| ( package_scope | class_scope )? identifier constant_select ( OPEN_BRACKET constant_range_expression CLOSE_BRACKET )?
// | constant_concatenation ( OPEN_BRACKET constant_range_expression CLOSE_BRACKET )?
// | constant_multiple_concatenation ( OPEN_BRACKET constant_range_expression CLOSE_BRACKET )?
// | subroutine_call
// | OPEN_PARENS constant_mintypmax_expression CLOSE_PARENS
| OPEN_PARENS constant_expression CLOSE_PARENS
// | casting_type TICK ( OPEN_PARENS constant_expression CLOSE_PARENS | constant_concatenation | constant_multiple_concatenation )
// | constant_assignment_pattern_expression
// | type_reference
| signing
| string_type
| const_type
| system_task
;
data_type
: integer_vector_type ( signing )? ( packed_dimension )*
| integer_atom_type ( signing )?
| non_integer_type
| struct_union ( packed_keyword ( signing )? )? OPEN_CURLY struct_union_member ( struct_union_member )* CLOSE_CURLY ( packed_dimension )*
| ENUM ( enum_base_type )? OPEN_CURLY enum_name_declaration ( COMMA enum_name_declaration )* CLOSE_CURLY
| string_type
| chandle_type
| VIRTUAL ( INTERFACE )? interface_identifier ( parameter_value_assignment )? ( DOT identifier )?
| ( class_scope | package_scope )? identifier ( ( packed_dimension )+ | (( parameter_value_assignment )? ( COLONCOLON identifier ( parameter_value_assignment )? )*) )
| event_type
| type_reference
;
packed_keyword : PACKED;
string_type : STRING ;
string_value : String ;
chandle_type : CHANDLE ;
event_type : EVENT ;
const_type : CONST ;
var_type : VAR ;
data_type_or_implicit
: data_type
| ( signing )? ( packed_dimension )*
;
implicit_data_type :
signing? packed_dimension*;
enum_base_type
: integer_atom_type ( signing )?
| integer_vector_type ( signing )? ( packed_dimension )?
| identifier ( packed_dimension )?
;
enum_name_declaration
: identifier
( OPEN_BRACKET Integral_number ( COLON Integral_number )? CLOSE_BRACKET )?
( ASSIGN_OP constant_expression )?
;
class_scope : class_type COLONCOLON ;
// identifier was inlined to lexer tokens for parsing speed
class_type :
( Simple_identifier
| Escaped_identifier
| THIS
| RANDOMIZE
| SAMPLE
| DOLLAR_UNIT ) ( parameter_value_assignment )? ( COLONCOLON identifier ( parameter_value_assignment )? )*
;
integer_type
: integer_vector_type
| integer_atom_type
;
integer_atom_type
: BYTE
| SHORTINT
| INT
| LONGINT
| INTEGER
| TIME
;
integer_vector_type
: BIT
| LOGIC
| REG
;
non_integer_type
: SHORTREAL
| REAL
| REALTIME
;
net_type
: SUPPLY0
| SUPPLY1
| TRI
| TRIAND
| TRIOR
| TRIREG
| TRI0
| TRI1
| UWIRE
| WIRE
| WAND
| WOR
;
net_port_type :
net_type? data_type_or_implicit
| identifier
| INTERCONNECT implicit_data_type ;
variable_port_type
: var_data_type
| OPEN_BRACKET constant_range CLOSE_BRACKET
;
var_data_type :
data_type
| var_type data_type_or_implicit ;
signing
: SIGNED
| UNSIGNED
;
simple_type
: integer_type
| non_integer_type
| ps_type_identifier
;
random_qualifier :
RAND # RandomQualifier_Rand
| RANDC # RandomQualifier_RandC
;
struct_union_member :
( attribute_instance )* ( random_qualifier )? data_type_or_void list_of_variable_decl_assignments SEMICOLON ;
data_type_or_void
: data_type
| VOID
;
struct_union
: struct_keyword
| union_keyword ( tagged_keyword )?
;
tagged_keyword : TAGGED;
type_reference :
TYPE OPEN_PARENS ( expression | data_type ) CLOSE_PARENS;
drive_strength
: OPEN_PARENS ( SUPPLY0 | STRONG0 | PULL0 | WEAK0 ) COMMA ( SUPPLY1 | STRONG1 | PULL1 | WEAK1 | HIGHZ1 ) CLOSE_PARENS
| OPEN_PARENS ( SUPPLY1 | STRONG1 | PULL1 | WEAK1 | HIGHZ1 ) COMMA ( SUPPLY0 | STRONG0 | PULL0 | WEAK0 | HIGHZ0 ) CLOSE_PARENS
| OPEN_PARENS HIGHZ0 COMMA ( SUPPLY1 | STRONG1 | PULL1 | WEAK1 ) CLOSE_PARENS
| OPEN_PARENS HIGHZ1 COMMA ( SUPPLY0 | STRONG0 | PULL0 | WEAK0 ) CLOSE_PARENS
;
strength0
: SUPPLY0
| STRONG0
| PULL0
| WEAK0
;
strength1
: SUPPLY1
| STRONG1
| PULL1
| WEAK1
;
charge_strength
: SMALL
| MEDIUM
| LARGE
;
delay3
: pound_delay_value
| POUND OPEN_PARENS mintypmax_expression ( COMMA mintypmax_expression
( COMMA mintypmax_expression )? )? CLOSE_PARENS
;
delay2
: pound_delay_value
| POUND OPEN_PARENS mintypmax_expression
( COMMA mintypmax_expression )? CLOSE_PARENS
;
pound_delay_value
: Pound_Pound_delay (time_unit)?
| Pound_delay (time_unit)?
| POUND delay_value ;
delay_value