gnome-base/librsvg: bump the C version to EAPI 7

Only the old pure C version of librsvg can currently be updated
beyond EAPI 6 due to this blocker: https://bugs.gentoo.org/723112

Bug: https://bugs.gentoo.org/753764
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: David Michael <fedora.dm0@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

gnome-base/librsvg/librsvg-2.40.21.ebuild

@@ -1,11 +1,11 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-GNOME2_LA_PUNT="yes"
+EAPI=7
+GNOME2_EAUTORECONF="yes"
 VALA_USE_DEPEND="vapigen"
 
-inherit autotools eutils gnome2 multilib-minimal vala
+inherit autotools gnome2 multilib-minimal vala
 
 DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
 HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg"
@@ -19,55 +19,52 @@ REQUIRED_USE="vala? ( introspection )"
 
 RDEPEND="
 	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
-	>=x11-libs/cairo-1.12.14-r4[${MULTILIB_USEDEP}]
-	>=x11-libs/pango-1.38.0[${MULTILIB_USEDEP}]
-	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
 	>=dev-libs/libcroco-0.6.8-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
+	>=x11-libs/cairo-1.12.14-r4[${MULTILIB_USEDEP}]
 	>=x11-libs/gdk-pixbuf-2.30.7:2[introspection?,${MULTILIB_USEDEP}]
+	>=x11-libs/pango-1.38.0[${MULTILIB_USEDEP}]
 	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )
 	tools? ( >=x11-libs/gtk+-3.10.0:3 )
 "
-DEPEND="${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	dev-libs/gobject-introspection-common
 	dev-libs/vala-common
 	dev-util/glib-utils
 	>=dev-util/gtk-doc-am-1.13
 	virtual/pkgconfig
+	x11-libs/gdk-pixbuf
 	vala? ( $(vala_depend) )
 "
 # >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf
 
 RESTRICT="test" # Lots of issues due to freetype changes and more; ever since newer tests got backported into 2.40.19
 
-src_prepare() {
+PATCHES=(
 	# https://bugzilla.gnome.org/show_bug.cgi?id=653323
-	eapply "${FILESDIR}/${PN}-2.40.12-gtk-optional.patch"
-
-	eautoreconf
+	"${FILESDIR}/${PN}-2.40.12-gtk-optional.patch"
+)
 
+src_prepare() {
 	use vala && vala_src_prepare
 	gnome2_src_prepare
 }
 
 multilib_src_configure() {
-	local myconf=()
+	local myconf=(
+		--disable-static
+		--disable-tools  # only useful for librsvg developers
+		$(multilib_native_use_enable introspection)
+		$(multilib_native_use_with tools gtk3)
+		$(multilib_native_use_enable vala)
+		--enable-pixbuf-loader
+	)
 
 	# -Bsymbolic is not supported by the Darwin toolchain
-	if [[ ${CHOST} == *-darwin* ]]; then
-		myconf+=( --disable-Bsymbolic )
-	fi
+	[[ ${CHOST} == *-darwin* ]] && myconf+=( --disable-Bsymbolic )
 
-	# --disable-tools even when USE=tools; the tools/ subdirectory is useful
-	# only for librsvg developers
-	ECONF_SOURCE=${S} \
-	gnome2_src_configure \
-		--disable-static \
-		--disable-tools \
-		$(multilib_native_use_enable introspection) \
-		$(multilib_native_use_with tools gtk3) \
-		$(multilib_native_use_enable vala) \
-		--enable-pixbuf-loader \
-		"${myconf[@]}"
+	ECONF_SOURCE=${S} gnome2_src_configure "${myconf[@]}"
 
 	if multilib_is_native_abi; then
 		ln -s "${S}"/doc/html doc/html || die