dev-libs/bglibs: EAPI7, update ebuild

Signed-off-by: Michael Mair-Keimberger <m.mairkeimberger@gmail.com>
Closes: https://bugs.gentoo.org/380649

dev-libs/bglibs/bglibs-1.106-r2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Bruce Guenters Libraries Collection"
+HOMEPAGE="http://untroubled.org/bglibs/
+	https://github.com/bruceg/bglibs"
+SRC_URI="http://untroubled.org/bglibs/archive/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+DEPEND="sys-devel/libtool"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.106-parallel-fix.patch )
+
+src_prepare() {
+	default
+	# disable tests as we want them manually
+	sed -i \
+		-e '/^all:/s|selftests||' \
+		"${S}"/Makefile || die
+	sed -i \
+		-e '/selftests/d' \
+		"${S}"/TARGETS || die
+	#sed -i \
+	#	-e 's,^libraries:,LIBS = ,g' \
+	#	-e '/^LIBS =/alibs-static: $(filter %.a,$(LIBS))' \
+	#	-e '/^LIBS =/alibs-shared: $(filter %.la,$(LIBS))' \
+	#	-e '/^LIBS =/alibraries: libs-static libs-shared' \
+	#	"${S}"/Makefile
+}
+
+src_compile() {
+	echo "${D}/usr/bin" > conf-bin || die
+	echo "${D}/usr/$(get_libdir)/bglibs" > conf-lib || die
+	echo "${D}/usr/include/bglibs" > conf-include || die
+	echo "${D}/usr/share/man" > conf-man || die
+	echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
+	echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
+	emake
+}
+
+src_test() {
+	einfo "Running selftests"
+	emake selftests
+}
+
+src_install () {
+	default
+
+	#make backwards compatible symlinks
+	dosym /usr/$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/lib
+	[ "$(get_libdir)" != "lib" ] && dosym /usr/$(get_libdir)/bglibs /usr/$(get_libdir)/bglibs/$(get_libdir)
+	dosym /usr/include/bglibs /usr/$(get_libdir)/bglibs/include
+
+	#install .so in LDPATH
+	mv "${D}"/usr/$(get_libdir)/bglibs/libbg.so.1.1.1 "${D}"/usr/$(get_libdir)/ || die
+	mv "${D}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1 "${D}"/usr/$(get_libdir)/ || die
+	dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so.1
+	dosym libbg.so.1.1.1 /usr/$(get_libdir)/libbg.so
+	dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so.1
+	dosym libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/libbg-sysdeps.so
+
+	dosym ../libbg.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg.so.1.1.1
+	dosym ../libbg-sysdeps.so.1.1.1 /usr/$(get_libdir)/bglibs/libbg-sysdeps.so.1.1.1
+
+	rm "${D}"/usr/$(get_libdir)/bglibs/libbg.la || die
+	rm "${D}"/usr/$(get_libdir)/bglibs/libbg-sysdeps.la || die
+
+	dodoc ANNOUNCEMENT NEWS README ChangeLog TODO VERSION
+	docinto html
+	dodoc doc/html/*
+	docinto latex
+	dodoc doc/latex/*
+}