Pillar echo

src/qml/filters/pillar_echo/meta.qml

@@ -0,0 +1,24 @@
+import QtQuick 2.0
+import org.shotcut.qml 1.0
+
+Metadata {
+    type: Metadata.Filter
+    objectName: 'pillarEcho'
+    name: qsTr('Pillar Echo')
+    mlt_service: 'pillar_echo'
+    qml: 'ui.qml'
+    vui: 'vui.qml'
+    keyframes {
+        allowAnimateIn: true
+        allowAnimateOut: true
+        simpleProperties: ['rect']
+        parameters: [
+            Parameter {
+                name: qsTr('Position / Size')
+                property: 'rect'
+                isSimple: true
+                isRectangle: true
+            }
+        ]
+    }
+}

src/qml/filters/pillar_echo/ui.qml

@@ -0,0 +1,259 @@
+/*
+ * Copyright (c) 2020 Meltytech, LLC
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation, either version 3 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+import QtQuick 2.0
+import QtQuick.Controls 1.1
+import QtQuick.Layouts 1.1
+import Shotcut.Controls 1.0
+
+Item {
+    property string rectProperty: 'rect'
+    property rect filterRect
+    property string startValue: '_shotcut:startValue'
+    property string middleValue: '_shotcut:middleValue'
+    property string endValue:  '_shotcut:endValue'
+
+    width: 350
+    height: 180
+
+    Component.onCompleted: {
+        filter.blockSignals = true
+        filter.set(middleValue, Qt.rect(0, 0, profile.width, profile.height))
+        filter.set(startValue, Qt.rect(0, 0, profile.width, profile.height))
+        filter.set(endValue, Qt.rect(0, 0, profile.width, profile.height))
+        if (filter.isNew) {
+            // Add default preset.
+            filter.set(rectProperty,   '25%/25%:50%x50%')
+            filter.set("blur", 4)
+            filter.savePreset(preset.parameters)
+        } else {
+            filter.set(middleValue, filter.getRect(rectProperty, filter.animateIn + 1))
+            if (filter.animateIn > 0)
+                filter.set(startValue, filter.getRect(rectProperty, 0))
+            if (filter.animateOut > 0)
+                filter.set(endValue, filter.getRect(rectProperty, filter.duration - 1))
+        }
+        filter.blockSignals = false
+        setControls()
+        setKeyframedControls()
+        if (filter.isNew)
+            filter.set(rectProperty, filter.getRect(rectProperty))
+    }
+
+    function getPosition() {
+        return Math.max(producer.position - (filter.in - producer.in), 0)
+    }
+
+    function setFilter(position) {
+        if (position !== null) {
+            filter.blockSignals = true
+            if (position <= 0 && filter.animateIn > 0)
+                filter.set(startValue, filterRect)
+            else if (position >= filter.duration - 1 && filter.animateOut > 0)
+                filter.set(endValue, filterRect)
+            else
+                filter.set(middleValue, filterRect)
+            filter.blockSignals = false
+        }
+
+        if (filter.animateIn > 0 || filter.animateOut > 0) {
+            filter.resetProperty(rectProperty)
+            positionKeyframesButton.checked = false
+            if (filter.animateIn > 0) {
+                filter.set(rectProperty, filter.getRect(startValue), 1.0, 0)
+                filter.set(rectProperty, filter.getRect(middleValue), 1.0, filter.animateIn - 1)
+            }
+            if (filter.animateOut > 0) {
+                filter.set(rectProperty, filter.getRect(middleValue), 1.0, filter.duration - filter.animateOut)
+                filter.set(rectProperty, filter.getRect(endValue), 1.0, filter.duration - 1)
+            }
+        } else if (!positionKeyframesButton.checked) {
+            filter.resetProperty(rectProperty)
+            filter.set(rectProperty, filter.getRect(middleValue))
+        } else if (position !== null) {
+            filter.set(rectProperty, filterRect, 1.0, position)
+        }
+    }
+
+    function setControls() {
+        amountSlider.value = filter.get('blur')
+    }
+
+    function setKeyframedControls() {
+        var position = getPosition()
+        var newValue = filter.getRect(rectProperty, position)
+        if (filterRect !== newValue) {
+            filterRect = newValue
+            rectX.text = filterRect.x.toFixed()
+            rectY.text = filterRect.y.toFixed()
+            rectW.text = filterRect.width.toFixed()
+            rectH.text = filterRect.height.toFixed()
+        }
+        var enabled = position <= 0 || (position >= (filter.animateIn - 1) && position <= (filter.duration - filter.animateOut)) || position >= (filter.duration - 1)
+        rectX.enabled = enabled
+        rectY.enabled = enabled
+        rectW.enabled = enabled
+        rectH.enabled = enabled
+    }
+
+    GridLayout {
+        columns: 6
+        anchors.fill: parent
+        anchors.margins: 8
+
+        Label {
+            text: qsTr('Preset')
+            Layout.alignment: Qt.AlignRight
+        }
+        Preset {
+            id: preset
+            parameters: [rectProperty]
+            Layout.columnSpan: 5
+            onBeforePresetLoaded: {
+                filter.resetProperty(rectProperty)
+            }
+            onPresetSelected: {
+                setControls()
+                setKeyframedControls()
+                positionKeyframesButton.checked = filter.keyframeCount(rectProperty) > 0 && filter.animateIn <= 0 && filter.animateOut <= 0
+                filter.blockSignals = true
+                filter.set(middleValue, filter.getRect(rectProperty, filter.animateIn + 1))
+                if (filter.animateIn > 0)
+                    filter.set(startValue, filter.getRect(rectProperty, 0))
+                if (filter.animateOut > 0)
+                    filter.set(endValue, filter.getRect(rectProperty, filter.duration - 1))
+                filter.blockSignals = false
+            }
+        }
+
+        Label {
+            text: qsTr('Position')
+            Layout.alignment: Qt.AlignRight
+        }
+        RowLayout {
+            Layout.columnSpan: 3
+            TextField {
+                id: rectX
+                horizontalAlignment: Qt.AlignRight
+                onEditingFinished: if (filterRect.x !== parseFloat(text)) {
+                    filterRect.x = parseFloat(text)
+                    setFilter(getPosition())
+                }
+            }
+            Label { text: ',' }
+            TextField {
+                id: rectY
+                horizontalAlignment: Qt.AlignRight
+                onEditingFinished: if (filterRect.y !== parseFloat(text)) {
+                    filterRect.y = parseFloat(text)
+                    setFilter(getPosition())
+                }
+            }
+        }
+        UndoButton {
+            onClicked: {
+                rectX.text = rectY.text = 0
+                filterRect.x = filterRect.y = 0
+                setFilter(getPosition())
+            }
+        }
+        KeyframesButton {
+            id: positionKeyframesButton
+            Layout.rowSpan: 2
+            checked: filter.keyframeCount(rectProperty) > 0 && filter.animateIn <= 0 && filter.animateOut <= 0
+            onToggled: {
+                if (checked) {
+                    filter.clearSimpleAnimation(rectProperty)
+                    filter.set(rectProperty, filterRect, 1.0, getPosition())
+                } else {
+                    filter.resetProperty(rectProperty)
+                    filter.set(rectProperty, filterRect)
+                }
+                checked = filter.keyframeCount(rectProperty) > 0 && filter.animateIn <= 0 && filter.animateOut <= 0
+            }
+        }
+
+        Label {
+            text: qsTr('Size')
+            Layout.alignment: Qt.AlignRight
+        }
+        RowLayout {
+            Layout.columnSpan: 3
+            TextField {
+                id: rectW
+                horizontalAlignment: Qt.AlignRight
+                onEditingFinished: if (filterRect.width !== parseFloat(text)) {
+                    filterRect.width = parseFloat(text)
+                    setFilter(getPosition())
+                }
+            }
+            Label { text: 'x' }
+            TextField {
+                id: rectH
+                horizontalAlignment: Qt.AlignRight
+                onEditingFinished: if (filterRect.height !== parseFloat(text)) {
+                    filterRect.height = parseFloat(text)
+                    setFilter(getPosition())
+                }
+            }
+        }
+        UndoButton {
+            onClicked: {
+                rectW.text = profile.width / 10
+                rectH.text = profile.height / 10
+                filterRect.width = profile.width / 10
+                filterRect.height = profile.height / 10
+                setFilter(getPosition())
+            }
+        }
+
+        Label {
+            text: qsTr('Blur')
+            Layout.alignment: Qt.AlignRight
+        }
+        SliderSpinner {
+            id: amountSlider
+            minimumValue: 0
+            maximumValue: 10.0
+            stepSize: .1
+            decimals: 2
+            suffix: ' %'
+            onValueChanged: filter.set("blur", value)
+        }
+        UndoButton {
+            onClicked: amountSlider.value = 20
+        }
+        Item { Layout.fillWidth: true }
+
+
+        Item { Layout.fillHeight: true }
+    }
+
+    Connections {
+        target: filter
+        onChanged: setKeyframedControls()
+        onInChanged: setFilter(null)
+        onOutChanged: setFilter(null)
+        onAnimateInChanged: setFilter(null)
+        onAnimateOutChanged: setFilter(null)
+    }
+
+    Connections {
+        target: producer
+        onPositionChanged: setKeyframedControls()
+    }
+}