Adds a new salvager weapon: The Makeshift Laser Rifle

code/datums/components/power_cell.dm

@@ -36,6 +36,15 @@ TYPEINFO(/datum/component/power_cell)
 	RegisterSignal(parent, COMSIG_CELL_IS_CELL, PROC_REF(is_cell))
 	RegisterSignal(parent, COMSIG_ITEM_PROCESS, PROC_REF(process))
 
+/datum/component/power_cell/UnregisterFromParent()
+	UnregisterSignal(parent, COMSIG_ATTACKBY)
+	UnregisterSignal(parent, COMSIG_CELL_CHARGE)
+	UnregisterSignal(parent, COMSIG_CELL_CAN_CHARGE)
+	UnregisterSignal(parent, COMSIG_CELL_USE)
+	UnregisterSignal(parent, COMSIG_CELL_CHECK_CHARGE)
+	UnregisterSignal(parent, COMSIG_CELL_IS_CELL)
+	UnregisterSignal(parent, COMSIG_ITEM_PROCESS)
+	. = ..()
 
 /datum/component/power_cell/InheritComponent(datum/component/power_cell/C, i_am_original, max, start_charge, recharge, delay, rechargable)
 	if(C)

code/modules/projectiles/laser.dm

@@ -621,3 +621,9 @@ toxic - poisons
 			hit.delStatus("cornicened2")
 		else
 			hit.setStatus("cornicened")
+
+/datum/projectile/laser/makeshift
+	cost = 1500
+	shot_sound = 'sound/weapons/laserlight.ogg'
+	icon_state = "laser_tiny"
+	damage = 12

code/obj/item/grenades.dm

@@ -1551,11 +1551,22 @@ TYPEINFO(/obj/item/old_grenade/oxygen)
 		src.AddComponent(/datum/component/assembly, src.allowed_items, PROC_REF(pipebomb_stuffing), TRUE)
 		// hollow frame + staple gun  -> zipgun
 		src.AddComponent(/datum/component/assembly, /obj/item/staple_gun, PROC_REF(zipgun_crafting), TRUE)
+		// hollow frame + wrench  -> makeshift laser gun frame
+		src.AddComponent(/datum/component/assembly, TOOL_WRENCHING, PROC_REF(makeshift_laser_crafting), FALSE)
 		// hollow frame + fuel  -> unwired pipebombs
 		src.AddComponent(/datum/component/assembly, list(/obj/item/reagent_containers/glass, /obj/item/reagent_containers/food/drinks,), PROC_REF(pipebomb_filling), FALSE)
 		// Since the assembly was done, return TRUE
 		return TRUE
 
+	/// laser rifle crafting proc
+	proc/makeshift_laser_crafting(var/atom/to_combine_atom, var/mob/user)
+		user.show_text("You wrench [src] into one long pipe!")
+		user.u_equip(src)
+		playsound(src, 'sound/items/Ratchet.ogg', 50, TRUE)
+		var/obj/item/gun/kinetic/zipgun/new_gun = new/obj/item/makeshift_laser_barrel
+		user.put_in_hand_or_drop(new_gun)
+		qdel(src)
+
 	/// Zipgun crafting proc
 	proc/zipgun_crafting(var/atom/to_combine_atom, var/mob/user)
 		user.show_text("You combine [to_combine_atom] and [src]. This looks pretty unsafe!")

code/obj/item/gun/energy.dm

@@ -1858,3 +1858,276 @@ TYPEINFO(/obj/item/gun/energy/wasp)
 		set_current_projectile(new/datum/projectile/energy_bolt/dazzler)
 		projectiles = list(current_projectile)
 		..()
