wrapping nodes using for-each after an arrow-operator

[line-o]

What is the problem

Wrapping nodes in a function used in fn:for-each after an Arrow Operator incorrectly outputs one element per item in the source sequence.

let $xml := <root><i/><i/><i/></root>
return
    $xml/i => for-each(function ($i) { <wrap>{$i}</wrap> })

returns

<wrap><i/><i/><i/></wrap>
<wrap><i/><i/><i/></wrap>
<wrap><i/><i/><i/></wrap>

What did you expect

<wrap><i/></wrap>
<wrap><i/></wrap>
<wrap><i/></wrap>

Describe how to reproduce or add a test

2 tests:

• ao:wrap-atomic-sequence does work
• ao:wrap-element-sequence outputs 9 instead of 3

xquery version "3.1";

module namespace ao="http://exist-db.org/xquery/test/arrowop";
declare namespace test="http://exist-db.org/xquery/xqsuite";

declare
	%private
function ao:wrap ($item as item()) as item() { 
    <wrap>{$item}</wrap>
};

declare
	%private
function ao:wrap-explicit-type-conversion ($item as item()) as item() { 
    <wrap>{xs:string($item)}</wrap>
};

declare
	%private 
function ao:first-element-text ($s as node()*) as text() {
    $s[1]/text()
};

declare
    %test:assertEquals("1")
function ao:wrap-atomic-sequence () {
    (1, 2, 3) => for-each(ao:wrap#1) => ao:first-element-text()
};

declare
    %test:assertEquals("1")
function ao:wrap-atomic-sequence-with-explicit-type-conversion () {
    (1, 2, 3) => for-each(ao:wrap-with-explicit-type-conversion#1) => ao:first-element-text()
};

declare
	%private 
function ao:get-i-elements ($i as item()) { $i//i };

declare
    %test:assertEquals(3)
function ao:wrap-element-sequence () {
    let $xml := <root><i/><i/><i/></root>
    return $xml/node()
        => for-each(ao:wrap#1)
        => for-each(ao:get-i-elements#1)
        => count()
};

Context information

• Tested on 4.1.0 and 5.0.0-RC1 (8339007)
• java version "1.8.0_152"
• Operating system: MacOs (64 bit)
• both are clones from GitHub
• the 4.1.0 is a customised version of existdb

[adamretter]

I can confirm that BaseX and Saxon both produce the correct result as indicated by @line-o, whilst eXist-db returns the incorrect result

[line-o]

Thanks for the edit @adamretter, looks much better.
I found more cases that do fail, but I think they all have the same root cause.

For example this will fail with a duplicate attribute exception err:XQDY0025:

(<item n="1"/>, <item n="2"/>, <item n="3"/>) 
    => for-each(function ($item as item()) as element(a) { <a>{$item/@n}</a> })

[line-o]

(1,2,3) => for-each(function ($a) {<a>{xs:string($a)}</a>})

does also trigger the behaviour while

(1,2,3) => for-each(function ($a) {<a>{$a}</a>})

does not

[line-o]

Added a test case for wrapping atomic values with explicit type conversion.

[line-o]

Hint from @wolfgangmm

UserDefinedFunction.eval (for the inner inline function) [...] is called way more often than 3 times. for-each (FunHigherOrderFun) iterates over 3 items only as expected. So somewhere between those two there's a bug.

[line-o]

It turns out, that it is the context that is handed down to the called function. The spec clearly states that the focus (context etc.) must not be present in the called function.

Also, more functions are affected:

• filter
• for-each-pair
• fold-left and ~-right
• sort