-
-
Notifications
You must be signed in to change notification settings - Fork 606
/
identifier.d
306 lines (271 loc) · 8.46 KB
/
identifier.d
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
/**
* Defines an identifier, which is the name of a `Dsymbol`.
*
* Copyright: Copyright (C) 1999-2020 by The D Language Foundation, All Rights Reserved
* Authors: $(LINK2 http://www.digitalmars.com, Walter Bright)
* License: $(LINK2 http://www.boost.org/LICENSE_1_0.txt, Boost License 1.0)
* Source: $(LINK2 https://github.com/dlang/dmd/blob/master/src/dmd/identifier.d, _identifier.d)
* Documentation: https://dlang.org/phobos/dmd_identifier.html
* Coverage: https://codecov.io/gh/dlang/dmd/src/master/src/dmd/identifier.d
*/
module dmd.identifier;
import core.stdc.ctype;
import core.stdc.stdio;
import core.stdc.string;
import dmd.globals;
import dmd.id;
import dmd.root.outbuffer;
import dmd.root.rootobject;
import dmd.root.string;
import dmd.root.stringtable;
import dmd.tokens;
import dmd.utf;
/***********************************************************
*/
extern (C++) final class Identifier : RootObject
{
private:
const int value;
const char[] name;
public:
/**
Construct an identifier from a D slice
Note: Since `name` needs to be `\0` terminated for `toChars`,
no slice overload is provided yet.
Params:
name = the identifier name
There must be `'\0'` at `name[length]`.
length = the length of `name`, excluding the terminating `'\0'`
value = Identifier value (e.g. `Id.unitTest`) or `TOK.identifier`
*/
extern (D) this(const(char)* name, size_t length, int value) nothrow
{
//printf("Identifier('%s', %d)\n", name, value);
this.name = name[0 .. length];
this.value = value;
}
extern (D) this(const(char)[] name, int value) nothrow
{
//printf("Identifier('%.*s', %d)\n", cast(int)name.length, name.ptr, value);
this.name = name;
this.value = value;
}
extern (D) this(const(char)* name) nothrow
{
//printf("Identifier('%s', %d)\n", name, value);
this(name.toDString(), TOK.identifier);
}
/// Sentinel for an anonymous identifier.
static Identifier anonymous() nothrow
{
__gshared Identifier anonymous;
if (anonymous)
return anonymous;
return anonymous = new Identifier("__anonymous", TOK.identifier);
}
static Identifier create(const(char)* name) nothrow
{
return new Identifier(name);
}
nothrow:
override const(char)* toChars() const pure
{
return name.ptr;
}
extern (D) override const(char)[] toString() const pure
{
return name;
}
int getValue() const pure
{
return value;
}
const(char)* toHChars2() const
{
const(char)* p = null;
if (this == Id.ctor)
p = "this";
else if (this == Id.dtor)
p = "~this";
else if (this == Id.unitTest)
p = "unittest";
else if (this == Id.dollar)
p = "$";
else if (this == Id.withSym)
p = "with";
else if (this == Id.result)
p = "result";
else if (this == Id.returnLabel)
p = "return";
else
{
p = toChars();
if (*p == '_')
{
if (strncmp(p, "_staticCtor", 11) == 0)
p = "static this";
else if (strncmp(p, "_staticDtor", 11) == 0)
p = "static ~this";
else if (strncmp(p, "__invariant", 11) == 0)
p = "invariant";
}
}
return p;
}
override DYNCAST dyncast() const
{
return DYNCAST.identifier;
}
private extern (D) __gshared StringTable!Identifier stringtable;
extern(D) static Identifier generateId(const(char)[] prefix)
{
__gshared size_t i;
return generateId(prefix, ++i);
}
extern(D) static Identifier generateId(const(char)[] prefix, size_t i)
{
OutBuffer buf;
buf.write(prefix);
buf.print(i);
return idPool(buf[]);
}
/***************************************
* Generate deterministic named identifier based on a source location,
* such that the name is consistent across multiple compilations.
* A new unique name is generated. If the prefix+location is already in
* the stringtable, an extra suffix is added (starting the count at "_1").
*
* Params:
* prefix = first part of the identifier name.
* loc = source location to use in the identifier name.
* Returns:
* Identifier (inside Identifier.idPool) with deterministic name based
* on the source location.
*/
extern (D) static Identifier generateIdWithLoc(string prefix, const ref Loc loc)
{
// generate `<prefix>_L<line>_C<col>`
OutBuffer idBuf;
idBuf.writestring(prefix);
idBuf.writestring("_L");
idBuf.print(loc.linnum);
idBuf.writestring("_C");
idBuf.print(loc.charnum);
/**
* Make sure the identifiers are unique per filename, i.e., per module/mixin
* (`path/to/foo.d` and `path/to/foo.d-mixin-<line>`). See issues
* https://issues.dlang.org/show_bug.cgi?id=16995
* https://issues.dlang.org/show_bug.cgi?id=18097
* https://issues.dlang.org/show_bug.cgi?id=18111
* https://issues.dlang.org/show_bug.cgi?id=18880
* https://issues.dlang.org/show_bug.cgi?id=18868
* https://issues.dlang.org/show_bug.cgi?id=19058
*/
static struct Key { Loc loc; string prefix; }
__gshared uint[Key] counters;
static if (__traits(compiles, counters.update(Key.init, () => 0u, (ref uint a) => 0u)))
{
// 2.082+
counters.update(Key(loc, prefix),
() => 1u, // insertion
(ref uint counter) // update
{
idBuf.writestring("_");
idBuf.print(counter);
return counter + 1;
}
);
}
else
{
const key = Key(loc, prefix);
if (auto pCounter = key in counters)
{
idBuf.writestring("_");
idBuf.print((*pCounter)++);
}
else
counters[key] = 1;
}
return idPool(idBuf[]);
}
/********************************************
* Create an identifier in the string table.
*/
static Identifier idPool(const(char)* s, uint len)
{
return idPool(s[0 .. len]);
}
extern (D) static Identifier idPool(const(char)[] s)
{
auto sv = stringtable.update(s);
auto id = sv.value;
if (!id)
{
id = new Identifier(sv.toString(), TOK.identifier);
sv.value = id;
}
return id;
}
extern (D) static Identifier idPool(const(char)* s, size_t len, int value)
{
return idPool(s[0 .. len], value);
}
extern (D) static Identifier idPool(const(char)[] s, int value)
{
auto sv = stringtable.insert(s, null);
assert(sv);
auto id = new Identifier(sv.toString(), value);
sv.value = id;
return id;
}
/**********************************
* Determine if string is a valid Identifier.
* Params:
* str = string to check
* Returns:
* false for invalid
*/
static bool isValidIdentifier(const(char)* str)
{
return str && isValidIdentifier(str.toDString);
}
/**********************************
* ditto
*/
extern (D) static bool isValidIdentifier(const(char)[] str)
{
if (str.length == 0 ||
(str[0] >= '0' && str[0] <= '9')) // beware of isdigit() on signed chars
{
return false;
}
size_t idx = 0;
while (idx < str.length)
{
dchar dc;
const s = utf_decodeChar(str, idx, dc);
if (s ||
!((dc >= 0x80 && isUniAlpha(dc)) || isalnum(dc) || dc == '_'))
{
return false;
}
}
return true;
}
extern (D) static Identifier lookup(const(char)* s, size_t len)
{
return lookup(s[0 .. len]);
}
extern (D) static Identifier lookup(const(char)[] s)
{
auto sv = stringtable.lookup(s);
if (!sv)
return null;
return sv.value;
}
extern (D) static void initTable()
{
stringtable._init(28_000);
}
}