MP3 (i2s or else) playback on rp2040

[Stass48]

Hello! I'm sorry, that I write to wrong topic, but in right topic there is no answer to me.

I want to play mp3 from SD card on Pico. It may be possible with ESP8266audio library here, but I can't to do this. In existing examples (included in library) I can't see code for rp2040:

void setup(){}
void loop(){}

Can someone help me?
Thank you.

[maxgerhardt]

I think the commenting out the example code for RP2040 is a relict. You can just build a MP3 to I2S from SD card player by combining https://github.com/earlephilhower/ESP8266Audio/blob/master/examples/PlayMP3FromSPIFFS/PlayMP3FromSPIFFS.ino and https://github.com/earlephilhower/ESP8266Audio/blob/master/examples/PlayFLAC-SD-SPDIF/PlayFLAC-SD-SPDIF.ino.

I just tested that

#include <Arduino.h>
#include "AudioFileSourceSD.h"
#include "AudioFileSourceID3.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2SNoDAC.h"

AudioGeneratorMP3 *mp3;
AudioFileSourceSD *file;
AudioOutputI2SNoDAC *out;
AudioFileSourceID3 *id3;

// Defines MISO, MOSI, SCLK, CS pins for SD card
#define SDCARD_SPI SPI
#define SDCARD_CS_PIN 10
// pno_cs.mp3 can be downloaded from https://ccrma.stanford.edu/~jos/pasp/Sound_Examples.html

// Called when a metadata event occurs (i.e. an ID3 tag, an ICY block, etc.
void MDCallback(void *cbData, const char *type, bool isUnicode, const char *string)
{
  (void)cbData;
  Serial.printf("ID3 callback for: %s = '", type);

  if (isUnicode) {
    string += 2;
  }

  while (*string) {
    char a = *(string++);
    if (isUnicode) {
      string++;
    }
    Serial.printf("%c", a);
  }
  Serial.printf("'\n");
  Serial.flush();
}


void setup()
{
  Serial.begin(115200);
  delay(1000);
  SD.begin(SDCARD_CS_PIN, SDCARD_SPI);
  Serial.printf("Sample MP3 playback begins...\n");

  audioLogger = &Serial;
  file = new AudioFileSourceSD("/pno-cs.mp3");
  id3 = new AudioFileSourceID3(file);
  id3->RegisterMetadataCB(MDCallback, (void*)"ID3TAG");
  out = new AudioOutputI2SNoDAC();
  mp3 = new AudioGeneratorMP3();
  mp3->begin(id3, out);
}

void loop()
{
  if (mp3->isRunning()) {
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.printf("MP3 done\n");
    delay(1000);
  }
}

compiles fine. Don't have an SD card or I2S DAC to test. I2S output is by default GPIO28 for data and GPIO26 for clock.

[DoomHammer]

Yeah, that's what occured to me as well so I uploaded CircuitPython and tried using some code I've used before with the same DAC but in a different breakout board. So far it is still silent :(

[maxgerhardt]

Per datasheet the DAC produces a line-out level, not like headphone output. How are you measuring the output? By directly plugging in headphones, or plugging it into the "line-in" on your PC and recording it?

[DoomHammer]

Tried both the headphones and an amp, without luck so far.

[DoomHammer]

OK, this time I tried with the DVI Pico Base from Pimoroni on which the CircuitPython code plays a sound.

According to the schematics https://cdn.shopify.com/s/files/1/0174/1800/files/pico_dv_schematic.pdf?v=1636985340 I assume the pinout should be out->SetPinout(27, 28, 26);. Alas, still I can't hear anything.

[DoomHammer]

OK, I got lucky with the bare I2S.h, that's mighty curious

[Stass48]

The code above doesn't work. Here's the working code. You need to solder a jumper on the PCM5102 module (shown in the photo) and power the module from 5 V. To avoid jerks during playback, you need to increase the SPI speed, as shown in the code. Also, use overclocking up to 200 MHz. Under these conditions, MP3 320 kbps Stereo is played.

#include "AudioFileSourceSD.h"
#include "AudioGeneratorMP3.h"
#include "AudioOutputI2S.h"

AudioGeneratorMP3 *mp3;
AudioFileSourceSD *file;
AudioOutputI2S *out;

// SPI0 for internal SD card
const int INT_SD_SCK = 18;
const int INT_SD_MOSI = 19;
const int INT_SD_MISO = 20;
const int INT_SD_CS = 21;

// You may need a fast SD card. Set this as high as it will work (40MHz max).
#define SPI_SPEED SD_SCK_MHZ(40) // Why not 50?

// Pins for I2S
const int PIN_BCLK = 2; // BCK
const int PIN_WCLK = 3; // LCK
const int PIN_DOUT = 4; // DIN
// Solder SCK jumper on module! VCC of PCM5102 module = 5V!

void setup() {
  SPI.setRX(INT_SD_MISO);
  SPI.setTX(INT_SD_MOSI);
  SPI.setSCK(INT_SD_SCK);
  SPI.setCS(INT_SD_CS);

  Serial.begin(115200);
  delay(1000);

  if (SD.begin(INT_SD_CS, SPI_SPEED, SPI)) Serial.println("SD OK!");
  Serial.println("Sample MP3 playback begins...");

  audioLogger = &Serial;
  file = new AudioFileSourceSD("/demo.mp3");
  out = new AudioOutputI2S();
  out->SetPinout(PIN_BCLK, PIN_WCLK, PIN_DOUT);
  mp3 = new AudioGeneratorMP3();
  mp3->begin(file, out);
}

void loop() {
  if (mp3->isRunning()) {
    if (!mp3->loop()) mp3->stop();
  } else {
    Serial.println("MP3 done");
    delay(1000);
  }
}

[Stass48]

Now I am interested in other questions.
In what mode does the memory card work? DEDICATED_SPI or SHARED_SPI? How can you control these modes? For example, set the DEDICATED_SPI mode.
If I have two SD cards, how can I choose which card will play files from?
For example, if I write:

#define SPI_CLOCK SD_SCK_MHZ(50)
SdFs rdSd;
FsFile rdFile;
#define SD_RD_CS_PIN 17
#define SD_RD_CONFIG SdSpiConfig(SD_RD_CS_PIN, DEDICATED_SPI, SPI_CLOCK, &SPI)

SdFs wrSd;
FsFile wrFile;
#define SD_WR_CS_PIN 13
#define SD_WR_CONFIG SdSpiConfig(SD_WR_CS_PIN, DEDICATED_SPI, SPI_CLOCK, &SPI1)

...

if (!rdSd.begin(SD_RD_CONFIG)) rdSd.initErrorHalt("rdSd");
if (!wrSd.begin(SD_WR_CONFIG)) wrSd.initErrorHalt("wrSd");

**How do I play a file from each memory card?

Another interesting question. Does the library support multithreading? RP2040 has 2 cores. Perhaps by using both cores, overclocking could be avoided.**