Ignoring hook context

[nh2]

Hi, I found myself to use the following (see full example:

-- | When a hook is set up with `beforeAll`, that changes the type
-- of all hspec `it`s to take the value supplied by `beforeAll`.
--
-- In some cases, we just want to use `beforeAll`/`afterAll` to have
-- a process (e.g. a web server) running during the tests, and the
-- individual `it`s may not care about the value supplied by `beforeAll`.
--
-- In such cases, this function can be used to allow to use plain `it`s
-- within a `describe` block that would usually mandate all `it`s to
-- accept the `a` that `beforeAll` provided.
ignoreHookContext :: SpecWith () -> SpecWith a
ignoreHookContext = Hooks.aroundWith (\actionRunner -> const (actionRunner ()))


spec :: Spec -- == SpecWith ()
spec =
    beforeAll (putStrLn "beforeAll hook" >> threadDelay 2000000 >> return (3 :: Int))
  . afterAll (\i -> putStrLn ("afterAll hook: " ++ show (i::Int)))
  $ do

  describe "section using the hook return value" $ do
    it "does X" $ \i -> do
      putStrLn $ "done, with access to value " ++ show i

  ignoreHookContext $ do
    describe "section NOT using the hook return value" $ do
      it "does Y" $
        putStrLn "done"

Is this a sensible pattern to use?

Should it be a helper function in hspec?

[soenkehahn]

This seems like a sensible pattern, yes. Maybe it would even make sense to have this as a primitive and implement before_ and friends in terms of it.

However both @sol and me are still experimenting with approaches for allowing multiple arguments to spec items. We tend to defer this issue until we have a proper solution. (We're afraid of additional breakage.)

If this is important to you, we would be happy to include it now though. Personally I use it "foo" $ \ _ -> ....

[sol]

I think this is a specialization #353.

[sol]

However both @sol and me are still experimenting with approaches for allowing multiple arguments to spec items.

I'm tempted to ditch this. Having only one argument to spec items actually nicely fits the concept of "subject under test" (see my prototype for RSpec-style one-liner it-blocks, https://github.com/hspec/hspec-subject).

[sol]

With #360 ignoreHookContext becomes

ignoreHookContext :: SpecWith () -> SpecWith a
ignoreHookContext = mapSubject (const ())

Assuming we add mapSubject, do we still want a separate primitive for this?

[sol]

mapSubject / ignoreSubject is on Hackage with hspec-2.8.2.