-
Notifications
You must be signed in to change notification settings - Fork 54
/
Report.pm
300 lines (221 loc) · 6.51 KB
/
Report.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
package C4::Report;
# Copyright 2009 Katipo Communications
#
# This file is part of Koha.
#
# Koha is free software; you can redistribute it and/or modify it under the
# terms of the GNU General Public License as published by the Free Software
# Foundation; either version 2 of the License, or (at your option) any later
# version.
#
# Koha is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
# A PARTICULAR PURPOSE. See the GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License along with
# Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
# Suite 330, Boston, MA 02111-1307 USA
use strict;
use warnings;
use C4::Context;
use C4::Taggable ':mixin';
use C4::Dates 'format_date';
use C4::Members;
=head1 NAME
C4::Report - an object representing a row in the C<saved_sql> table
=head1 SYNOPSIS
Using a report:
use C4::Report;
my $report = C4::Report->find(1);
print $report->name, "\n";
print $report->savedsql, "\n";
$report->notes('run this daily');
$report->add_tag('daily');
$report->update;
Find all reports tagged with 'daily' and 'circulation':
my @reports = C4::Report->search_by_tags('daily', 'circulation');
=head1 DESCRIPTION
This module provides an OO interface to SQL reports. It also mixes in
L<C4::Taggable> to add tagging functionality.
=head1 API
=head2 new(\%attr)
This method constructs a C4::Report object in memory.
=cut
sub new {
my ($class, $attr, $_options) = @_;
$_options ||= {};
$attr ||= {};
my $options = { format_date => 1, tags => 1, borrower => 1, %$_options };
my $self = bless { %$attr } => $class;
$self->reformat_date if ($options->{format_date});
$self->load_tags if ($options->{tags});
$self->load_borrower if ($options->{borrower});
return $self
}
=head2 table
"saved_sql"
=head2 resource_id_field
"saved_sql_id"
=head2 primary_key
"id"
=cut
sub table { "saved_sql" }
sub primary_key { "id" }
sub foreign_key_for_xtags { "saved_sql_id" }
=head2 find($id)
This method will construct a C4::Report object using data from the saved_sql table.
C4::Report->find(1)
=cut
sub find {
my ($class, $id) = @_;
my $dbh = C4::Context->dbh;
my $sql = "SELECT * FROM saved_sql WHERE id = ?";
my $rs = $dbh->selectall_arrayref($sql, { Slice => {} }, $id);
my $report = $rs->[0];
my $object = $class->new($report);
return $object;
}
=head2 id
=head2 borrowernumber
=head2 date_created
=head2 last_modified
=head2 savedsql
=head2 last_run
=head2 report_name
=head2 type
=head2 notes
All of the above represent columns in the saved_sql table.
=cut
# attributes that directly map to what's in the saved_sql table
my @attributes = qw(
borrowernumber
date_created
last_modified
savedsql
last_run
report_name
type
notes
);
=head2 borrower
This is a hashref representing the koha user that created this report.
=head2 borrowersurname
Report creator's surname.
=head2 borrowerfirstname
Report creator's first name.
=head2 last_modified_f
This is $self->last_modified with format_date() applied to it.
=head2 date_created_f
This is $self->date_created with format_date() applied to it.
=cut
# aside from id, attributes that are just in memory for convenience
my @extra = qw(
id
borrower
borrowersurname
borrowerfirstname
date_created_f
last_modified_f
);
sub _accessor {
my $attr = shift;
sub {
my ($self, $value) = @_;
if ($value) {
$self->{$attr} = $value;
} else {
$self->{$attr};
}
}
}
{
no strict 'refs';
no warnings 'once';
*{$_} = _accessor($_) for (@attributes, @extra);
}
my $attributes_sql = join(', ' => map { "$_ = ?" } @attributes);
sub attributes_sql { $attributes_sql }
=head2 update
This method updates the database with the current state of the C4::Report object.
$report->update;
=cut
sub update {
my ($self) = @_;
my @x = localtime;
my $now = sprintf('%d-%02d-%02d %02d:%02d:%02d', $x[5]+1900, $x[4]+1, $x[3], $x[2], $x[1], $x[0]);
my $dbh = C4::Context->dbh;
my $sql = "UPDATE saved_sql SET $attributes_sql WHERE id = ?";
$self->last_modified($now);
$dbh->do($sql, undef, (map { $self->$_ } @attributes), $self->id);
}
=head2 delete
When called as an instance method, the current object will be deleted.
$report->delete;
When called as a class method, you can provide the id of a report to delete.
C4::Report->delete(5);
=cut
sub delete {
my ($proto, $id) = @_;
if ($id) {
return _delete_by_id($id);
} else {
if (ref $proto) {
my $self = $proto;
return _delete_by_id($self->id);
} else {
warn "When delete is called as a class method, an id needs to be provided.";
return undef;
}
}
}
sub _delete_by_id {
my $id = shift;
my $dbh = C4::Context->dbh;
$dbh->do("DELETE FROM saved_sql WHERE id = ?", {}, $id);
}
sub reformat_date {
my ($self) = @_;
$self->date_created_f(format_date($self->date_created));
$self->last_modified_f(format_date($self->last_modified));
}
sub load_tags {
my ($self) = @_;
$self->{tags} = [ map { { name => $_ } } $self->tags ];
}
sub load_borrower {
my ($self) = @_;
if ($self->borrowernumber) {
$self->borrower(GetMember($self->borrowernumber, 'borrowernumber'));
if ($self->borrower) {
$self->borrowerfirstname($self->borrower->{firstname});
$self->borrowersurname($self->borrower->{surname});
}
}
}
sub all {
my ($class, $_options) = @_;
$_options ||= {};
my $options = { order_by => 'id', format_date => 1, tags => 1, borrower => 1, %$_options };
my $dbh = C4::Context->dbh;
my $select = "SELECT * FROM saved_sql ";
if ($options) {
if (exists $options->{order_by}) {
$select .= "ORDER BY $options->{order_by}\n";
}
if (exists $options->{limit}) {
$select .= "LIMIT $options->{limit}\n";
}
if (exists $options->{offset}) {
$select .= "OFFSET $options->{offset}\n";
}
}
my $rs = $dbh->selectall_arrayref($select, { Slice => {} });
return map {
$class->new($_, $options);
} @$rs;
}
1;
__END__
=head1 SEE ALSO
L<C4::Taggable>, L<C4::Reports>, L<C4::Reports::Guided>
=cut