x11-plugins/pidgin-*: EAPI8 bumps, minor fixes

x11-plugins/guifications/guifications-2.16-r1.ebuild

@@ -0,0 +1,35 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="pidgin-${PN}"
+MY_PV="${PV/_beta/beta}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="Guifications is a graphical notification plugin for pidgin"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="http://downloads.guifications.org/plugins//Guifications2/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="debug nls"
+
+RDEPEND="net-im/pidgin[gtk]
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	econf \
+		$(use_enable debug ) \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+
+	find "${D}" -type f -name '*.la' -delete || die "la removal failed"
+}

x11-plugins/pidgin-birthday-reminder/pidgin-birthday-reminder-1.7-r2.ebuild

@@ -0,0 +1,33 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Plugin for Pidgin that reminds you of your buddies birthdays"
+HOMEPAGE="https://launchpad.net/pidgin-birthday-reminder"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="static-libs"
+
+RDEPEND="net-im/pidgin[gtk]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	if ! use static-libs ; then
+		find "${D}" -type f -name '*.la' -delete || die "la removal failed"
+	fi
+}

x11-plugins/pidgin-hotkeys/pidgin-hotkeys-0.2.4-r1.ebuild

@@ -0,0 +1,23 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Pidgin plugin to define global hotkeys for various actions"
+HOMEPAGE="https://sourceforge.net/projects/pidgin-hotkeys/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+
+RDEPEND="net-im/pidgin[gtk]
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_install() {
+	default
+
+	find "${D}" -type f -name '*.la' -delete || die
+}

x11-plugins/pidgin-led-notification/pidgin-led-notification-0.1.ebuild → x11-plugins/pidgin-led-notification/pidgin-led-notification-0.1-r1.ebuild

@@ -1,29 +1,27 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
 inherit toolchain-funcs
 
-MY_PN=${PN/pidgin-/}
-MY_P=${MY_PN}-${PV}
+MY_PN="${PN/pidgin-/}"
+MY_P="${MY_PN}-${PV}"
 
 DESCRIPTION="Pidgin plugin to notify by writing user defined strings to (led control) files"
 HOMEPAGE="https://sites.google.com/site/simohmattila/led-notification"
 SRC_URI="https://sites.google.com/site/simohmattila/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~riscv ~x86"
-IUSE=""
 
 RDEPEND="
 	net-im/pidgin[gtk]
 	x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-S=${WORKDIR}/${MY_P}
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
 PATCHES=( "${FILESDIR}"/${P}-hardware.patch )
 

x11-plugins/pidgin-libnotify/pidgin-libnotify-0.14-r2.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Pidgin-libnotify provides popups for pidgin via a libnotify interface"
+HOMEPAGE="https://gaim-libnotify.sourceforge.net/"
+SRC_URI="mirror://sourceforge/gaim-libnotify/${P}.tar.gz
+	mirror://debian/pool/main/p/${PN}/${PN}_${PV}-4.debian.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="nls debug"
+
+RDEPEND=">=x11-libs/libnotify-0.3.2
+	net-im/pidgin[gtk]
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}/debian/patches"
+	"${FILESDIR}/${P}-libnotify-0.7.patch"
+)
+
+src_prepare() {
+	default
+	sed -i -e '/CFLAGS/s:-g3::' configure || die "sed failed"
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die "Pruning failed"
+}

x11-plugins/pidgin-mbpurple/pidgin-mbpurple-0.3.0-r3.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_P="${P/pidgin-/}"
+
+DESCRIPTION="Pidgin plug-in supporting microblog services like Twitter or identi.ca"
+HOMEPAGE="https://code.google.com/archive/p/microblog-purple/"
+SRC_URI="https://microblog-purple.googlecode.com/files/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="+twitgin"
+
+RDEPEND="net-im/pidgin
+	twitgin? ( net-im/pidgin[gtk] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# upstream Issue 226 (Respect LDFLAGS)
+	sed -i "/^LDFLAGS/d" global.mak || die "sed for LDFLAGS failed"
+
+	# upstream Issue 225 (Warnings during compilation using make -j2)
+	sed -i "s/make /\$(MAKE) /g" Makefile || die "sed #2 failed"
+
+	# upstream Issue 224 (configurable twitgin)
+	if ! use twitgin; then
+		sed -i 's/twitgin//g' Makefile || die
+	fi
+}
+
+src_configure() {
+	tc-export CC
+}

x11-plugins/pidgin-privacy-please/pidgin-privacy-please-0.7.1-r1.ebuild

@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Pidgin plugin to stop spammers from annoying you"
+HOMEPAGE="https://code.google.com/p/pidgin-privacy-please/"
+SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="<net-im/pidgin-3[gtk]"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	default
+	sed -e 's: -Wall -g3::' -i configure.ac || die
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	find "${D}" -type f -name '*.la' -delete || die "la removal failed"
+}