Program keeps crashing when I call Firebase.RTDB.get(&firebaseData,"location/")

[jpcaldwell30]

I cannot for the life of me figure out why this keeps causing my program to crash. It's the line listed in the title that causes the crash: Firebase.RTDB.get(&firebaseData,"location/") I am hoping for some help in figuring this out.

Here are the relevant sections of my code:

void getTimerData(){ //request only timer data
  Serial.println("running Get timer data");
  FirebaseData firebaseData;
  Serial.printf("Get free heap size: %d\n\n", system_get_free_heap_size());
  Firebase.RTDB.get(&firebaseData,"location/");
  Serial.println(timerData.dataType());
  Serial.printf("Get free heap size: %d\n\n", system_get_free_heap_size());
}

void streamCallback(FirebaseStream data){ //runs on every change to database.
  Serial.printf("stream path, %s\nevent path, %s\ndata type, %s\nevent type, %s\n\n",
                data.streamPath().c_str(),
                data.dataPath().c_str(),
                data.dataType().c_str(),
                data.eventType().c_str());
  printResult(data); //see addons/RTDBHelper.h
  Serial.println();

  String streamPath = String(data.streamPath());
  String dataPath = String(data.dataPath());
  String key = dataPath.substring(1);

  if (dataPath == String('/')) { //init or reconnect
      if (data.dataType().equals("json") ){
        FirebaseJson *json = data.to<FirebaseJson *>();
        size_t len = json->iteratorBegin();
        FirebaseJson::IteratorValue value;
        for (size_t i = 0; i < len; i++) {
            value = json->valueAt(i);
            //Serial_Printf((const char *)FPSTR("Name: %s, Value: %s\n"), value.key.c_str(), value.value.c_str());
            Serial.println("key: " + String(value.key.c_str()) + ", value: " + String(value.value.c_str()));
            if (value.key.equals("runtime")){
              runtime = value.value.toInt();
              Serial.println("Runtime: " + String(runtime)); //fix why this doesn't print anything
            }
            if (value.key.equals("timer_enabled")) {
              timer_enabled = value.value.c_str();
              Serial.println("Timer Enabled " + String(timer_enabled));
              if (timer_enabled){
                getTimerData();
              }
            }
        }
        json->iteratorEnd();
        json->clear();
      }
      else {
          Serial.println("Somehow, no json data was sent. Got: " + data.to<String>());
      }
    }
}

void streamTimeoutCallback(bool timeout) {
  if (timeout)
    Serial.println("stream timeout, resuming...\n");
  if (!stream.httpConnected())
    Serial.printf("error code: %d, reason: %s\n\n", stream.httpCode(), stream.errorReason().c_str());
  }

void setup() {
  Serial.begin(115200);
  delay(500);
  initWiFi();
  initTime();

  config.api_key = API_KEY;

  // Assign the user sign in credentials
  auth.user.email = USER_EMAIL;
  auth.user.password = USER_PASSWORD;

  // Assign the RTDB URL (required)
  config.database_url = DATABASE_URL;

  Firebase.reconnectWiFi(true);

  // Assign the callback function for the long running token generation task */
  config.token_status_callback = tokenStatusCallback; //see addons/TokenHelper.h

  // Assign the maximum retry of token generation
  config.max_token_generation_retry = 5;

  // Initialize the library with the Firebase authen and config
  Firebase.begin(&config, &auth);

  // Streaming (whenever data changes on a path)
  // Begin stream on a database path --> board1/outputs/digital
  if (!Firebase.RTDB.beginStream(&stream, listenerPath.c_str()))
    Serial.printf("stream begin error, %s\n\n", stream.errorReason().c_str());

  // Assign a calback function to run when it detects changes on the database
  Firebase.RTDB.setStreamCallback(&stream, streamCallback, streamTimeoutCallback);
}

At first, I thought it had something to do with not enough memory, but when I run the program, I get a heap size of Get free heap size: 12336 from the statement right before the database get request which I think is ok for the board I have (Node MCU v1)

[mobizt]

If you see the example code, I wrote at line #77 which you should be aware of and avoid it in your programming logic.

Firebase-ESP-Client/examples/RTDB/DataChangesListener/Callback/Callback.ino

Lines 60 to 80 in 0d89ed4

	void streamCallback(FirebaseStream data)
	{
	Serial.printf("sream path, %s\nevent path, %s\ndata type, %s\nevent type, %s\n\n",
	data.streamPath().c_str(),
	data.dataPath().c_str(),
	data.dataType().c_str(),
	data.eventType().c_str());
	printResult(data); // see addons/RTDBHelper.h
	Serial.println();
	// This is the size of stream payload received (current and max value)
	// Max payload size is the payload size under the stream path since the stream connected
	// and read once and will not update until stream reconnection takes place.
	// This max value will be zero as no payload received in case of ESP8266 which
	// BearSSL reserved Rx buffer size is less than the actual stream payload.
	Serial.printf("Received stream payload size: %d (Max. %d)\n\n", data.payloadLength(), data.maxPayloadLength());
	// Due to limited of stack memory, do not perform any task that used large memory here especially starting connect to server.
	// Just set this flag and check it status later.
	dataChanged = true;
	}

The callback is the same as interrupts that mcu exits from its running sequence instruction with current data stores in stack, calling time consuming task inside callback function can cause nested callback which leads to stack overflow. Any memory consuming task in the callback function can cause stack overflow too.

[mobizt]

The callback function purpose is for event triggering or acknowledgement and exit immediately not for doing something that blocks inside.