-
Notifications
You must be signed in to change notification settings - Fork 0
/
IntroFramework.asm
1832 lines (1460 loc) · 46.5 KB
/
IntroFramework.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
*****************************************************************************
; Name : IntroFramework.s
; Coded by : Antiriad (Jonathan Bennett <jon@autoitscript.com)
; Description : Shared framework.
; Date last edited : 04/02/2020
*****************************************************************************
include "hardware/custom.i"
include "hardware/cia.i"
include "hardware/dmabits.i"
include "hardware/intbits.i"
include "exec/execbase.i"
include "exec/exec_lib.i"
include "graphics/gfxbase.i"
include "graphics/graphics_lib.i"
include "graphics/text.i"
include "../IntroConfig.i"
include "IntroFramework.i"
include "CustomExtra.i"
include "CustomMacros.i"
*****************************************************************************
ifeq FW_MUSIC_TYPE-1 ;p61
xref P61_End
xref P61_Init
xref P61_VBR
xref P61_Play
xref P61_E8 ;word
xref P61_visuctr0 ;words
xref P61_visuctr1 ;words
xref P61_visuctr2 ;words
xref P61_visuctr3 ;words
xref P61Module
xref P61Samples
ifeq FW_MUSIC_VBLANK-1
xref P61_Music
endif
endif
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay
xref _mt_install_cia
xref _mt_remove_cia
xref _mt_init
xref _mt_end
;xref _mt_music
xref _mt_E8Trigger ;byte
xref _mt_Enable
xref _mt_VUMeter ;byte
xref PHXPT_Module
xref PHXPT_Samples
endif
ifne FW_MUSIC_AMIGAKLANG
xref AMIGAKLANG_Init
xref AMIGAKLANG_Temp
xref AMIGAKLANG_Isamp
xref AMIGAKLANG_Progress
endif
ifeq FW_MUSIC_TYPE-3 ;prt
include "MusicReplay/PreTracker_Offsets.i"
; Song/buffers from IntroSharedData.s
xref prtPlayer
xref prtChipBuf
xref prtPlayerBuf
xref prtSong
xref prtSongBuf
endif
;Shared buffers
xref FW_Chip_Buffer_1
xref FW_Chip_Buffer_1_End
xref FW_Public_Buffer_1
xref FW_Public_Buffer_1_End
*****************************************************************************
section FW_PublicCode,code ;Code section in Public memory
*****************************************************************************
*****************************************************************************
* Gets sys details like VBR on 68010+ and if AA chipset. Run first as it gets
* critical details like VBR.
* IN:
* OUT:
* TRASHED: d0-d1/a0-a1
*****************************************************************************
xdef FW_Init
FW_Init:
movem.l d2-d7/a2-a6,-(sp) ;save
lea FW_Vars(pc),a4
;Kickstart check
move.l (_ExecBase).w,a6
cmp.w #37,LIB_VERSION(a6) ;Check for Kickstart 2.04+ (A600) or later. For Cache functions
sge FW_KICKSTART2ORLATER(a4)
;AA check
cmpi.b #$f8,lisaid+1+_custom ;$fc=ECS, $f8=AA
seq FW_AA_CHIPSET(a4)
;VBR check
move.l (_ExecBase).w,a6
moveq #0,d0 ;default VBR at $0
btst.b #0,AttnFlags+1(a6) ;68000 CPU?
beq.s .yes68k
lea .GetVBR(pc),a5 ;else fetch vector base address
jsr _LVOSupervisor(a6) ;Go Supervisor mode to run a5 and return VBR
.yes68k:
move.l d0,FW_VBRPTR(a4) ;d0 is vbr
movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
; From call to Supervisor()
; Get VBR in d0.l
.GetVBR
;dc.w $4e7a,$c801 ; movec vbr,a4
dc.w $4e7a,$0801 ; movec vbr,d0
;moveq #0,d0
;dc.l $4e7b0002 ;movec d0,cacr #disable all cache
;dc.l $f4784e71 ;cpusha dc #Flush dirty cache lines
;dc.l $4e7b0808 ;!! movec d0,pcr #>=68060 only!
rte
*****************************************************************************
* Kills the system.
*
* MUST RUN FW_GetSysDetails first!
*
* IN:
* OUT:
* TRASHED: d0-d1/a0-a1
*****************************************************************************
xdef FW_KillSys
FW_KillSys:
movem.l d2-d7/a2-a6,-(sp) ;save
move.l (_ExecBase).w,a6
jsr _LVOForbid(a6) ;Disable multitasking
lea FW_Vars(pc),a5 ;Storage
lea FW_GfxName(pc),a1 ;open graphics.library
jsr _LVOOldOpenLibrary(a6) ;open
move.l d0,a6
move.l a6,FW_GFXBASE(a5) ;Save adr
move.l gb_ActiView(a6),FW_GFXVIEW(a5) ;save active view
ifne FW_TOPAZ8
lea FW_Topaz_TextAttr(pc),a0
move.l #FW_TopazName,ta_Name(a0)
jsr _LVOOpenFont(a6) ;I:a0, O:d0 (TextFont)
move.l d0,FW_Topaz_TextFont_Ptr
endif
jsr _LVOOwnBlitter(a6) ;Take over blitter
jsr _LVOWaitBlit(a6) ;and let it finish
sub.l a1,a1 ;null view
jsr _LVOLoadView(a6) ;reset display
jsr _LVOWaitTOF(a6) ;twice to let interlaced displays stop
jsr _LVOWaitTOF(a6)
;Stop interrupts before waiting for TOF and killing system as vblank interrupt
;processing may mean we get sprite corruption if interrupt takes too long. Toni Wilen
;suggested its safer to store the custom registers after interrupts disabled.
lea _custom,a6
move.w intenar(a6),FW_SYSINTENA(a5) ;save
move.w #$7fff,d0
move.w d0,intena(a6) ;Disable interrupts
move.w d0,intreq(a6)
bsr FW_WaitTOF_A6 ;T:None
move.w dmaconr(a6),FW_SYSDMACON(a5) ;save
move.w adkconr(a6),FW_SYSADKCON(a5)
move.w d0,dmacon(a6) ;disable
move.w d0,adkcon(a6)
;Save irq handlers
move.l FW_VBRPTR(a5),a0
movem.l VEC_LEVEL1(a0),d0-d5 ;save lev1-6 irqs
movem.l d0-d5,FW_VEC_LEVEL1(a5)
;Exception handlers
ifne FW_EXCEPTION_HANDLER
move.l VEC_BUSERR(a0),FW_VEC_BUSERR(a5)
move.l VEC_ADDRERR(a0),FW_VEC_ADDRERR(a5)
move.l VEC_ILLEGAL(a0),FW_VEC_ILLEGAL(a5)
move.l VEC_ZERODIV(a0),FW_VEC_ZERODIV(a5)
lea FW_ExceptionHandler(pc),a1
move.l a1,VEC_BUSERR(a0)
move.l a1,VEC_ADDRERR(a0)
move.l a1,VEC_ILLEGAL(a0)
move.l a1,VEC_ZERODIV(a0)
endif
;Write base CL/IRQ and then wait a frame to be sure it's active, then safe to turn on CDANG
;without risk of blitter being triggered (seems to happen on real a1200). When copper dma is turned
;on the last STROBED list from cop1lch immediately starts running. We need to be sure that is our
;new list.
bsr FW_SetBaseCopperIrq_A6
bsr FW_WaitTOF_A6 ;T:None
;move.w #$0002,copcon(a6) ;Enable copper controlled blits, be sure custom CL installed first
;move.w #$8000,vposw(a6) ;Ensure using long frame
movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
* Restores the system.
*
* IN:
* OUT:
* TRASHED: d0-d1/a0-a1
*****************************************************************************
xdef FW_RestoreSys
FW_RestoreSys:
movem.l d2-d7/a2-a6,-(sp) ;save
lea _custom,a6
lea FW_Vars(pc),a5 ;Storage
;Fix up set/clr bit
move.w #$8000,d0
or.w d0,FW_SYSADKCON(a5)
or.w d0,FW_SYSDMACON(a5)
or.w d0,FW_SYSINTENA(a5)
;Stop interrupts before waiting for EOF as slow music players running
;in the lev3 irq can cause line position checks to never finish.
subq.w #1,d0 ;$8000 to $7fff
move.w d0,intena(a6)
move.w d0,intreq(a6)
;Wait for any blits and TOF to safely disable sprite DMA
bsr FW_WaitBlit_A6 ;I:a6, T:None
bsr FW_WaitTOF_A6 ;I:a6, T:None
;Disable everything else
;move.w #$7fff,d0 ;d0 is already $7fff
move.w d0,dmacon(a6)
move.w d0,adkcon(a6)
;Restore irq handlers
move.l FW_VBRPTR(a5),a0
movem.l FW_VEC_LEVEL1(a5),d0-d5
movem.l d0-d5,VEC_LEVEL1(a0)
;Restore exception handlers
ifne FW_EXCEPTION_HANDLER
move.l FW_VEC_BUSERR(a5),VEC_BUSERR(a0)
move.l FW_VEC_ADDRERR(a5),VEC_ADDRERR(a0)
move.l FW_VEC_ILLEGAL(a5),VEC_ILLEGAL(a0)
move.l FW_VEC_ZERODIV(a5),VEC_ZERODIV(a0)
endif
;Write the system copper lists first. But gotcha here is that this new list will only run at next
;vblank so the sprite dma disable code in our framework/previous CL is at risk of running when we turn DMA back
;on which would then cause issues with OS sprites. Easiest solution stobe copjmp1 before
;renabling DMA.
move.l FW_GFXBASE(a5),a4 ;gfx library
move.l gb_copinit(a4),cop1lch(a6) ;Startup copper list in cop1lc
move.l gb_LOFlist(a4),cop2lch(a6) ;Long frame copper list in cop2lc
move.w d0,copjmp1(a6)
move.w FW_SYSINTENA(a5),intena(a6)
move.w FW_SYSDMACON(a5),dmacon(a6)
move.w FW_SYSADKCON(a5),adkcon(a6)
move.l a4,a6 ;gfx base
move.l FW_GFXVIEW(a5),a1 ;get old view
jsr _LVOLoadView(a6) ;activate view
jsr _LVODisownBlitter(a6) ;free the blitter
;Apparently, topaz and gfx library are always open, so can save some code here by not trying to close
ifne FW_TOPAZ8
move.l FW_Topaz_TextFont_Ptr(pc),a1
jsr _LVOCloseFont(a6) ;I:a1 (TextFont)
endif
move.l a6,a1 ;gfx base
move.l (_ExecBase).w,a6 ;DO NOT COMMENT OUT - NEEDED FOR PERMIT()
jsr _LVOCloseLibrary(a6) ;close, not really needed as GFX is always open
jsr _LVOPermit(a6) ;multitask on
movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
* Init music routines that can be done after system killed. P61 etc
* IN:
* OUT:
* TRASHED: d0-d1/a0-a1
*****************************************************************************
xdef FW_MusicInit
FW_MusicInit:
movem.l d2-d7/a2-a6,-(sp) ;save
ifeq FW_MUSIC_TYPE-1 ;p61
clr.b FW_Vars+FW_MUSICPLAYING
clr.w P61_Play ;Default is not playing until we enable
move.l FW_Vars+FW_VBRPTR(pc),P61_VBR
lea P61Module,a0
lea P61Samples,a1
sub.l a2,a2 ;Packed samples address
moveq #1,d0 ;PAL
jsr P61_Init
st FW_Vars+FW_MUSICINITIALISED
endif ;p61
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay (with optional amigaklag)
;Amigaklang samples precalc
ifne FW_MUSIC_AMIGAKLANG
;a0: startaddress where to render the samples to (chipram, see amigaklanggui for size)
;a1: startaddress of a temporary render buffer (65536 bytes, public ram)
;a2: startaddress of external samples (if used. Include Ismp.raw, can be public ram)
;a4: address where the synth puts the rendering progress (e.g. for a progressbar, a long in public ram)
lea PHXPT_Samples,a0
lea FW_Public_Buffer_1_End-65536,a1 ;needs 64KB buffer
lea AMIGAKLANG_Isamp,a2
lea AMIGAKLANG_Progress,a4
jsr AMIGAKLANG_Init
endif
clr.b FW_Vars+FW_MUSICPLAYING
clr.b _mt_Enable ;Starts paused
;_mt_install_cia(a6=CUSTOM, a0=VectorBase, d0=PALflag.b)
lea _custom,a6
move.l FW_Vars+FW_VBRPTR,a0 ;VBR
moveq #1,d0 ;PAL
jsr _mt_install_cia ;I:a0/a6/d0 T:d0-d7/a0-a5
;_mt_init(a6=CUSTOM, a0=TrackerModule, a1=Samples|NULL, d0=InitialSongPos.b)
lea PHXPT_Module,a0
lea PHXPT_Samples,a1
moveq #0,d0
jsr _mt_init
st FW_Vars+FW_MUSICINITIALISED
endif ;PHX_PTReplay
ifeq FW_MUSIC_TYPE-3 ;prt
clr.b FW_Vars+FW_MUSICPLAYING
lea prtPlayer,a6
lea prtPlayerBuf,a0
lea prtSongBuf,a1
lea prtSong,a2
add.l (prtSongInit,a6),a6
jsr (a6) ; songInit
lea prtPlayer,a6
lea prtPlayerBuf,a0
lea prtChipBuf,a1
lea prtSongBuf,a2
add.l (prtPlayerInit,a6),a6
jsr (a6) ; playerInit
st FW_Vars+FW_MUSICINITIALISED
endif ;prt
movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
* Starts playing music if not started yet or has been paused.
* IN:
* OUT:
* TRASHED: d0-a1/a0-a1
*****************************************************************************
xdef FW_MusicPlay
FW_MusicPlay:
;movem.l d2-d7/a2-a6,-(sp) ;save
ifeq FW_MUSIC_TYPE-1 ;p61
move.w #1,P61_Play ;Default is not playing until we enable
st FW_Vars+FW_MUSICPLAYING
endif ;p61
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay (with optional amigaklag)
move.b #1,_mt_Enable ;Start playing
st FW_Vars+FW_MUSICPLAYING
endif ;PHX_PTReplay
ifeq FW_MUSIC_TYPE-3 ;prt
st FW_Vars+FW_MUSICPLAYING
endif ;prt
;movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
* Starts playing music if not started yet or has been paused.
* IN:
* OUT:
* TRASHED: d0-a1/a0-a1
*****************************************************************************
xdef FW_MusicPause
FW_MusicPause:
;movem.l d2-d7/a2-a6,-(sp) ;save
ifeq FW_MUSIC_TYPE-1 ;p61
clr.w P61_Play ;Stop playing
clr.b FW_Vars+FW_MUSICPLAYING
endif ;p61
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay (with optional amigaklag)
clr.b _mt_Enable ;Stop playing
clr.b FW_Vars+FW_MUSICPLAYING
endif ;PHX_PTReplay
ifeq FW_MUSIC_TYPE-3 ;prt
clr.b FW_Vars+FW_MUSICPLAYING
endif ;prt
;movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
* Gets a bit mask for new notes on a channel for VU meters.
* 1=chan1, 2=chan2, 4=chan3, 8=chan4
* E8x values are shifted 4 bits so we have bits 0-3 for new notes, and bits
* 4-7 being the E8x value (shifted 4 bits)
*
* Note: Visualiser functions have to be enabled in P61/PHXPtplayer for this to assemble.
*
* IN:
* OUT: d0.w mask value
* TRASHED: d0-d1/a0
*****************************************************************************
xdef FW_MusicGetSyncVal
FW_MusicGetSyncVal:
ifeq FW_MUSIC_TYPE-1 ;p61
; Bits 0-3 are just the VUmeter
moveq #0,d0
; These are counters since last trigger, so 0 is just triggered
lea P61_visuctr0,a0
.vu1:
tst.w (a0)+
bne.s .vu2
addq.w #1,d0
.vu2:
tst.w (a0)+
bne.s .vu3
addq.w #2,d0
.vu3:
tst.w (a0)+
bne.s .vu4
addq.w #4,d0
.vu4:
tst.w (a0)+
bne.s .vuwrite
addq.w #8,d0
.vuwrite:
;bits 4-7 is the E8x value shifted << 4
move.w P61_E8,d1
clr.w P61_E8
lsl.w #4,d1
or.w d1,d0
endif ;p61
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay
; Bits 0-3 are just the VUmeter
moveq #0,d0
move.b _mt_VUMeter,d0
clr.b _mt_VUMeter
;bits 4-7 is the E8x value shifted << 4
moveq #0,d1
move.b _mt_E8Trigger,d1
clr.b _mt_E8Trigger
lsl.b #4,d1
or.b d1,d0
endif ;PHX_PTReplay
rts
*****************************************************************************
* Stop music routines that can be done after system killed. P61 etc
* Runs any cleanup as well.
* IN:
* OUT:
* TRASHED: d0-a1/a0-a1
*****************************************************************************
xdef FW_MusicEnd
FW_MusicEnd:
movem.l d2-d7/a2-a6,-(sp) ;save
; Finish music
ifeq FW_MUSIC_TYPE-1 ;p61
jsr P61_End
clr.b FW_Vars+FW_MUSICPLAYING
clr.b FW_Vars+FW_MUSICINITIALISED
endif
ifeq FW_MUSIC_TYPE-2 ;PHX_PTReplay
lea _custom,a6
jsr _mt_end
jsr _mt_remove_cia
clr.b FW_Vars+FW_MUSICPLAYING
clr.b FW_Vars+FW_MUSICINITIALISED
endif
ifeq FW_MUSIC_TYPE-3 ;prt
clr.b FW_Vars+FW_MUSICPLAYING
clr.b FW_Vars+FW_MUSICINITIALISED
endif
movem.l (sp)+,d2-d7/a2-a6 ;restore
rts
*****************************************************************************
; Normal 320x320 starting at line 44($2c) means EOF would be 44+256 = 300
; Overscan 352x272 starting at line 36($24) means EOF would be 36+272 = 308
; For interlaced PAL:
; vblank begins at vpos 312 hpos 1 and ends at vpos 25 hpos 1
; vblank begins at vpos 311 hpos 1 and ends at vpos 25 hpos 1
; So safest last visible line to wait for before vblank interrupt would be 310
; I like to start clearing the screen as soon as possible after the last visible line
; which means that the blitter is usually clearing already by the time the vblank happens
; and then there is a nice mix of CPU code happening while clearing.
;
xdef FW_WaitEOFExact_A6
FW_WaitEOFExact_A6: ;wait for end of frame, IN: a6=_custom, trashes d0
.lo: move.l vposr(a6),d0
andi.l #$1ff00,d0 ;16
cmpi.l #303<<8,d0 ;14
bne.s .lo ;wait until it matches (eq)
rts
xdef FW_WaitEOF_A6
FW_WaitEOF_A6: ;wait for end of frame or greater, IN: a6=_custom, trashes d0
.lo: move.l vposr(a6),d0
lsr.l #1,d0 ;10
lsr.w #7,d0 ;20
cmpi.w #303,d0
blt.s .lo ;EOF or later
rts
xdef FW_WaitRasterExact_A6
FW_WaitRasterExact_A6:
.lo: move.l vposr(a6),d1 ;Wait for scanline. IN: A6=custom, d0=scanline, trashes d1
lsr.l #1,d1
lsr.w #7,d1
cmp.w d0,d1
bne.s .lo ;wait until it matches (eq)
rts
xdef FW_WaitRaster_A6
FW_WaitRaster_A6:
.lo: move.l vposr(a6),d1 ;Wait for scanline or greater. IN: A6=custom, d0=scanline, trashes d1
lsr.l #1,d1
lsr.w #7,d1
cmp.w d0,d1
blt.s .lo ;wait until it matches or later
rts
xdef FW_WaitTOF
FW_WaitTOF:
.vsync:
btst #0,_custom+vposr+1
beq.b .vsync ;wait while in 0-255 range if bit is 0
.vsync2:
btst #0,_custom+vposr+1 ;wait while in 256+ range
bne.b .vsync2
;just started new frame, and will only really return after any VBL processing
;because the code will be blocked during that.
rts
xdef FW_WaitTOF_A6
FW_WaitTOF_A6:
.vsync:
btst #0,vposr+1(a6)
beq.b .vsync ;wait while in 0-255 range if bit is 0
.vsync2:
btst #0,vposr+1(a6) ;wait while in 256+ range
bne.b .vsync2
;just started new frame, and will only really return after any VBL processing
;because the code will be blocked during that.
rts
*****************************************************************************
xdef FW_WaitBlit_A6
FW_WaitBlit_A6: ;wait until blitter is finished, IN: A5=_custom
tst.w dmaconr(a6) ;for compatibility with A1000
.loop: btst.b #6,dmaconr(a6)
bne.s .loop
rts
*****************************************************************************
* Clears a buffer using the Blitter and CPU.
* Adapted from source from Photon/Scoopex.
* Max 256KB
* IN: a6, _custom/$dff000
* a0 (buffer to clear) (even address)
* d0.w, number of words to clear
* d1.w, number of bytes to clear with blitter (tune to suit)
* 0=all CPU, 65535=99% blitter
* OUT: a0, next address after the cleared buffer
* a6, _custom
* TRASHED: d0-d7/a0-a4
*****************************************************************************
FW_ClearBuffer_BlitCPU_BlkSize equ 2 ;movem-repetitions, 2*13.l = 104 bytes per loop
xdef FW_ClearBuffer_BlitCPU_A6
FW_ClearBuffer_BlitCPU_A6:
move.l a5,-(sp) ;save
moveq #0,d2
move.w d0,d2
mulu d1,d0 ;blit part of the clr, 34250/65536 for 6bpdma
swap d0
move.l d2,d1
and.w #-64,d0 ;bltsize
beq.s .skipb
sub.w d0,d1 ;rest (words)
;Start the blit
WAITBLIT_NASTY_A6
move.l #$01000000,bltcon0(a6) ;Clear
clr.w bltdmod(a6)
move.l a0,bltdpth(a6)
move.w d0,bltsize(a6)
.skipb:
; Work out how many movem loops we need
divu #13*2*FW_ClearBuffer_BlitCPU_BlkSize,d1
.cpu:
add.l d2,d2 ;words to bytes
add.l d2,a0 ;find end of buffer for pre-decrement
movem.l FW_ClearBuffer_Zero13,d0/d2-d7/a1-a6 ;zeroes, 13 regs
subq.w #1,d1 ;-1 for dbf
bmi.s .nor2
.mvml:
REPT FW_ClearBuffer_BlitCPU_BlkSize
movem.l d0/d2-d7/a1-a6,-(a0) ;13 regs (52 bytes)
ENDR
dbf d1,.mvml
.nor2:
;Clear any remaining in single 13 long blocks
swap d1 ;rest
bra.s .cont1
.bigl:
movem.l d0/d2-d7/a1-a6,-(a0) ;13 regs
.cont1:
sub.w #13*2,d1 ;13 regs
bpl.s .bigl
add.w #13*2,d1 ;13 regs
;Clear final remaining in single long/word loop
lsr.w #1,d1
bcc.s .now
move.w d0,-(a0)
.now: subq.w #1,d1
bmi.s .nor1
.l: move.l d0,-(a0)
dbf d1,.l
.nor1:
lea _custom,a6 ;restore a6
move.l (sp)+,a5
rts
*****************************************************************************
* Clears a buffer using the CPU.
* Adapted from source from Photon/Scoopex.
* Max 256KB
* IN: a0 (buffer to clear) (even address)
* d0.w, number of words to clear
* OUT: a0, next address after the cleared buffer
* TRASHED: d0-d7/a0-a4
*****************************************************************************
xdef FW_ClearBuffer_CPU
FW_ClearBuffer_CPU:
move.l a5,-(sp) ;save
move.l a6,-(sp)
moveq #0,d2 ;clear top of d2
move.w d0,d2 ;d2=words to clr (cleared top)
move.l d2,d1 ;d1=words to clr (cleared top)
; Work out how many movem loops we need (how many words per loop)
divu #13*2*FW_ClearBuffer_BlitCPU_BlkSize,d1
.cpu:
add.l d2,d2 ;words to bytes
add.l d2,a0 ;find end of buffer for pre-decrement
movem.l FW_ClearBuffer_Zero13,d0/d2-d7/a1-a6 ;zeroes, 13 regs, d0 already 0
subq.w #1,d1 ;-1 for dbf
bmi.s .nor2
.mvml:
REPT FW_ClearBuffer_BlitCPU_BlkSize
movem.l d0/d2-d7/a1-a6,-(a0) ;13 regs (52 bytes)
ENDR
dbf d1,.mvml
.nor2:
;Clear any remaining in single 13 long blocks
swap d1 ;rest
bra.s .cont1
.bigl:
movem.l d0/d2-d7/a1-a6,-(a0) ;13 regs
.cont1:
sub.w #13*2,d1 ;13 regs
bpl.s .bigl
add.w #13*2,d1 ;13 regs
;Clear final remaining in single long/word loop
lsr.w #1,d1
bcc.s .now
move.w d0,-(a0)
.now: subq.w #1,d1
bmi.s .nor1
.l: move.l d0,-(a0)
dbf d1,.l
.nor1:
move.l (sp)+,a6 ;restore
move.l (sp)+,a5
rts
*****************************************************************************
* Copies a buffer using the CPU.
* Max 256KB
* IN: a0 (source) (even address)
* a1 (dest)
* d0.w, number of words to copy
* OUT:
* TRASHED: d0-d7/a0-a2
*****************************************************************************
xdef FW_CopyBuffer_CPU
FW_CopyBuffer_CPU:
FW_CopyBuffer_BlkSize equ 4 ;movem-repetitions, 4*8.l = 128 bytes per loop
;Copying 8 longs at a time
ext.l d0 ;clear top
divu.w #8*2*FW_CopyBuffer_BlkSize,d0
subq.w #1,d0 ;dbf
bmi.s .nor2
.copy:
REPT FW_CopyBuffer_BlkSize
movem.l (a0)+,d1-d7/a2
movem.l d1-d7/a2,(a1)
lea 8*4(a1),a1
ENDR
dbf d0,.copy
.nor2:
;Clear any remaining (get remainder from highword)
swap d0
;Copy final remaining in single long/word loop
lsr.w #1,d0
bcc.s .now
move.w (a0)+,(a1)+
.now: subq.w #1,d0
bmi.s .nor1
.l: move.l (a0)+,(a1)+
dbf d0,.l
.nor1:
rts
*****************************************************************************
* Sets all colors to $000 (for startup or non-copper list routines)
* IN:
* OUT:
* TRASHED: d0-d1/a0
*****************************************************************************
xdef FW_SetColorsBlack_A6
FW_SetColorsBlack_A6:
lea color00(a6),a0
moveq #32-1,d0
moveq #0,d1
.loop:
move.w d1,(a0)+
dbf d0,.loop
rts
*****************************************************************************
* Sets Lev1 IRQ safely on 68000+. Sets it immediately so handle any
* timing/waiting externally.
* IN: a0, new Irq
* OUT:
* TRASHED: a1
*****************************************************************************
xdef FW_SetLev1Irq
FW_SetLev1Irq:
move.l FW_Vars+FW_VBRPTR(pc),a1
move.l a0,VEC_LEVEL1(a1)
rts
*****************************************************************************
* Sets Lev3 IRQ safely on 68000+. Sets it immediately so handle any
* timing/waiting externally.
* IN: a0, new Irq
* OUT:
* TRASHED: a1
*****************************************************************************
xdef FW_SetLev3Irq
FW_SetLev3Irq:
move.l FW_Vars+FW_VBRPTR(pc),a1
move.l a0,VEC_LEVEL3(a1)
rts
*****************************************************************************
* Sets the copper list and default IRQ
*
* IN: a6, _custom
* a0, ptr to new copperlist
* a1, ptr to lev3 irq
* OUT:
* TRASHED: a0
*****************************************************************************
xdef FW_SetCopperIrq_A6
FW_SetCopperIrq_A6:
move.l a0,cop1lch(a6)
move.l FW_Vars+FW_VBRPTR(pc),a0
ifne FW_FRAME_IRQ_LEV3
move.l a1,VEC_LEVEL3(a0)
endif
ifne FW_FRAME_IRQ_LEV1
move.l a1,VEC_LEVEL1(a0)
endif
rts
*****************************************************************************
* Sets the base CL.
* Doesn't touch Dma so set separately.
* IN: a6, _custom
* OUT:
* TRASHED: a0
*****************************************************************************
xdef FW_SetBaseCopper_A6
FW_SetBaseCopper_A6:
move.l #FW_CL,cop1lch(a6)
rts
*****************************************************************************
* Sets the base CL and Lev3 Irq.
* Doesn't touch Dma so set separately.
* IN: a6, _custom
* OUT:
* TRASHED: a0
*****************************************************************************
xdef FW_SetBaseCopperIrq_A6
FW_SetBaseCopperIrq_A6:
bsr.s FW_SetBaseCopper_A6
bsr.s FW_SetBaseIrq
rts
*****************************************************************************
* Sets Lev3 IRQ safely on 68000+. Sets to FW default (just music player)
* IN:
* OUT:
* TRASHED: a0
*****************************************************************************
xdef FW_SetBaseIrq
FW_SetBaseIrq:
move.l FW_Vars+FW_VBRPTR(pc),a0
ifne FW_FRAME_IRQ_LEV3
move.l #FW_IrqHandlerLev3,VEC_LEVEL3(a0)
endif
ifne FW_FRAME_IRQ_LEV1
move.l #FW_IrqHandlerLev1,VEC_LEVEL1(a0)
endif
rts
*****************************************************************************
* Sets the copper list and enables DMA (Blitter,Copper,Bitplane)
* Use after exiting a subpart to ensure blank screen.
* IN: a6, _custom
* OUT:
* TRASHED: d0/a0-a1
*****************************************************************************
xdef FW_SetBaseCopperIrqDma_A6
FW_SetBaseCopperIrqDma_A6:
;move.w #INTF_INTEN,intena(a6) ;Interrupts off while we switch
;bsr FW_WaitBlit_A6 ;Finish off blits
;Can't use a EOF vposr check here as music player may run over the frame
;Also can't use framesync counter as irq may not be running yet.
;Instead just check for going into the 256+ (bit V8 is bit 0 of vposr)
;territory and then back to 0-255.
;this usually handles IRQs that are waiting for line 0, or 256+
;without clashing with long running music players
;bsr FW_WaitTOF
move.l FW_Vars+FW_VBRPTR(pc),a0
move.l #FW_CL,cop1lch(a6)
; Enable DMA and interrupts
BaseDMA set DMAF_SETCLR|DMAF_MASTER|DMAF_RASTER|DMAF_COPPER|DMAF_BLITTER
ifeq FW_FRAME_IRQ_TYPE-FW_FRAME_IRQ_NONE
BaseINT set INTF_SETCLR|INTF_INTEN
endif
ifeq FW_FRAME_IRQ_TYPE-FW_FRAME_IRQ_COPER
BaseINT set INTF_SETCLR|INTF_INTEN|INTF_COPER
move.l #FW_IrqHandlerLev3,VEC_LEVEL3(a0)
endif
ifeq FW_FRAME_IRQ_TYPE-FW_FRAME_IRQ_VERTB
BaseINT set INTF_SETCLR|INTF_INTEN|INTF_VERTB
move.l #FW_IrqHandlerLev3,VEC_LEVEL3(a0)
endif
ifeq FW_FRAME_IRQ_TYPE-FW_FRAME_IRQ_SOFTINT
BaseINT set INTF_SETCLR|INTF_INTEN|INTF_SOFTINT
move.l #FW_IrqHandlerLev1,VEC_LEVEL1(a0)
endif
move.w #BaseDMA,dmacon(a6)
move.w #BaseINT,intena(a6)
;move.w #0,COPJMP1(a6)
rts