New Graph v5.0+ broke my code

[Gruski]

I had this but now many classes are no longer found in API. What is the substitution to get same behavior?

    Private Shared ReadOnly Property Client As GraphServiceClient
        Get
            If _client Is Nothing Then
                _client = New GraphServiceClient(New DelegateAuthenticationProvider(AddressOf SetRequestHeaderAuth))
            End If
            Return _client
        End Get
    End Property

    Private Shared Async Function SetRequestHeaderAuth(request As HttpRequestMessage) As Task

        'consideres expired 5 min before actual expiration so expiration can't accidentally
        'occur between this check and identity server's check for expiration 
        If _auth Is Nothing OrElse DateTimeOffset.UtcNow > _auth.ExpiresOn.AddMinutes(-5) Then
            Dim app = ConfidentialClientApplicationBuilder _
                .Create(Secrets.msClientId) _
                .WithTenantId(Secrets.msTenantId) _
                .WithClientSecret(Secrets.msClientSecret) _
                .Build()

            Dim scopes = {"https://graph.microsoft.com/.default"}

            _auth = Await app.AcquireTokenForClient(scopes).ExecuteAsync()
        End If
        request.Headers.Authorization = New AuthenticationHeaderValue("bearer", _auth.AccessToken)

    End Function
    

[andrueastman]

Thanks for raising this @Gruski

Any chance the docs here are helpful? https://github.com/microsoftgraph/msgraph-sdk-dotnet/blob/dev/docs/upgrade-to-v5.md#authentication

[Gruski]

Thanks that helped. Here is the code if someone else needs it.
Not sure why we must implement AllowedHostsValidator if it's never called internally by the API.

Imports Microsoft.Kiota.Abstractions.Authentication
Imports Microsoft.Graph
Imports Microsoft.Identity.Client
Imports System.Threading

Public Class GraphAPI
    'docs: https://github.com/microsoftgraph/msgraph-sdk-dotnet/tree/dev/docs

    Private Shared _client As GraphServiceClient   'shared among all requests

    Public Shared ReadOnly Property Client As GraphServiceClient
        Get
            If _client Is Nothing Then
                Dim authProvider = New BaseBearerTokenAuthenticationProvider(New TokenProvider())
                _client = New GraphServiceClient(authProvider)
            End If
            Return _client
        End Get
    End Property

    Private Class TokenProvider
        Implements IAccessTokenProvider

        Public ReadOnly Property AllowedHostsValidator As AllowedHostsValidator Implements IAccessTokenProvider.AllowedHostsValidator
            Get
                Throw New NotImplementedException()
            End Get
        End Property

        Public Async Function GetAuthorizationTokenAsync(uri As Uri, Optional additionalAuthenticationContext As Dictionary(Of String, Object) = Nothing, Optional cancellationToken As CancellationToken = Nothing) As Task(Of String) Implements IAccessTokenProvider.GetAuthorizationTokenAsync
            Dim app = ConfidentialClientApplicationBuilder _
                .Create(Secrets.msClientId) _
                .WithTenantId(Secrets.msTenantId) _
                .WithClientSecret(Secrets.msClientSecret) _
                .Build()

            Dim scopes = {"https://graph.microsoft.com/.default"}

            Dim authResult = Await app.AcquireTokenForClient(scopes).ExecuteAsync()
            Return authResult.AccessToken
        End Function
    End Class

    'test API call
    Public Shared Async Function GetUser(userEmail As String) As Task(Of Object)
        Dim user = Await Client.Users(userEmail).GetAsync()

        'convert to annonymous object so consumer doesn't need to reference Microsoft.Graph.Models
        Dim jsonString = Newtonsoft.Json.JsonConvert.SerializeObject(user)
        Dim anonUser = Newtonsoft.Json.JsonConvert.DeserializeObject(Of Object)(jsonString)
        Return anonUser
    End Function

End Class

[Gruski]

They also broke sending emails.

Await Client().Users(sender).SendMail(_msg, saveToSent).Request().PostAsync()

is now

Dim reqBody As New SendMailPostRequestBody
reqBody.Message = _msg
reqBody.SaveToSentItems = saveToSent

Await Client.Users(sender).SendMail().PostAsync(reqBody)

This wasn't even documented.