app-accessibility/orca: add orca-3.22.2.ebuild

Simple bump, no relevant changes

https://git.gnome.org/browse/orca/diff/?id=ORCA_3_22_2&&id2=ORCA_3_22_1
Closes: #2784

Signed-off-by: Gilles Dartiguelongue <eva@gentoo.org>

app-accessibility/orca/Manifest

@@ -1,2 +1,3 @@
 DIST orca-3.20.3.tar.xz 2312864 SHA256 86a03b504f626e39247694d8d76c272a298874887a40bd044f8a535b8d689fd7 SHA512 5dc04cec821f7a47be0cb6e820a531e9753dd24685771e6b70488d30502bc111a4b107f8d63440139bfa9579015f224f6fda6cd8f0ecc0fc7fbfa3ce684d75f9 WHIRLPOOL c96795a9d6f9486cce7150041c5608d5beb39b8fdd33c7312beee40100aba67f3846f4c449ea8ae8b393c334be27197dbb5b2415d8a8a38cba9d775144b1bbfd
 DIST orca-3.22.1.tar.xz 2348012 SHA256 8622d45733c05f21fd1a126aa50b165c37fcfa083a1e25e20b317864394d0993 SHA512 4f65a6c2bf667c0a65158c6e01a5ee1800b8c7b7ada0bfb04bdf91c73accd9d6659ab313930862127645376c0371fe8cfe71f0080a8725e4cc31c9db9374a708 WHIRLPOOL ddc87ac21c739e621f9f0f514d4e626418629325b57d4ac1bfb05fe6e59dae4ec0539b71b29742ec5242c252606fcb25f7cb104121c7e465f263f85e3c94b671
+DIST orca-3.22.2.tar.xz 2345292 SHA256 599beeeec99fcf24aed7b97c832140f9355c79504c9250fcae90f611680368ca SHA512 0c4f3055509fd983da1081c4e33a4675ca498e75a8f2701318c000810cf691758eaded01969a6b56a2c25cf507bc4cb7e099f8498d1a0f6fa739d074a23528c5 WHIRLPOOL 9d6a88310a6e53ab93d16740e90eed8af54185b47b93fa2e0f7ffdda37178be2f07f5d1db38bc23b526ba2f3ec408aab15749a97f81367bfd5951a72e5967c53

app-accessibility/orca/orca-3.22.2.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{4,5} )
+PYTHON_REQ_USE="threads"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.12:2
+	>=app-accessibility/at-spi2-core-2.12:2[introspection]
+	>=dev-libs/atk-2.10
+	>=dev-libs/glib-2.28:2
+	dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.10:3[${PYTHON_USEDEP}]
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	braille? (
+		>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+		dev-libs/liblouis[python,${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+	dev-libs/atk[introspection]
+	dev-python/pyatspi[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	dev-util/itstool
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
+			-i src/orca/orca || die
+		python_doscript src/orca/orca
+	}
+	python_foreach_impl run_in_build_dir installing
+}