[#2663] Switch Grimoire over to ClojureDocs

This handles only the web views, as the data from the middleware needs
further processing.

cider-apropos.el

@@ -42,7 +42,7 @@
 
 (defcustom cider-apropos-actions '(("display-doc" . cider-doc-lookup)
                                    ("find-def" . cider--find-var)
-                                   ("lookup-on-grimoire" . cider-grimoire-lookup))
+                                   ("lookup-on-clojuredocs" . cider-clojuredocs-lookup))
   "Controls the actions to be applied on the symbol found by an apropos search.
 The first action key in the list will be selected as default.  If the list
 contains only one action key, the associated action function will be

cider-clojuredocs.el

@@ -0,0 +1,131 @@
+;;; cider-clojuredocs.el --- ClojureDocs integration -*- lexical-binding: t -*-
+
+;; Copyright © 2014-2019 Bozhidar Batsov and CIDER contributors
+;;
+;; Author: Bozhidar Batsov <bozhidar@batsov.com>
+
+;; This program is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+;; This file is not part of GNU Emacs.
+
+;;; Commentary:
+
+;; A few commands for ClojureDocs documentation lookup.
+
+;;; Code:
+
+(require 'cider-client)
+(require 'cider-common)
+(require 'subr-x)
+(require 'cider-compat)
+(require 'cider-popup)
+
+(require 'nrepl-dict)
+
+(require 'url-vars)
+
+(defconst cider-clojuredocs-url "https://clojuredocs.org/")
+
+(defconst cider-clojuredocs-buffer "*cider-clojuredocs*")
+
+(defun cider-sync-request:clojuredocs-lookup (ns sym)
+  "Perform nREPL \"resource\" op with NS and SYM."
+  (thread-first `("op" "clojuredocs-lookup"
+                  "ns" ,ns
+                  "symbol" ,sym)
+    (cider-nrepl-send-sync-request)
+    (nrepl-dict-get "clojuredocs")))
+
+(defun cider-clojuredocs-replace-special (name)
+  "Convert the dashes in NAME to a ClojureDocs friendly format.
+We need to handle \"?\", \".\", \"..\" and \"/\"."
+  (thread-last name
+    (replace-regexp-in-string "\\?" "_q")
+    (replace-regexp-in-string "\\(\\.+\\)" "_\\1")
+    (replace-regexp-in-string "/" "fs")))
+
+(defun cider-clojuredocs-url (name ns)
+  "Generate a ClojureDocs url from NAME and NS."
+  (let ((base-url cider-clojuredocs-url))
+    (when (and name ns)
+      (concat base-url ns "/" (cider-clojuredocs-replace-special name)))))
+
+(defun cider-clojuredocs-web-lookup (symbol)
+  "Open the ClojureDocs documentation for SYMBOL in a web browser."
+  (if-let* ((var-info (cider-var-info symbol)))
+      (let ((name (nrepl-dict-get var-info "name"))
+            (ns (nrepl-dict-get var-info "ns")))
+        (browse-url (cider-clojuredocs-url name ns)))
+    (error "Symbol %s not resolved" symbol)))
+
+;;;###autoload
+(defun cider-clojuredocs-web (&optional arg)
+  "Open ClojureDocs documentation in the default web browser.
+
+Prompts for the symbol to use, or uses the symbol at point, depending on
+the value of `cider-prompt-for-symbol'.  With prefix arg ARG, does the
+opposite of what that option dictates."
+  (interactive "P")
+  (funcall (cider-prompt-for-symbol-function arg)
+           "ClojureDocs doc for"
+           #'cider-clojuredocs-web-lookup))
+
+(defun cider-create-clojuredocs-buffer (content)
+  "Create a new ClojureDocs buffer with CONTENT."
+  (with-current-buffer (cider-popup-buffer cider-clojuredocs-buffer t)
+    (read-only-mode -1)
+    (insert content)
+    (cider-popup-buffer-mode 1)
+    (view-mode 1)
+    (goto-char (point-min))
+    (current-buffer)))
+
+(defun cider-clojuredocs--content (dict)
+  "Generate a nice string from DICT."
+  (with-temp-buffer
+    (insert "= " (nrepl-dict-get dict "ns") "/" (nrepl-dict-get dict "name") "\n")
+    (insert "== See Also\n")
+    (insert "== Examples\n")
+    (insert "== Notes\n")
+    (buffer-string)))
+
+(defun cider-clojuredocs-lookup (symbol)
+  "Look up the ClojureDocs documentation for SYMBOL.
+
+If SYMBOL is a special form, the clojure.core ns is used, as is
+ClojureDocs's convention."
+  (if-let* ((var-info (cider-var-info symbol)))
+      (let* ((name (nrepl-dict-get var-info "name"))
+             (ns (nrepl-dict-get var-info "ns" "clojure.core"))
+             (docs (cider-sync-request:clojuredocs-lookup ns name)))
+        (pop-to-buffer (cider-create-clojuredocs-buffer (cider-clojuredocs--content docs))))
+    (error "Symbol %s not resolved" symbol)))
+
+;;;###autoload
+(defun cider-clojuredocs (&optional arg)
+  "Open ClojureDocs documentation in a popup buffer.
+
+Prompts for the symbol to use, or uses the symbol at point, depending on
+the value of `cider-prompt-for-symbol'.  With prefix arg ARG, does the
+opposite of what that option dictates."
+  (interactive "P")
+  (when (derived-mode-p 'clojurescript-mode)
+    (user-error "`cider-clojuredocs' doesn't support ClojureScript"))
+  (funcall (cider-prompt-for-symbol-function arg)
+           "ClojureDocs doc for"
+           #'cider-clojuredocs-lookup))
+
+(provide 'cider-clojuredocs)
+
+;;; cider-clojuredocs.el ends here

cider-doc.el

@@ -31,7 +31,7 @@
 (require 'cider-util)
 (require 'cider-popup)
 (require 'cider-client)
-(require 'cider-grimoire)
+(require 'cider-clojuredocs)
 (require 'nrepl-dict)
 (require 'org-table)
 (require 'button)
@@ -70,10 +70,10 @@
     (define-key cider-doc-map (kbd "C-e") #'cider-apropos-documentation-select)
     (define-key cider-doc-map (kbd "d") #'cider-doc)
     (define-key cider-doc-map (kbd "C-d") #'cider-doc)
-    (define-key cider-doc-map (kbd "r") #'cider-grimoire)
-    (define-key cider-doc-map (kbd "C-r") #'cider-grimoire)
-    (define-key cider-doc-map (kbd "w") #'cider-grimoire-web)
-    (define-key cider-doc-map (kbd "C-w") #'cider-grimoire-web)
+    (define-key cider-doc-map (kbd "r") #'cider-clojuredocs)
+    (define-key cider-doc-map (kbd "C-r") #'cider-clojuredocs)
+    (define-key cider-doc-map (kbd "w") #'cider-clojuredocs-web)
+    (define-key cider-doc-map (kbd "C-w") #'cider-clojuredocs-web)
     (define-key cider-doc-map (kbd "j") #'cider-javadoc)
     (define-key cider-doc-map (kbd "C-j") #'cider-javadoc)
     cider-doc-map)
@@ -83,8 +83,8 @@
   '("Documentation"
     ["CiderDoc" cider-doc]
     ["JavaDoc in browser" cider-javadoc]
-    ["Grimoire" cider-grimoire]
-    ["Grimoire in browser" cider-grimoire-web]
+    ["Clojuredocs" cider-clojuredocs]
+    ["Clojuredocs in browser" cider-clojuredocs-web]
     ["Search symbols" cider-apropos]
     ["Search symbols & select" cider-apropos-select]
     ["Search documentation" cider-apropos-documentation]
@@ -156,17 +156,17 @@
 (defvar cider-docview-mode-map
   (let ((map (make-sparse-keymap)))
     (define-key map "q" #'cider-popup-buffer-quit-function)
-    (define-key map "g" #'cider-docview-grimoire)
-    (define-key map "G" #'cider-docview-grimoire-web)
+    (define-key map "g" #'cider-docview-clojuredocs)
+    (define-key map "G" #'cider-docview-clojuredocs-web)
     (define-key map "j" #'cider-docview-javadoc)
     (define-key map "s" #'cider-docview-source)
     (define-key map (kbd "<backtab>") #'backward-button)
     (define-key map (kbd "TAB") #'forward-button)
     (easy-menu-define cider-docview-mode-menu map
       "Menu for CIDER's doc mode"
       `("CiderDoc"
-        ["Look up in Grimoire" cider-docview-grimoire]
-        ["Look up in Grimoire (browser)" cider-docview-grimoire-web]
+        ["Look up in Clojuredocs" cider-docview-clojuredocs]
+        ["Look up in Clojuredocs (browser)" cider-docview-clojuredocs-web]
         ["JavaDoc in browser" cider-docview-javadoc]
         ["Jump to source" cider-docview-source]
         "--"
@@ -242,23 +242,23 @@ opposite of what that option dictates."
 
 (defvar cider-buffer-ns)
 
-(declare-function cider-grimoire-lookup "cider-grimoire")
+(declare-function cider-clojuredocs-lookup "cider-clojuredocs")
 
-(defun cider-docview-grimoire ()
-  "Return the grimoire documentation for `cider-docview-symbol'."
+(defun cider-docview-clojuredocs ()
+  "Return the clojuredocs documentation for `cider-docview-symbol'."
   (interactive)
   (if cider-buffer-ns
-      (cider-grimoire-lookup cider-docview-symbol)
-    (error "%s cannot be looked up on Grimoire" cider-docview-symbol)))
+      (cider-clojuredocs-lookup cider-docview-symbol)
+    (error "%s cannot be looked up on ClojureDocs" cider-docview-symbol)))
 
-(declare-function cider-grimoire-web-lookup "cider-grimoire")
+(declare-function cider-clojuredocs-web-lookup "cider-clojuredocs")
 
-(defun cider-docview-grimoire-web ()
-  "Open the grimoire documentation for `cider-docview-symbol' in a web browser."
+(defun cider-docview-clojuredocs-web ()
+  "Open the clojuredocs documentation for `cider-docview-symbol' in a web browser."
   (interactive)
   (if cider-buffer-ns
-      (cider-grimoire-web-lookup cider-docview-symbol)
-    (error "%s cannot be looked up on Grimoire" cider-docview-symbol)))
+      (cider-clojuredocs-web-lookup cider-docview-symbol)
+    (error "%s cannot be looked up on ClojureDocs" cider-docview-symbol)))
 
 (defconst cider-doc-buffer "*cider-doc*")
 

cider-xref.el

@@ -45,7 +45,7 @@
 
 (defcustom cider-xref-actions '(("display-doc" . cider-doc-lookup)
                                 ("find-def" . cider--find-var)
-                                ("lookup-on-grimoire" . cider-grimoire-lookup))
+                                ("lookup-on-clojuredocs" . cider-clojuredocs-lookup))
   "Controls the actions to be applied on the symbol found by an xref search.
 The first action key in the list will be selected as default.  If the list
 contains only one action key, the associated action function will be

cider.el

@@ -400,7 +400,7 @@ Elements of the list are artifact name and list of exclusions to apply for the a
 (defconst cider-latest-clojure-version "1.10.0"
   "Latest supported version of Clojure.")
 
-(defconst cider-required-middleware-version "0.22.0-beta8"
+(defconst cider-required-middleware-version "0.22.0-beta9"
   "The CIDER nREPL version that's known to work properly with CIDER.")
 
 (defcustom cider-jack-in-auto-inject-clojure nil

doc/modules/ROOT/pages/caveats.adoc

@@ -9,7 +9,6 @@ should be aware of.
 Currently, the following features are not supported for ClojureScript
 development:
 
-* Grimoire lookup
 * Reloading
 * Running tests
 * Tracing

doc/modules/ROOT/pages/repl/keybindings.adoc

@@ -57,7 +57,7 @@ kbd:[C-c C-d C-j]
 
 | kbd:[C-c C-d r] +
 kbd:[C-c C-d C-r]
-| Lookup symbol in Grimoire.
+| Lookup symbol in ClojureDocs.
 
 | kbd:[C-c C-d a] +
 kbd:[C-c C-d C-a]