-
Notifications
You must be signed in to change notification settings - Fork 2
/
PrintEyeCase.scad
188 lines (176 loc) · 5 KB
/
PrintEyeCase.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
// Printeye Case
$fn=90; // or fugly
pcbx=53.5; // taken from the pcb as made
pcby=31.5; // not from the model
edgeRad=2; // round off
fitting = true;
if(!fitting) {
casebody();
translate([0,-50,33]) rotate([0,180,0])
casestand();
} else {
translate([-pcbx/2,pcby/2,17])
rotate([180,0,0])
pcb();
color("grey",0.4) casestand();
color("lavender",0.4) casebody();
}
module casestand() {
// Four tabs to grip onto case, wider at top
translate([0,0,17.5])
linear_extrude(height=4,convexity=8) {
difference() {
union() {
//square([pcbx+1,16],center=true);
square([30,pcby+0.8],center=true);
}
square([pcbx-3.2,pcby-3.4],center=true);
}
}
// Thinner part of tabs
translate([0,0,21.5])
linear_extrude(height=10,convexity=8) {
difference() {
union() {
square([pcbx+0.8,16],center=true);
square([30,pcby+0.6],center=true);
}
square([pcbx-3.2,pcby-3.4],center=true);
}
}
//Plate over the whole thing with cutouts.
// color("grey",0.5) // handy 4 debug
translate([0,0,30])
linear_extrude(height=3,convexity=8) {
difference() {
minkowski() {
square([pcbx-3.2,pcby-3.4],center=true);
circle(2);
}
translate([-16,0]) circle(d=13); // button
hull() { // air/inspect/prodding hole
translate([0,-3])
scale([0.5,1]) circle(d=19);
translate([18,-3])
scale([0.5,1]) circle(d=19);
}
minkowski() { // cable slot)
translate([-2,10.8])
square([16,2.8]);
circle(0.4);
}
}
translate([0,-18])
square([46,5],center=true);
}
// foot
translate([0,-20.5,31])
hull() {
rotate([0,90,0])
cylinder(d=4,h=46,center=true);
translate([0,-7,-12])
rotate([0,90,0])
cylinder(d=3,h=42,center=true);
}
// Button recess
translate([-16,0,24])
linear_extrude(height=9,convexity=8) {
difference() {
circle(d=16);
circle(d=13);
}
}
translate([-16,0,24])
linear_extrude(height=1,convexity=8) {
intersection() {
circle(d=16);
square([3.2,18],center=true);
}
}
}
module casebody() {
difference() {
minkowski() {
translate([0,0,15])
cube([pcbx+1,pcby+1,30-2*edgeRad],center=true);
sphere(edgeRad);
}
// lenses
hull() {
translate([0,-1.6,0])
cube([52,15.6,0.1],center=true);
translate([0,-1.6,1])
cube([50,13.6,0.1],center=true);
}
// pcbs
// Section with fat pins to support oleds
translate([0,0,1])
linear_extrude(height=2,convexity=8) {
difference() {
square([51.2,27.8],center=true);
for(x=[-23.5,-1.5,1.5,23.5],
y=[-12,12])
translate([x,y]) circle(2.8);
}
}
// Now the bit with the pin tops
translate([0,0,2.8])
linear_extrude(height=30,convexity=8) {
difference() {
square([51.2,27.8],center=true);
for(x=[-23,-2,2,23],
y=[-11.5,11.5])
translate([x,y]) circle(1);
}
}
// Now the rest
translate([0,0,4])
linear_extrude(height=30,convexity=8) {
square([51.2,27.8],center=true);
}
translate([0,0,15.5])
linear_extrude(height=60,convexity=8) {
square([pcbx+1,pcby+0.8],center=true);
}
}
}
module pcb(opacity=0.5) {
color("green",opacity)
import("PrintEyePcb.stl");
translate([13.6,15.3,13.3])
rotate([0,0,90])
oled(alpha=opacity);
translate([38.5,15.3,13.3])
rotate([0,0,90])
oled(alpha=opacity);
}
module oled(alpha=0.5) {
color("blue",alpha)
linear_extrude(height=1.2,convexity=5)
difference() {
square([27,25],center=true);
for(x=[-11.5,11.5],y=[-10.5,10.5])
translate([x,y]) circle(1.5);
}
color("grey",alpha) {
translate([0,0,1.3])
linear_extrude(height=1.4,convexity=5)
square([16.6,24.8],center=true);
translate([-10,0,1.3])
linear_extrude(height=0.8,convexity=5)
square([7,12],center=true);
translate([2,0,1.3])
linear_extrude(height=1.8,convexity=5)
square([13.5,24.8],center=true);
}
for(y=[-3.81,-1.27,1.27,3.81]) {
color("gold",alpha)
translate([12,y,-11.7])
linear_extrude(height=13.7,convexity=5)
square([0.6,0.6],center=true);
color("grey",0.8)
translate([12,y,-11.7])
linear_extrude(height=11.7,convexity=5)
square([2,2.6],center=true);
}
}