-
Notifications
You must be signed in to change notification settings - Fork 4.7k
/
BaseIncrementalCompilationAfterFailureIntegrationTest.groovy
351 lines (298 loc) · 12.9 KB
/
BaseIncrementalCompilationAfterFailureIntegrationTest.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
/*
* Copyright 2022 the original author or authors.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package org.gradle.java.compile.incremental
import org.gradle.api.internal.cache.StringInterner
import org.gradle.api.internal.tasks.compile.incremental.recomp.PreviousCompilationAccess
import org.gradle.integtests.fixtures.CompiledLanguage
import org.gradle.util.Requires
import org.gradle.util.TestPrecondition
import spock.lang.Issue
import static org.junit.Assume.assumeFalse
abstract class BaseIncrementalCompilationAfterFailureIntegrationTest extends AbstractJavaGroovyIncrementalCompilationSupport {
def "detects deletion of a source base class that leads to compilation failure but keeps old files"() {
def a = source "class A {}"
source "class B extends A {}"
outputs.snapshot { run language.compileTaskName }
when:
assert a.delete()
then:
fails language.compileTaskName
outputs.noneRecompiled()
// We keep old classes since we support incremental compilation after failure
outputs.deletedClasses()
}
def "old classes are restored after the compile failure"() {
source("class A {}", "class B {}")
outputs.snapshot { run language.compileTaskName }
when:
source("class A { garbage }")
runAndFail language.compileTaskName
then:
outputs.noneRecompiled()
outputs.hasFiles(file("A.class"), file("B.class"))
}
def "incremental compilation works after a compile failure"() {
source("class A {}", "class B {}")
outputs.snapshot { run language.compileTaskName }
source("class A { garbage }")
runAndFail language.compileTaskName
outputs.noneRecompiled()
when:
source("class A { }")
run language.compileTaskName
then:
outputs.recompiledClasses("A")
outputs.hasFiles(file("A.class"), file("B.class"))
}
def "incremental compilation works after multiple compile failures"() {
source("class A {}", "class B {}")
outputs.snapshot { run language.compileTaskName }
source("class A { garbage }")
runAndFail language.compileTaskName
outputs.noneRecompiled()
runAndFail language.compileTaskName
outputs.noneRecompiled()
when:
source("class A { }")
run language.compileTaskName
then:
outputs.recompiledClasses("A")
outputs.hasFiles(file("A.class"), file("B.class"))
}
def "nothing is recompiled after a compile failure when file is reverted"() {
source("class A {}", "class B {}")
outputs.snapshot { run language.compileTaskName }
source("class A { garbage }")
runAndFail language.compileTaskName
outputs.noneRecompiled()
when:
source("class A {}")
run language.compileTaskName
then:
outputs.noneRecompiled()
outputs.hasFiles(file("A.class"), file("B.class"))
}
def "writes relative paths to source-to-class mapping after incremental compilation"() {
given:
assumeFalse("Source-to-class mapping is not written for CLI compiler", this.class == JavaSourceCliIncrementalCompilationIntegrationTest.class)
source("package test.gradle; class A {}", "package test2.gradle; class B {}")
outputs.snapshot { run language.compileTaskName }
def previousCompilationDataFile = file("build/tmp/${language.compileTaskName}/previous-compilation-data.bin")
def previousCompilationAccess = new PreviousCompilationAccess(new StringInterner())
when:
source("package test.gradle; class A { static class C {} }")
run language.compileTaskName
then:
outputs.recompiledClasses("A", 'A$C')
def previousCompilationData = previousCompilationAccess.readPreviousCompilationData(previousCompilationDataFile)
previousCompilationData.compilerApiData.sourceToClassMapping == [
("test/gradle/A.${languageName}" as String): ["test.gradle.A", "test.gradle.A\$C"] as Set,
("test2/gradle/B.${languageName}" as String): ["test2.gradle.B"] as Set
]
}
def "nothing is stashed on full recompilation but it's stashed on incremental compilation"() {
given:
source("class A {}", "class B {}")
def compileTransactionDir = file("build/tmp/${language.compileTaskName}/compileTransaction")
when: "First compilation is always full compilation"
run language.compileTaskName
then:
outputs.recompiledClasses("A", "B")
!compileTransactionDir.exists()
when: "Compilation after failure with clean is full recompilation"
source("class A { garbage }")
runAndFail language.compileTaskName
outputs.snapshot { source("class A { }") }
run "clean", language.compileTaskName
then:
outputs.recompiledClasses("A", "B")
!compileTransactionDir.exists()
when: "Incremental compilation"
outputs.snapshot { source("class A {}") }
run language.compileTaskName
then:
outputs.recompiledClasses("A")
compileTransactionDir.exists()
compileTransactionDir.file("stash-dir/A.class.uniqueId0").exists()
}
@Issue("https://github.com/gradle/gradle/issues/21644")
def "unrelated class in the same source file as affected class is recompiled and stashed on incremental compilation"() {
given:
source "class A {}", "class B extends A {}", "class D {}"
// F is not affected by changes, but it is recompiled
// and should still be stashed since it's in the same source file as C
source """
class C extends B {}
class F {}
"""
def compileTransactionDir = file("build/tmp/${language.compileTaskName}/compileTransaction")
def stashDirClasses = {
compileTransactionDir.file("stash-dir")
.list()
.collect { it.replaceAll(".uniqueId.", "") }
.sort()
}
when: "First compilation is always full compilation"
run language.compileTaskName
then:
outputs.recompiledClasses("A", "B", "C", "D", "F")
!compileTransactionDir.exists()
when:
outputs.snapshot { source("class A { /* comment */ }") }
run language.compileTaskName
then:
outputs.recompiledClasses("A", "B", "C", "F")
compileTransactionDir.exists()
stashDirClasses() == ["A.class", "B.class", "C.class", "F.class"]
}
def "can disable incremental compilation after failure and forces full recompilation"() {
given:
def compileTask = language == CompiledLanguage.GROOVY ? "GroovyCompile" : "JavaCompile"
buildFile << """
tasks.withType($compileTask) {
options.incremental = true
options.incrementalAfterFailure = false
}
"""
source "class A {}", "class B extends A {}", "class C {}"
when: "First compilation is always full compilation"
run language.compileTaskName
then:
outputs.recompiledClasses("A", "B", "C")
when: "Compilation after failure is full recompilation when optimization is disabled"
outputs.snapshot { source("class A { garbage }") }
runAndFail language.compileTaskName
outputs.snapshot { source("class A {}") }
run language.compileTaskName, "--info"
then:
outputs.recompiledClasses("A", "B", "C")
outputContains("Full recompilation is required")
}
}
class JavaIncrementalCompilationAfterFailureIntegrationTest extends BaseIncrementalCompilationAfterFailureIntegrationTest {
CompiledLanguage language = CompiledLanguage.JAVA
@Requires(TestPrecondition.JDK9_OR_LATER)
def "incremental compilation after failure works with modules #description"() {
file("impl/build.gradle") << """
def layout = project.layout
tasks.compileJava {
modularity.inferModulePath = $inferModulePath
options.compilerArgs.addAll($compileArgs)
doFirst {
$doFirst
}
}
"""
source "package a; import b.B; public class A {}",
"package b; public class B {}",
"package c; public class C {}"
file("src/main/${language.name}/module-info.${language.name}").text = """
module impl {
exports a;
exports b;
exports c;
}
"""
succeeds language.compileTaskName
outputs.recompiledClasses("A", "B", "C", "module-info")
when:
outputs.snapshot {
source "package a; import b.B; public class A { void m1() {}; }",
"package b; import a.A; public class B { A m1() { return new B(); } }"
}
then:
fails language.compileTaskName
when:
outputs.snapshot {
source "package a; import b.B; public class A { void m1() {}; }",
"package b; import a.A; public class B { A m1() { return new A(); } }"
}
succeeds language.compileTaskName
then:
outputs.recompiledClasses("A", "B", "module-info")
where:
description | inferModulePath | compileArgs | doFirst
"with inferred module-path" | "true" | "[]" | ""
"with manual module-path" | "false" | "[\"--module-path=\${classpath.join(File.pathSeparator)}\"]" | "classpath = layout.files()"
}
}
class GroovyIncrementalCompilationAfterFailureIntegrationTest extends BaseIncrementalCompilationAfterFailureIntegrationTest {
CompiledLanguage language = CompiledLanguage.GROOVY
def setup() {
configureGroovyIncrementalCompilation()
}
@Issue("https://github.com/gradle/gradle/issues/21644")
def "removes all classes for a recompiled source from output to stash dir for Spock tests when super class is changed"() {
given:
buildScript """
plugins {
id 'groovy'
id 'java-library'
}
${mavenCentralRepository()}
dependencies {
testImplementation 'org.codehaus.groovy:groovy:3.0.13'
testImplementation 'org.spockframework:spock-core:2.1-groovy-3.0'
}
tasks.withType(GroovyCompile) {
options.incremental = true
}
tasks.named('test') {
useJUnitPlatform()
}
"""
file("src/test/groovy/BaseTest.groovy").text = """
import spock.lang.Specification
class BaseTest extends Specification {}
"""
file("src/test/groovy/UnrelatedClass.groovy").text = "class UnrelatedClass {}"
file("src/test/groovy/AppTest.groovy").text = """
class AppTest extends BaseTest {
def "some test"() {
// These nested closures create nested \$closureXY.class
with("") {
with("") {
}
}
}
}
"""
def compileTransactionDir = file("build/tmp/compileTestGroovy/compileTransaction")
def stashDirClasses = {
compileTransactionDir.file("stash-dir")
.list()
.collect { it.replaceAll(".uniqueId.", "") }
.sort() as Set<String>
}
when: "First compilation is always full compilation"
run "compileTestGroovy"
then:
outputs.recompiledClasses("AppTest", "AppTest\$_some_test_closure1", "AppTest\$_some_test_closure1\$_closure2", "BaseTest", "UnrelatedClass")
!compileTransactionDir.exists()
when:
outputs.snapshot {
file("src/test/groovy/BaseTest.groovy").text = """
import spock.lang.Specification
class BaseTest extends Specification { void hello() {} }
"""
}
run "compileTestGroovy"
then:
outputs.recompiledClasses("AppTest", "AppTest\$_some_test_closure1", "AppTest\$_some_test_closure1\$_closure2", "BaseTest")
compileTransactionDir.exists()
stashDirClasses() == ["AppTest.class", "AppTest\$_some_test_closure1.class", "AppTest\$_some_test_closure1\$_closure2.class", "BaseTest.class"] as Set<String>
}
}