net-im/element-desktop-bin: add 1.11.45

Bug: https://bugs.gentoo.org/914926
Closes: https://bugs.gentoo.org/910067
Closes: #31805
Signed-off-by: tastytea <gentoo@tastytea.de>
Closes: #33134
Signed-off-by: Sam James <sam@gentoo.org>

net-im/element-desktop-bin/Manifest

@@ -1 +1,2 @@
 DIST element-desktop_1.11.39_amd64.deb 88299616 BLAKE2B ed6b6e3ba89617632d6350d85e6dda2eac7f5be630b011c9606766b0111ca94df7da16cbb77a047e1830bfc8994cf3ed7803778c9e1eef76506abfa178e4ca63 SHA512 9b53df0eb63e6330b8f6e36629978bfad9d26e1ad000abafeaf68c8a50969e1d0703df399c7c50e708a748f20381c00c95217ed8296cfa46d891fc9ae2d6b9c5
+DIST element-desktop_1.11.45_amd64.deb 90253530 BLAKE2B fe2961f19b0cd005068a8aa6c90b4217de63195e3214e86854dedcb5cb99e3cc1f0c449957e722ec4ae0540f75b8a2509233f6b8712a5a5ca5c602c394d33686 SHA512 b008f1e38218678b52b4e9e756161a44a85d541dd04c6541ddfd15f7e5c9789d510905e050e74426bdae5b76f66e85d15be5fcc109ab549400e2b40cf50d70cc

net-im/element-desktop-bin/element-desktop-bin-1.11.45.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature unpacker xdg
+
+MY_PN="${PN/-bin}"
+
+DESCRIPTION="A glossy Matrix collaboration client for desktop (binary package)"
+HOMEPAGE="https://element.io"
+SRC_URI="https://packages.element.io/debian/pool/main/e/element-desktop/${MY_PN}_${PV}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="splitdebug"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango"
+
+QA_PREBUILT="opt/Element/chrome-sandbox
+	opt/Element/chrome_crashpad_handler
+	opt/Element/element-desktop
+	opt/Element/libEGL.so
+	opt/Element/libGLESv2.so
+	opt/Element/libffmpeg.so
+	opt/Element/libvk_swiftshader.so
+	opt/Element/libvulkan.so.1
+	opt/Element/resources/app.asar.unpacked/node_modules/matrix-seshat/index.node
+	opt/Element/resources/app.asar.unpacked/node_modules/keytar/build/Release/keytar.node"
+
+src_prepare() {
+	default
+	rm opt/Element/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "/${f}"
+	done
+	fperms u+s /opt/Element/chrome-sandbox
+
+	dosym ../../opt/Element/${MY_PN} /usr/bin/${MY_PN}
+	dosym ${MY_PN} /usr/bin/riot-desktop
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "emojis" media-fonts/noto-emoji
+}