media-libs/osl: Version bump to 1.10.10

Version bump osl to 1.10.10

This version of osl supports up to LLVM/Clang 9.

Minimum versions of dependencies have been removed where all versions
in the tree are suitable. The patch to find openexr used in the
previous version is no longer required as it has been incorporated
upstream.

Signed-off-by: Adrian Grigo <agrigo2001@yahoo.com.au>
Closes: https://bugs.gentoo.org/717506
Closes: https://bugs.gentoo.org/720242
Package-Manager: Portage-2.3.99, Repoman-2.3.22

media-libs/osl/Manifest

@@ -1 +1,2 @@
+DIST osl-1.10.10.tar.gz 13549066 BLAKE2B d91360d4cde0e8f70e01aa5cbf14bd6dc30be47ba96d4f2206adb75ef8f14af6af43b00f025cbf9b9c03cfcf117380ee9bb0a93129c314b249151cd97135757b SHA512 10371d9aefa786fefbae15cb9c71d7360bd903a36734840f7d0a960a615d48096b7170596bd934d10579b33d8f8398fc0e00471a10cd517c1a4a601169b2ca13
 DIST osl-1.10.5.tar.gz 13543151 BLAKE2B 3c67834d9ab6d4d725ecde622c402707593b9aaf25f1e94f9ed6b004c28fa9b7b90cfd0d320cb2898f77f8883ac14a71310abaf63a5b06704565c5a3bdea09b4 SHA512 d704b623836edca4c3fe9c18f33b8d76f4625036228fc977732c600e23e16da4cb4bf311607019b251d734b63a184bde0f7726f144ecd5bcd7866938d95bfdff

media-libs/osl/osl-1.10.10.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake llvm toolchain-funcs
+
+# check this on updates
+LLVM_MAX_SLOT=9
+
+DESCRIPTION="Advanced shading language for production GI renderers"
+HOMEPAGE="http://opensource.imageworks.com/?p=osl"
+SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*}"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/pugixml
+	media-libs/openexr:=
+	media-libs/openimageio:=
+	<sys-devel/clang-10:=
+	sys-libs/zlib:=
+	partio? ( media-libs/partio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.10.5-fix-install-shaders.patch"
+)
+
+# Restricting tests as Make file handles them differently
+RESTRICT="test"
+
+S="${WORKDIR}/OpenShadingLanguage-Release-${PV}"
+
+llvm_check_deps() {
+	has_version -r "sys-devel/clang:${LLVM_SLOT}"
+}
+
+src_configure() {
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local gcc=$(tc-getCC)
+	# LLVM needs CPP11. Do not disable.
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DENABLERTTI=OFF
+		-DINSTALL_DOCS=$(usex doc)
+		-DLLVM_STATIC=ON
+		-DOSL_BUILD_TESTS=$(usex test)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_PARTIO=$(usex partio)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
+	)
+
+	cmake_src_configure
+}