+
+#define HEAT_REMOVED_PER_PROCESS 25
+// Makeshift Laser Rifle
+TYPEINFO(/obj/item/gun/energy/makeshift)
+	mats = 0
+
+/obj/item/gun/energy/makeshift
+	name = "makeshift laser rifle"
+	icon = 'icons/obj/large/64x32.dmi'
+	wear_image_icon = 'icons/mob/clothing/back.dmi'
+	icon_state = "makeshift-energy"
+	item_state = "makeshift_laser"
+	wear_state = "makeshift_laser"
+	w_class = W_CLASS_BULKY
+	c_flags = ONBACK
+	cell_type = null
+	can_swap_cell = FALSE
+	rechargeable = FALSE
+	force = 7
+	two_handed = TRUE
+	can_dual_wield = FALSE
+	desc = "A laser rifle cobbled together from various supplies found around the station, probably not the most reliable weapon in a firefight."
+	muzzle_flash = "muzzle_flash_phaser"
+	charge_icon_state = "laser"
+	spread_angle = 10
+	shoot_delay = 5 DECI SECONDS
+	///What light source we use for the rifle
+	var/obj/item/light/tube/our_light
+	///What battery this gun uses
+	var/obj/item/cell/our_cell
+	///How much heat this weapon has after firing, the flashlight breaks if this gets too high
+	var/heat = 0
+
+	proc/break_light()
+		elecflash(get_turf(src), 1, 3)
+		our_light.light_status = LIGHT_BURNED
+		our_light.update()
+
+	proc/attach_cell(var/obj/item/cell/C, mob/user)
+		if (user)
+			user.u_equip(C)
+		our_cell = C
+		our_cell.set_loc(src)
+		our_cell.AddComponent(/datum/component/power_cell, our_cell.maxcharge, our_cell.charge, our_cell.genrate, 0, FALSE)
+		SEND_SIGNAL(src, COMSIG_CELL_SWAP, our_cell)
+		update_icon()
+
+	proc/do_explode()
+		explosion(src, get_turf(src), -1, -1, 1, 2)
+		qdel(src)
+
+	emp_act()
+		if (our_cell)
+			src.visible_message("<span class='alert'>[src]'s cell violently explodes!</span>")
+			do_explode() // heh
+
+	New()
+		processing_items |= src
+		set_current_projectile(new/datum/projectile/laser/makeshift)
+		projectiles = list(current_projectile)
+		..()
+
+	Exited(Obj, newloc)
+		var/obj/item/cell/C = Obj
+		if (istype(C) && !QDELETED(C))
+			C.update_icon()
+			var/datum/component/power_cell/comp = C.GetComponent(/datum/component/power_cell)
+			comp.UnregisterFromParent()
+			comp.RemoveComponent()
+			our_cell = null
+			update_icon()
+		. = ..()
+
+
+	process()
+		if (heat > 0)
+			heat = max(0, heat - HEAT_REMOVED_PER_PROCESS)
+			update_icon()
+		return
+
+	canshoot(mob/user)
+		if (!our_light)
+			boutput(user,"<span class='alert'>[src] needs a light source to function!</span>")
+			return FALSE
+		else if (our_light.light_status != LIGHT_OK)
+			boutput(user,"<span class='alert'>[src] has no reaction when you pull the trigger!</span>")
+			return FALSE
+		else
+			return ..()
+
+	attackby(obj/item/W, mob/user, params)
+		if (iswrenchingtool(W) && our_cell)
+			var/obj/item/removed_cell = our_cell
+			SEND_SIGNAL(src, COMSIG_CELL_SWAP, null)
+			boutput(user,"<span class='notice'>You disconnect [our_cell] from [src].</span>")
+			playsound(src, 'sound/items/Ratchet.ogg', 50, TRUE)
+			user.put_in_hand_or_drop(removed_cell)
+			return
+		else if (istype(W, /obj/item/cell) && !our_cell)
+			user.u_equip(W)
+			boutput(user,"<span class='notice'>You attach [W] to [src].</span>")
+			attach_cell(W, user)
+			return
+		else if (issnippingtool(W) && our_light)
+			boutput(user,"<span class='notice'>You remove [our_light] from the barrel.</span>")
+			playsound(src, 'sound/items/Wirecutter.ogg', 50, TRUE)
+			user.put_in_hand_or_drop(our_light)
+			our_light = null
+			update_icon()
+			return
+		else if (istype(W, /obj/item/light/tube) && !our_light)
+			boutput(user,"<span class='notice'>You place [W] inside of the barrel and redo the wiring.</span>")
+			playsound(src.loc, 'sound/effects/pop.ogg', 50, TRUE)
+			user.u_equip(W)
+			our_light = W
+			W.set_loc(src)
+			update_icon()
+			return
+		..()
+
+	examine()
+		. = ..()
+		if (!our_cell)
+			. += "[src] is lacking a power source!"
+
+	attack_self(mob/user)
+		var/I = tgui_input_number(user, "Input a firerate (In deciseconds)", "Timer Adjustment", shoot_delay, 10, 2)
+		if (!I || BOUNDS_DIST(src, user) > 0)
+			return
+		shoot_delay = I
+		boutput(user, "<span class='notice'>You adjust [src] to fire every [I / 10] seconds.</span>")
+
+	update_icon()
+		if (our_cell)
+			var/image/overlay_image
+			if (istype(our_cell, /obj/item/cell/artifact))
+				var/obj/item/cell/artifact/C = our_cell
+				var/datum/artifact/powercell/AS = C.artifact
+				var/datum/artifact_origin/AO = AS.artitype
+				overlay_image = SafeGetOverlayImage("gun_cell", 'icons/obj/large/64x32.dmi', "makeshift-[AO.name]")
+			else
+				overlay_image = SafeGetOverlayImage("gun_cell", 'icons/obj/large/64x32.dmi', "makeshift-[our_cell.icon_state]")
+			src.UpdateOverlays(overlay_image, "gun_cell")
+		else
+			src.UpdateOverlays(null, "gun_cell")
+
+		if (our_light)
+			var/image/overlay_image = SafeGetOverlayImage("gun_light", 'icons/obj/large/64x32.dmi', "makeshift-light")
+			src.UpdateOverlays(overlay_image, "gun_light")
+		else
+			src.UpdateOverlays(null, "gun_light")
+
+		if (heat > 70) // danger of breaking
+			var/image/overlay_image = SafeGetOverlayImage("gun_smoke", 'icons/obj/large/64x32.dmi', "makeshift-smoke")
+			src.UpdateOverlays(overlay_image, "gun_smoke")
+		else
+			src.UpdateOverlays(null, "gun_smoke")
+		..()
+
+	shoot(turf/target, turf/start, mob/user, POX, POY, is_dual_wield, atom/called_target = null)
+		if (canshoot(user))
+			if (our_light.rigged) // bad idea
+				src.visible_message("<span class='alert'>[src]'s light tube violently explodes!</span>")
+				do_explode()
+				return
+			heat += rand(15,20)
+			update_icon()
+			if (heat > 120 || (heat > 100 && prob(25)))
+				boutput(user,"<span class='alert'>[src]'s light source breaks due to the excess heat within!</span>")
+				break_light()
+				return
+			our_cell.use(current_projectile.cost)
+		return ..(target, start, user)
+
+/obj/item/makeshift_laser_barrel
+	name = "pipe assembly"
+	desc = "A long empty pipe."
+	w_class = W_CLASS_BULKY // so you cant have 5 almost finished guns in your backpack then finish them in a combat encounter
+
+	tooltip_rebuild = TRUE
+	icon = 'icons/obj/large/64x32.dmi'
+	icon_state = "makeshift-construction1"
+
+	var/obj/item/light/tube/our_light
+
+	New()
+		..()
+		src.AddComponent(/datum/component/assembly, /obj/item/sheet, PROC_REF(construct_stock), FALSE)
+
+	proc/construct_stock(var/atom/to_combine_atom, var/mob/user)
+		var/obj/item/sheet/W = to_combine_atom
+		if (W.material.getMaterialFlags() & MATERIAL_METAL && W.amount >= 4)
+			boutput(user,"<span class='notice'>You construct a stock and grip for the barrel.</span>")
+			playsound(src.loc, 'sound/effects/pop.ogg', 50, TRUE)
+			W.change_stack_amount(-4)
+			name = "pipe/stock assembly"
+			desc = "A gun of some kind? It seems unfinished."
+			icon_state = "makeshift-construction2"
+			update_icon()
+			src.RemoveComponentsOfType(/datum/component/assembly)
+			src.AddComponent(/datum/component/assembly, /obj/item/sheet, PROC_REF(construct_lens), FALSE)
+			return TRUE
+
+	proc/construct_lens(var/atom/to_combine_atom, var/mob/user)
+		var/obj/item/sheet/W = to_combine_atom
+		if (W.material.getMaterialFlags() & MATERIAL_CRYSTAL && W.amount >= 3)
+			boutput(user,"<span class='notice'>You create a lens using [W] and stuff it inside [src].</span>")
+			W.change_stack_amount(-3)
+			src.RemoveComponentsOfType(/datum/component/assembly)
+			src.AddComponent(/datum/component/assembly, /obj/item/light/tube, PROC_REF(add_lighttube), FALSE)
+			return TRUE
+
+	proc/add_lighttube(var/atom/to_combine_atom, var/mob/user)
+		var/obj/item/light/tube/T = to_combine_atom
+		boutput(user,"<span class='notice'>You place [T] inside of the barrel.</span>")
+		playsound(src.loc, 'sound/effects/pop.ogg', 50, TRUE)
+		user.u_equip(T)
+		our_light = T
+		T.set_loc(src)
+		name = "pipe/stock/light assembly"
+		icon_state = "makeshift-construction3"
+		update_icon()
+		src.RemoveComponentsOfType(/datum/component/assembly)
+		src.AddComponent(/datum/component/assembly, /obj/item/device/timer, PROC_REF(add_timer), FALSE)
+		return TRUE
+
+	proc/add_timer(var/atom/to_combine_atom, var/mob/user)
+		var/obj/item/device/timer/T = to_combine_atom
+		boutput(user,"<span class='notice'>You attach the timer to [src].</span>")
+		playsound(src.loc, 'sound/effects/pop.ogg', 50, TRUE)
+		user.u_equip(T)
+		qdel(T)
+		name = "pipe/stock/light/timer assembly"
+		icon_state = "makeshift-construction4"
+		update_icon()
+		src.RemoveComponentsOfType(/datum/component/assembly)
+		src.AddComponent(/datum/component/assembly, TOOL_WELDING, PROC_REF(weld_barrel), FALSE)
+		return TRUE
+
+	proc/weld_barrel(var/atom/to_combine_atom, var/mob/user)
+		if (to_combine_atom:try_weld(user, 1))
+			boutput(user,"<span class='notice'>You weld the end of the barrel into a point.</span>")
+			name = "makeshift energy rifle"
+			icon_state = "makeshift-construction5"
+			update_icon()
+			src.RemoveComponentsOfType(/datum/component/assembly)
+			src.AddComponent(/datum/component/assembly, /obj/item/cable_coil, PROC_REF(finish_gun), FALSE)
+			return TRUE
+
+	proc/finish_gun(var/atom/to_combine_atom, var/mob/user)
+		var/obj/item/cable_coil/C = to_combine_atom
+		boutput(user,"<span class='notice'>You wire [src] together.</span>")
+		C.change_stack_amount(-1)
+		var/obj/item/gun/energy/makeshift/M = new/obj/item/gun/energy/makeshift
+		M.our_light = our_light
+		our_light.set_loc(M)
+		user.put_in_hand_or_drop(M)
+		M.update_icon()
+		qdel(src)
+		return
+
+
+
+/obj/item/makeshift_laser_barrel/testing
+
+	New()
+		..()
+		our_light = new /obj/item/light/tube
+		our_light.set_loc(src)
+		src.RemoveComponentsOfType(/datum/component/assembly)
+		src.AddComponent(/datum/component/assembly, /obj/item/cable_coil, PROC_REF(finish_gun), FALSE)
+
+#undef HEAT_REMOVED_PER_PROCESS