media-gfx/openpgl: add 0.6.0, use PV as subslot

Bug: https://bugs.gentoo.org/926890
Closes: https://bugs.gentoo.org/927244
Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>

media-gfx/blender/blender-3.6.0.ebuild

@@ -88,7 +88,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( media-libs/openpgl )
+	openpgl? ( media-libs/openpgl:0/0.5=)
 	opensubdiv? ( >=media-libs/opensubdiv-3.4.0 )
 	openvdb? (
 		>=media-gfx/openvdb-9.0.0:=[nanovdb?]

media-gfx/blender/blender-3.6.5.ebuild

@@ -86,7 +86,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( media-libs/openpgl )
+	openpgl? ( media-libs/openpgl:0/0.5=)
 	opensubdiv? ( >=media-libs/opensubdiv-3.4.0 )
 	openvdb? (
 		>=media-gfx/openvdb-9.0.0:=[nanovdb?]

media-gfx/blender/blender-3.6.8.ebuild

@@ -86,7 +86,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( media-libs/openpgl )
+	openpgl? ( media-libs/openpgl:0/0.5=)
 	opensubdiv? ( >=media-libs/opensubdiv-3.4.0 )
 	openvdb? (
 		>=media-gfx/openvdb-9.0.0:=[nanovdb?]

media-gfx/blender/blender-4.0.1-r1.ebuild

@@ -90,7 +90,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( >=media-libs/openpgl-0.5.0 )
+	openpgl? ( media-libs/openpgl:0/0.5= )
 	opensubdiv? ( >=media-libs/opensubdiv-3.5.0 )
 	openvdb? (
 		>=media-gfx/openvdb-10.1.0:=[nanovdb?]

media-gfx/blender/blender-4.0.2.ebuild

@@ -88,7 +88,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( >=media-libs/openpgl-0.5.0 )
+	openpgl? ( media-libs/openpgl:0/0.5= )
 	opensubdiv? ( >=media-libs/opensubdiv-3.5.0 )
 	openvdb? (
 		>=media-gfx/openvdb-10.0.0:=[nanovdb?]

media-gfx/blender/blender-9999.ebuild

@@ -90,7 +90,7 @@ RDEPEND="${PYTHON_DEPS}
 		>=dev-libs/imath-3.1.4-r2:=
 		>=media-libs/openexr-3:0=
 	)
-	openpgl? ( >=media-libs/openpgl-0.5.0 )
+	openpgl? ( media-libs/openpgl:= )
 	opensubdiv? ( >=media-libs/opensubdiv-3.5.0 )
 	openvdb? (
 		>=media-gfx/openvdb-10.1.0:=[nanovdb?]

media-libs/openpgl/Manifest

@@ -1 +1,2 @@
 DIST openpgl-0.5.0.tar.gz 10767365 BLAKE2B 051b26c17300506dd20989ba9dc1aa83b0baf77c5f24650c74518ae56081b5a0ecca88c13d5d79a71cb0b6fa4a5b4841ee03e5223ec91ab16bb5655f2e52a9d7 SHA512 9b992ffa17ad6f9fcde48add5d9cc1e58be2daacd40478fb1babe0741a6c7a64f12f36c9c1f7d5ec6f79cdd847c082d39e03e58cfd9af1a903adca56f1ac19e1
+DIST openpgl-0.6.0.tar.gz 10824550 BLAKE2B a08f5469cce808c51eb64a619621de31923318a230e49ababad2140d00b53d3ad688e095c4f7aba1ac6ebfd874ed1357e4a501bee5f45a826c39cddbab4fa3cd SHA512 a40161d79e9f340e631eda9dedbabd9c71fb0184c65f45e0abcb64ce53289a65b7434c11678f845f76006a0ce579c4458a39200dc8caca1c455f18739488e173

media-libs/openpgl/openpgl-0.5.0-r1.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Open Path Guiding Library"
+HOMEPAGE="https://github.com/OpenPathGuidingLibrary/openpgl"
+SRC_URI="https://github.com/OpenPathGuidingLibrary/openpgl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="-* ~amd64 ~arm64"
+
+X86_CPU_FLAGS=( sse4_2 avx2 avx512dq )
+CPU_FLAGS=( cpu_flags_arm_neon "${X86_CPU_FLAGS[@]/#/cpu_flags_x86_}" )
+IUSE="${CPU_FLAGS[*]} debug"
+
+RDEPEND="
+	media-libs/embree:=
+	dev-cpp/tbb:=
+"
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	if use amd64 ; then
+		if ! use cpu_flags_x86_sse4_2 && ! use cpu_flags_x86_avx2 && ! use cpu_flags_x86_avx512dq ; then
+			die "You need to select a compatible ISA"
+		fi
+	elif use arm64 ; then
+		if ! use cpu_flags_arm_neon; then
+			die "You need to select a compatible ISA"
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DOPENPGL_ISA_SSE4="$(usex cpu_flags_x86_sse4_2)"
+		-DOPENPGL_ISA_AVX2="$(usex cpu_flags_x86_avx2)"
+		-DOPENPGL_ISA_AVX512="$(usex cpu_flags_x86_avx512dq)"
+		-DOPENPGL_ISA_NEON="$(usex cpu_flags_arm_neon)"
+		# TODO look into neon 2x support
+		# -DOPENPGL_ISA_NEON2X="$(usex cpu_flags_arm_neon2x)"
+	)
+
+	# This is currently needed on arm64 to get the NEON SIMD wrapper to compile the code successfully
+	use cpu_flags_arm_neon && append-flags -flax-vector-conversions
+
+	# Disable asserts
+	append-cppflags "$(usex debug '' '-DNDEBUG')"
+
+	cmake_src_configure
+}

media-libs/openpgl/openpgl-0.6.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Open Path Guiding Library"
+HOMEPAGE="https://github.com/OpenPathGuidingLibrary/openpgl"
+SRC_URI="https://github.com/OpenPathGuidingLibrary/openpgl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="-* ~amd64 ~arm64"
+
+X86_CPU_FLAGS=( sse4_2 avx2 avx512dq )
+CPU_FLAGS=( cpu_flags_arm_neon "${X86_CPU_FLAGS[@]/#/cpu_flags_x86_}" )
+IUSE="${CPU_FLAGS[*]} debug"
+
+RDEPEND="
+	media-libs/embree:=
+	dev-cpp/tbb:=
+"
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	if use amd64 ; then
+		if ! use cpu_flags_x86_sse4_2 && ! use cpu_flags_x86_avx2 && ! use cpu_flags_x86_avx512dq ; then
+			die "You need to select a compatible ISA"
+		fi
+	elif use arm64 ; then
+		if ! use cpu_flags_arm_neon; then
+			die "You need to select a compatible ISA"
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DOPENPGL_ISA_SSE4="$(usex cpu_flags_x86_sse4_2)"
+		-DOPENPGL_ISA_AVX2="$(usex cpu_flags_x86_avx2)"
+		-DOPENPGL_ISA_AVX512="$(usex cpu_flags_x86_avx512dq)"
+		-DOPENPGL_ISA_NEON="$(usex cpu_flags_arm_neon)"
+		# TODO look into neon 2x support
+		# -DOPENPGL_ISA_NEON2X="$(usex cpu_flags_arm_neon2x)"
+	)
+
+	# This is currently needed on arm64 to get the NEON SIMD wrapper to compile the code successfully
+	use cpu_flags_arm_neon && append-flags -flax-vector-conversions
+
+	# Disable asserts
+	append-cppflags "$(usex debug '' '-DNDEBUG')"
+
+	cmake_src_configure
+}