Example for FormUrlEncoded endpoint

[rubenmoor]

Is there an example on how to implement a FormUrlEncoded endpoint in Servant?

I'm trying to build plain, old HTML forms (using digestive-functors and blaze) and want Servant to handle GET and POST. For digestive functors I need to build an Env m and I'm looking for a good starting point.

Atm I don't even understand what the consequences of the FormUrlEncoded-contenttype are, as in here:

type Api = "contract" :> "create" :> ReqBody '[FormUrlEncoded] ContractData :> Post '[HTML] Html

[fizruk]

Have you looked at ToFormUrlEncoded/FromFormUrlEncoded classes in Servant.API.ContentTypes?

If you're making a server, you just need to implement instance FromFormUrlEncoded ContractData to be able to handle incoming form data.

[fizruk]

Also documentation on FormUrlEncoded tells you that it uses application/x-www-form-urlencoded content type.

[alpmestan]

Here's a minimal example of using FormUrlEncoded.

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE OverloadedStrings #-}
import Control.Applicative
import Data.Aeson
import Data.Monoid
import Servant

type API = "login" :> ReqBody '[FormUrlEncoded] User :> Post '[JSON] Login

data Login = LoggedIn | NotLoggedIn
  deriving (Eq, Show)

instance ToJSON Login where
  toJSON = toJSON . show

data User = User
  { email :: Text
  , password :: Text
  } deriving (Eq, Show)

instance FromFormUrlEncoded User where
  fromFormUrlEncoded inputs =
    User <$> lkp "email" <*> lkp "password"

    where lkp input_label = case lookup input_label inputs of
                 Nothing -> Left $ "label " <> input_label <> " not found"
                 Just v    -> Right v

server :: Server API
server usr =
  if email usr == "admin@admin.com" && password usr == "1234"
  then return LoggedIn
  else return NotLoggedIn

Now, as you can see, in the FromFormUrlEncoded instance I don't do any fancy validation here. inputs is a list of all inputs pairs (input_name, input_value), of type [(Text, Text)], which I'm pretty sure most validation libraries will happily let you work with. I however don't use any of them but would be glad to help you figure out how to wire those to this FromFormUrlEncoded class :)

[rubenmoor]

Great, thanks! I'll be able to take it from here.

[alpmestan]

Feel free to use this issue to ask questions, if you get stuck further down the road.

[jkarni]

I think it'd be very useful to have an example of using digestive-functors with servant though. @rubenmoor if you end up doing that, please consider adding an example to servant-examples!

[rubenmoor]

@jkarni will sure do!

[alpmestan]

Can we consider this issue solved/closed?

[rubenmoor]

Closed, in my opinion. I'll get back later with my solution and open questions regarding the combination of Servant with digestive-functors.

[alpmestan]

Yeah, definitely. Just open an issue about this when you manage to make both play well together :)