gui-apps/waybar: update waybar to verison 0.9.3

This version bump added a new dependency on 'dev-libs/date'.

Closes: https://bugs.gentoo.org/714834
Closes: https://bugs.gentoo.org/712236
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Jonas Toth <gentoo@jonas-toth.eu>

dev-libs/date/date-3.0.0.ebuild

@@ -8,34 +8,23 @@ inherit cmake
 DESCRIPTION="A date and time library based on the C++11/14/17 <chrono> header"
 HOMEPAGE="https://github.com/HowardHinnant/date"
 
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/HowardHinnant/${PN}"
-else
-	SRC_URI="https://github.com/HowardHinnant/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
-fi
+SRC_URI="https://github.com/HowardHinnant/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="test tz system-tz only-c-locale"
+IUSE="test only-c-locale"
 RESTRICT="!test? ( test )"
 
-BDEPEND=""
-DEPEND=""
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	eapply "${FILESDIR}"/${P}-c-locale-export.patch \
-           "${FILESDIR}"/${P}-version.patch
-	eapply_user
-	cmake_src_prepare
-}
+PATCHES=(
+	"${FILESDIR}"/${P}-c-locale-export.patch
+    "${FILESDIR}"/${P}-version.patch
+)
 
 src_configure() {
 	local mycmakeargs=(
-		-DBUILD_TZ_LIB=$(usex tz)
-		-DUSE_SYSTEM_TZ_DB=$(usex system-tz)
+		-DBUILD_TZ_LIB=ON
+		-DUSE_SYSTEM_TZ_DB=ON
 		-DENABLE_DATE_TESTING=$(usex test)
 		-DCOMPILE_WITH_C_LOCALE=$(usex only-c-locale)
 	)

dev-libs/date/metadata.xml

@@ -10,8 +10,6 @@
 		<name>Proxy Maintainers</name>
 	</maintainer>
 	<use>
-		<flag name="tz">Build timezone library on top of date.h</flag>
-		<flag name="system-tz">Use the operating system's timezone database</flag>
 		<flag name="only-c-locale">Build only the C locale</flag>
 	</use>
 	<upstream>

gui-apps/waybar/Manifest

@@ -1 +1,2 @@
 DIST waybar-0.8.0.tar.gz 112019 BLAKE2B b3b61e02a104599e8f9047f9e2f76ec57ef7dd164edca2afd7b0afbb6b2c2341e20d6175905eba525337df9215473afa6cf017f736bb2de24e4daa169a5af3ee SHA512 c670fd21a7d29396d8bbe1b7540ddbbe44a98f7fb49f8518e0cc302aa57e5bb993ff8306973a7b8ca4ec000a7ecc311872762a0782ce19e4bf4cff8ea09caccb
+DIST waybar-0.9.3.tar.gz 135024 BLAKE2B d7b0090d0d7e25701ba7b76353737451e4ff8f145998b1a395e4c57e845be319380ac41b1a464bc7b5cc4d9ce037151bc9e7f37763ed1c0f42e945503668f1df SHA512 19dba92c5e430ce71567f149e5d208d594928a1d642584f606d55779d0a336ec4587e8a2e15698a25bdf0d26525f771d0a73b193f948bf9c1dfba5be350d4e78

gui-apps/waybar/metadata.xml

@@ -1,10 +1,19 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<!-- maintainer-needed -->
+	<maintainer type="person">
+		<email>gentoo@jonas-toth.eu</email>
+		<name>Jonas Toth</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
 	<use>
 		<flag name="mpd">Enable support for the Music Player Daemon</flag>
 		<flag name="network">Enable libnl support for network related features</flag>
+		<flag name="popups">Enable popup support with gtk-layer-shell</flag>
+		<flag name="pulseaudio">Enable support for volume control via PulseAudio</flag>
 		<flag name="tray">Enable support for tray</flag>
 	</use>
 	<upstream>

gui-apps/waybar/waybar-0.9.3.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+	SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="mpd network popups pulseaudio tray +udev"
+
+BDEPEND="
+	>=app-text/scdoc-1.9.2
+	virtual/pkgconfig
+	"
+DEPEND="
+	dev-cpp/gtkmm:3.0
+	dev-libs/jsoncpp:=
+	dev-libs/libinput:=
+	dev-libs/libsigc++:2
+	>=dev-libs/libfmt-5.3.0:=
+	>=dev-libs/spdlog-1.3.1:=
+	dev-libs/date
+	dev-libs/wayland
+	dev-libs/wayland-protocols
+	gui-libs/wlroots
+	mpd? ( media-libs/libmpdclient )
+	network? ( dev-libs/libnl:3 )
+	popups? ( gui-libs/gtk-layer-shell )
+	pulseaudio? ( media-sound/pulseaudio )
+	tray? (
+			dev-libs/libdbusmenu[gtk3]
+			dev-libs/libappindicator
+		  )
+	udev? ( virtual/libudev:= )
+	"
+RDEPEND="${DEPEND}"
+
+if [[ ${PV} != 9999 ]]; then
+	S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature mpd)
+		$(meson_feature network libnl)
+		$(meson_feature popups gtk-layer-shell)
+		$(meson_feature pulseaudio)
+		$(meson_feature tray dbusmenu-gtk)
+		$(meson_feature udev libudev)
+	)
+	meson_src_configure
+}

gui-apps/waybar/waybar-9999.ebuild

@@ -1,11 +1,11 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 inherit meson
 
-DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors."
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
 HOMEPAGE="https://github.com/Alexays/Waybar"
 
 if [[ ${PV} == 9999 ]]; then
@@ -18,30 +18,33 @@ fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="mpd network pulseaudio tray +udev"
+IUSE="mpd network popups pulseaudio tray +udev"
 
 BDEPEND="
 	>=app-text/scdoc-1.9.2
 	virtual/pkgconfig
-"
-
+	"
 DEPEND="
 	dev-cpp/gtkmm:3.0
 	dev-libs/jsoncpp:=
 	dev-libs/libinput:=
 	dev-libs/libsigc++:2
 	>=dev-libs/libfmt-5.3.0:=
 	>=dev-libs/spdlog-1.3.1:=
+	dev-libs/date
 	dev-libs/wayland
 	dev-libs/wayland-protocols
 	gui-libs/wlroots
 	mpd? ( media-libs/libmpdclient )
 	network? ( dev-libs/libnl:3 )
+	popups? ( gui-libs/gtk-layer-shell )
 	pulseaudio? ( media-sound/pulseaudio )
-	tray? ( dev-libs/libdbusmenu[gtk3] )
+	tray? (
+			dev-libs/libdbusmenu[gtk3]
+			dev-libs/libappindicator
+		  )
 	udev? ( virtual/libudev:= )
-"
-
+	"
 RDEPEND="${DEPEND}"
 
 if [[ ${PV} != 9999 ]]; then
@@ -52,6 +55,7 @@ src_configure() {
 	local emesonargs=(
 		$(meson_feature mpd)
 		$(meson_feature network libnl)
+		$(meson_feature popups gtk-layer-shell)
 		$(meson_feature pulseaudio)
 		$(meson_feature tray dbusmenu-gtk)
 		$(meson_feature udev libudev)