-
Notifications
You must be signed in to change notification settings - Fork 48
/
SmartyPants.pm
executable file
·1359 lines (988 loc) · 41.4 KB
/
SmartyPants.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package Text::SmartyPants;
use strict;
use vars qw($VERSION);
$VERSION = "1.3";
# Configurable variables:
my $smartypants_attr = "1";
# 1 => "--" for em-dashes; no en-dash support
# 2 => "---" for em-dashes; "--" for en-dashes
# 3 => "--" for em-dashes; "---" for en-dashes
# See docs for more configuration options.
# Globals:
my $tags_to_skip = qr!<(/?)(?:pre|code|kbd|script)[\s>]!;
sub process {
shift if ( $_[0] eq __PACKAGE__ ); # oops, called in OOP fashion.
# Paramaters:
my $text = shift; # text to be parsed
# value of the smart_quotes="" attribute. Default to 'everything on'
my $attr = shift || '1';
# Options to specify which transformations to make:
my ( $do_quotes, $do_backticks, $do_dashes, $do_ellipses, $do_stupefy );
# should we translate " entities into normal quotes?
my $convert_quot = 0;
# Parse attributes:
# 0 : do nothing
# 1 : set all
# 2 : set all, using old school en- and em- dash shortcuts
# 3 : set all, using inverted old school en and em- dash shortcuts
#
# q : quotes
# b : backtick quotes (``double'' only)
# B : backtick quotes (``double'' and `single')
# d : dashes
# D : old school dashes
# i : inverted old school dashes
# e : ellipses
# w : convert " entities to " for Dreamweaver users
if ( $attr eq "0" ) {
# Do nothing.
return $text;
}
elsif ( $attr eq "1" ) {
# Do everything, turn all options on.
$do_quotes = 1;
$do_backticks = 1;
$do_dashes = 1;
$do_ellipses = 1;
}
elsif ( $attr eq "2" ) {
# Do everything, turn all options on, use old school dash shorthand.
$do_quotes = 1;
$do_backticks = 1;
$do_dashes = 2;
$do_ellipses = 1;
}
elsif ( $attr eq "3" ) {
# Do everything, turn all options on, use inverted old school dash shorthand.
$do_quotes = 1;
$do_backticks = 1;
$do_dashes = 3;
$do_ellipses = 1;
}
elsif ( $attr eq "-1" ) {
# Special "stupefy" mode.
$do_stupefy = 1;
}
else {
my @chars = split( //, $attr );
foreach my $c (@chars) {
if ( $c eq "q" ) { $do_quotes = 1; }
elsif ( $c eq "b" ) { $do_backticks = 1; }
elsif ( $c eq "B" ) { $do_backticks = 2; }
elsif ( $c eq "d" ) { $do_dashes = 1; }
elsif ( $c eq "D" ) { $do_dashes = 2; }
elsif ( $c eq "i" ) { $do_dashes = 3; }
elsif ( $c eq "e" ) { $do_ellipses = 1; }
elsif ( $c eq "w" ) { $convert_quot = 1; }
else {
# Unknown attribute option, ignore.
}
}
}
my $tokens ||= _tokenize($text);
my $result = '';
my $in_pre = 0; # Keep track of when we're inside <pre> or <code> tags.
my $prev_token_last_char = ""; # This is a cheat, used to get some context
# for one-character tokens that consist of
# just a quote char. What we do is remember
# the last character of the previous text
# token, to use as context to curl single-
# character quote tokens correctly.
foreach my $cur_token (@$tokens) {
if ( $cur_token->[0] eq "tag" ) {
# Don't mess with quotes inside tags.
$result .= $cur_token->[1];
if ( $cur_token->[1] =~ m/$tags_to_skip/ ) {
$in_pre = defined $1 && $1 eq '/' ? 0 : 1;
}
}
else {
my $t = $cur_token->[1];
my $last_char =
substr( $t, -1 ); # Remember last char of this token before processing.
if ( !$in_pre ) {
$t = ProcessEscapes($t);
if ($convert_quot) {
$t =~ s/"/"/g;
}
if ($do_dashes) {
$t = EducateDashes($t) if ( $do_dashes == 1 );
$t = EducateDashesOldSchool($t) if ( $do_dashes == 2 );
$t = EducateDashesOldSchoolInverted($t) if ( $do_dashes == 3 );
}
$t = EducateEllipses($t) if $do_ellipses;
# Notes: backticks need to be processed before quotes.
if ($do_backticks) {
$t = EducateBackticks($t);
$t = EducateSingleBackticks($t) if ( $do_backticks == 2 );
}
if ($do_quotes) {
if ( $t eq q/'/ ) {
# Special case: single-character ' token
if ( $prev_token_last_char =~ m/\S/ ) {
$t = "’";
}
else {
$t = "‘";
}
}
elsif ( $t eq q/"/ ) {
# Special case: single-character " token
if ( $prev_token_last_char =~ m/\S/ ) {
$t = "”";
}
else {
$t = "“";
}
}
else {
# Normal case:
$t = EducateQuotes($t);
}
}
$t = StupefyEntities($t) if $do_stupefy;
}
$prev_token_last_char = $last_char;
$result .= $t;
}
}
return $result;
}
sub SmartQuotes {
# Paramaters:
my $text = shift; # text to be parsed
my $attr = shift; # value of the smart_quotes="" attribute
my $do_backticks; # should we educate ``backticks'' -style quotes?
if ( $attr == 0 ) {
# do nothing;
return $text;
}
elsif ( $attr == 2 ) {
# smarten ``backticks'' -style quotes
$do_backticks = 1;
}
else {
$do_backticks = 0;
}
# Special case to handle quotes at the very end of $text when preceded by
# an HTML tag. Add a space to give the quote education algorithm a bit of
# context, so that it can guess correctly that it's a closing quote:
my $add_extra_space = 0;
if ( $text =~ m/>['"]\z/ ) {
$add_extra_space = 1; # Remember, so we can trim the extra space later.
$text .= " ";
}
my $tokens ||= _tokenize($text);
my $result = '';
my $in_pre = 0; # Keep track of when we're inside <pre> or <code> tags
my $prev_token_last_char = ""; # This is a cheat, used to get some context
# for one-character tokens that consist of
# just a quote char. What we do is remember
# the last character of the previous text
# token, to use as context to curl single-
# character quote tokens correctly.
foreach my $cur_token (@$tokens) {
if ( $cur_token->[0] eq "tag" ) {
# Don't mess with quotes inside tags
$result .= $cur_token->[1];
if ( $cur_token->[1] =~ m/$tags_to_skip/ ) {
$in_pre = defined $1 && $1 eq '/' ? 0 : 1;
}
}
else {
my $t = $cur_token->[1];
my $last_char =
substr( $t, -1 ); # Remember last char of this token before processing.
if ( !$in_pre ) {
$t = ProcessEscapes($t);
if ($do_backticks) {
$t = EducateBackticks($t);
}
if ( $t eq q/'/ ) {
# Special case: single-character ' token
if ( $prev_token_last_char =~ m/\S/ ) {
$t = "’";
}
else {
$t = "‘";
}
}
elsif ( $t eq q/"/ ) {
# Special case: single-character " token
if ( $prev_token_last_char =~ m/\S/ ) {
$t = "”";
}
else {
$t = "“";
}
}
else {
# Normal case:
$t = EducateQuotes($t);
}
}
$prev_token_last_char = $last_char;
$result .= $t;
}
}
if ($add_extra_space) {
$result =~ s/ \z//; # Trim trailing space if we added one earlier.
}
return $result;
}
sub SmartDashes {
# Paramaters:
my $text = shift; # text to be parsed
my $attr = shift; # value of the smart_dashes="" attribute
# reference to the subroutine to use for dash education, default to EducateDashes:
my $dash_sub_ref = \&EducateDashes;
if ( $attr == 0 ) {
# do nothing;
return $text;
}
elsif ( $attr == 2 ) {
# use old smart dash shortcuts, "--" for en, "---" for em
$dash_sub_ref = \&EducateDashesOldSchool;
}
elsif ( $attr == 3 ) {
# inverse of 2, "--" for em, "---" for en
$dash_sub_ref = \&EducateDashesOldSchoolInverted;
}
my $tokens;
$tokens ||= _tokenize($text);
my $result = '';
my $in_pre = 0; # Keep track of when we're inside <pre> or <code> tags
foreach my $cur_token (@$tokens) {
if ( $cur_token->[0] eq "tag" ) {
# Don't mess with quotes inside tags
$result .= $cur_token->[1];
if ( $cur_token->[1] =~ m/$tags_to_skip/ ) {
$in_pre = defined $1 && $1 eq '/' ? 0 : 1;
}
}
else {
my $t = $cur_token->[1];
if ( !$in_pre ) {
$t = ProcessEscapes($t);
$t = $dash_sub_ref->($t);
}
$result .= $t;
}
}
return $result;
}
sub SmartEllipses {
# Paramaters:
my $text = shift; # text to be parsed
my $attr = shift; # value of the smart_ellipses="" attribute
if ( $attr == 0 ) {
# do nothing;
return $text;
}
my $tokens;
$tokens ||= _tokenize($text);
my $result = '';
my $in_pre = 0; # Keep track of when we're inside <pre> or <code> tags
foreach my $cur_token (@$tokens) {
if ( $cur_token->[0] eq "tag" ) {
# Don't mess with quotes inside tags
$result .= $cur_token->[1];
if ( $cur_token->[1] =~ m/$tags_to_skip/ ) {
$in_pre = defined $1 && $1 eq '/' ? 0 : 1;
}
}
else {
my $t = $cur_token->[1];
if ( !$in_pre ) {
$t = ProcessEscapes($t);
$t = EducateEllipses($t);
}
$result .= $t;
}
}
return $result;
}
sub EducateQuotes {
#
# Parameter: String.
#
# Returns: The string, with "educated" curly quote HTML entities.
#
# Example input: "Isn't this fun?"
# Example output: “Isn’t this fun?”
#
local $_ = shift;
# Tell perl not to gripe when we use $1 in substitutions,
# even when it's undefined. Use $^W instead of "no warnings"
# for compatibility with Perl 5.005:
local $^W = 0;
# Make our own "punctuation" character class, because the POSIX-style
# [:PUNCT:] is only available in Perl 5.6 or later:
my $punct_class = qr/[!"#\$\%'()*+,-.\/:;<=>?\@\[\\\]\^_`{|}~]/;
# Special case if the very first character is a quote
# followed by punctuation at a non-word-break. Close the quotes by brute force:
s/^'(?=$punct_class\B)/’/;
s/^"(?=$punct_class\B)/”/;
# Special case for double sets of quotes, e.g.:
# <p>He said, "'Quoted' words in a larger quote."</p>
s/"'(?=\w)/“‘/g;
s/'"(?=\w)/‘“/g;
my $close_class = qr![^\ \t\r\n\[\{\(]!;
# Single closing quotes:
s {
($close_class)?
'
(?(1)| # If $1 captured, then do nothing;
(?=\s | s\b) # otherwise, positive lookahead for a whitespace
) # char or an 's' at a word ending position. This
# is a special case to handle something like:
# "<i>Custer</i>'s Last Stand."
} {$1’}xgi;
# Single opening quotes:
s/'/‘/g;
# Double closing quotes:
s {
($close_class)?
"
(?(1)|(?=\s)) # If $1 captured, then do nothing;
# if not, then make sure the next char is whitespace.
} {$1”}xg;
# Double opening quotes:
s/"/“/g;
return $_;
}
sub EducateBackticks {
#
# Parameter: String.
# Returns: The string, with ``backticks'' -style double quotes
# translated into HTML curly quote entities.
#
# Example input: ``Isn't this fun?''
# Example output: “Isn't this fun?”
#
local $_ = shift;
s/``/“/g;
s/''/”/g;
return $_;
}
sub EducateSingleBackticks {
#
# Parameter: String.
# Returns: The string, with `backticks' -style single quotes
# translated into HTML curly quote entities.
#
# Example input: `Isn't this fun?'
# Example output: ‘Isn’t this fun?’
#
local $_ = shift;
s/`/‘/g;
s/'/’/g;
return $_;
}
sub EducateDashes {
#
# Parameter: String.
#
# Returns: The string, with each instance of "--" translated to
# an em-dash HTML entity.
#
local $_ = shift;
s/--/—/g;
return $_;
}
sub EducateDashesOldSchool {
#
# Parameter: String.
#
# Returns: The string, with each instance of "--" translated to
# an en-dash HTML entity, and each "---" translated to
# an em-dash HTML entity.
#
local $_ = shift;
s/---/—/g; # em
s/--/–/g; # en
return $_;
}
sub EducateDashesOldSchoolInverted {
#
# Parameter: String.
#
# Returns: The string, with each instance of "--" translated to
# an em-dash HTML entity, and each "---" translated to
# an en-dash HTML entity. Two reasons why: First, unlike the
# en- and em-dash syntax supported by
# EducateDashesOldSchool(), it's compatible with existing
# entries written before SmartyPants 1.1, back when "--" was
# only used for em-dashes. Second, em-dashes are more
# common than en-dashes, and so it sort of makes sense that
# the shortcut should be shorter to type. (Thanks to Aaron
# Swartz for the idea.)
#
local $_ = shift;
s/---/–/g; # en
s/--/—/g; # em
return $_;
}
sub EducateEllipses {
#
# Parameter: String.
# Returns: The string, with each instance of "..." translated to
# an ellipsis HTML entity.
#
# Example input: Huh...?
# Example output: Huh…?
#
local $_ = shift;
s/\.\.\./…/g;
return $_;
}
sub StupefyEntities {
#
# Parameter: String.
# Returns: The string, with each SmartyPants HTML entity translated to
# its ASCII counterpart.
#
# Example input: “Hello — world.”
# Example output: "Hello -- world."
#
local $_ = shift;
s/–/-/g; # en-dash
s/—/--/g; # em-dash
s/‘/'/g; # open single quote
s/’/'/g; # close single quote
s/“/"/g; # open double quote
s/”/"/g; # close double quote
s/…/.../g; # ellipsis
return $_;
}
sub SmartyPantsVersion {
return $VERSION;
}
sub ProcessEscapes {
#
# Parameter: String.
# Returns: The string, with after processing the following backslash
# escape sequences. This is useful if you want to force a "dumb"
# quote or other character to appear.
#
# Escape Value
# ------ -----
# \\ \
# \" "
# \' '
# \. .
# \- -
# \` `
#
local $_ = shift;
s! \\\\ !\!gx;
s! \\" !"!gx;
s! \\' !'!gx;
s! \\\. !.!gx;
s! \\- !-!gx;
s! \\` !`!gx;
return $_;
}
sub _tokenize {
#
# Parameter: String containing HTML markup.
# Returns: Reference to an array of the tokens comprising the input
# string. Each token is either a tag (possibly with nested,
# tags contained therein, such as <a href="<MTFoo>">, or a
# run of text between tags. Each element of the array is a
# two-element array; the first is either 'tag' or 'text';
# the second is the actual value.
#
#
# Based on the _tokenize() subroutine from Brad Choate's MTRegex plugin.
# <http://www.bradchoate.com/past/mtregex.php>
#
my $str = shift;
my $pos = 0;
my $len = length $str;
my @tokens;
# pattern to match balanced nested <> pairs, up to two levels deep:
my $nested_angles = qr/<(?:[^<>]|<[^<>]*>)*>/;
while ( $str =~ m/($nested_angles)/gs ) {
my $whole_tag = $1;
my $sec_start = pos $str;
my $tag_start = $sec_start - length $whole_tag;
if ( $pos < $tag_start ) {
push @tokens, [ 'text', substr( $str, $pos, $tag_start - $pos ) ];
}
push @tokens, [ 'tag', $whole_tag ];
$pos = pos $str;
}
push @tokens, [ 'text', substr( $str, $pos, $len - $pos ) ] if $pos < $len;
\@tokens;
}
1;
__END__
=pod
=head1 Name
B<SmartyPants>
=head1 Synopsis
SmartyPants is a free web publishing plug-in for Movable Type, Blosxom,
and BBEdit that easily translates plain ASCII punctuation characters
into "smart" typographic punctuation HTML entities.
=head1 Description
SmartyPants can perform the following transformations:
=over 4
=item *
Straight quotes ( " and ' ) into "curly" quote HTML entities
=item *
Backticks-style quotes (``like this'') into "curly" quote HTML entities
=item *
Dashes (C<--> and C<--->) into en- and em-dash entities
=item *
Three consecutive dots (C<...>) into an ellipsis entity
=back
This means you can write, edit, and save your posts using plain old
ASCII straight quotes, plain dashes, and plain dots, but your published
posts (and final HTML output) will appear with smart quotes, em-dashes,
and proper ellipses.
SmartyPants is a combination plug-in -- the same file works with Movable
Type, Blosxom, and BBEdit. It can also be used from a Unix-style
command-line. Version requirements and installation instructions for
each of these tools can be found in the corresponding sub-section under
"Installation", below.
SmartyPants does not modify characters within C<< <pre> >>, C<< <code>
>>, C<< <kbd> >>, or C<< <script> >> tag blocks. Typically, these tags
are used to display text where smart quotes and other "smart
punctuation" would not be appropriate, such as source code or example
markup.
=head2 Backslash Escapes
If you need to use literal straight quotes (or plain hyphens and
periods), SmartyPants accepts the following backslash escape sequences
to force non-smart punctuation. It does so by transforming the escape
sequence into a decimal-encoded HTML entity:
Escape Value Character
------ ----- ---------
\\ \ \
\" " "
\' ' '
\. . .
\- - -
\` ` `
This is useful, for example, when you want to use straight quotes as
foot and inch marks: 6'2" tall; a 17" iMac.
=head2 MT-Textile Integration
Movable Type users should also note that SmartyPants can work in
conjunction with Brad Choate's MT-Textile plug-in:
http://bradchoate.com/past/mttextile.php
MT-Textile is a port of Dean Allen's original Textile project to Perl
and Movable Type. MT-Textile by itself only translates Textile markup
to HTML. However, if SmartyPants is also installed, MT-Textile will
call on SmartyPants to educate quotes, dashes, and ellipses,
automatically. Using SmartyPants in conjunction with MT-Textile
requires no modifications to your Movable Type templates.
Textile is Dean Allen's "humane web text generator", an easy-to-write
and easy-to-read shorthand for writing text for the web. An online
Textile web application is available at Mr. Allen's site:
http://textism.com/tools/textile/
=head1 Installation
=head2 Movable Type
SmartyPants works with Movable Type version 2.5 or later.
=over 4
=item 1.
Copy the "SmartyPants.pl" file into your Movable Type "plugins" directory.
The "plugins" directory should be in the same directory as "mt.cgi"; if it
doesn't already exist, use your FTP program to create it. Your
installation should look like this:
(mt home)/plugins/SmartyPants.pl
=item 2.
If you're using SmartyPants with Brad Choate's MT-Textile, you're done.
If not, to activate SmartyPants on your weblog, you need to edit your MT
templates. The easiest way is to add the C<smarty_pants> attribute to
each MT template tag whose contents you wish to apply SmartyPants'
transformations. Obvious tags would include C<MTEntryTitle>,
C<MTEntryBody>, and C<MTEntryMore>. SmartyPants should work within any
MT content tag.
For example, to apply SmartyPants to your entry titles:
<$MTEntryTitle smarty_pants="1"$>
The value passed to C<smarty_pants> specifies the way SmartyPants works.
See "Options", below, for full details on all of the supported options.
=back
=head2 Blosxom
SmartyPants works with Blosxom version 2.0 or later.
=over 4
=item 1.
Rename the "SmartyPants.pl" plug-in to "SmartyPants" (case is
important). Movable Type requires plug-ins to have a ".pl" extension;
Blosxom forbids it (at least as of this writing).
=item 2.
Copy the "SmartyPants" plug-in file to your Blosxom plug-ins folder. If
you're not sure where your Blosxom plug-ins folder is, see the Blosxom
documentation for information.
=item 3.
That's it. The entries in your weblog should now automatically have
SmartyPants' default transformations applied.
=item 4.
If you wish to configure SmartyPants' behavior, open the "SmartyPants"
plug-in, and edit the value of the C<$smartypants_attr> configuration
variable, located near the top of the script. The default value is 1;
see "Options", below, for the full list of supported values.
=back
=head2 BBEdit
SmartyPants works with BBEdit 6.1 or later on Mac OS X; and BBEdit 5.1
or later on Mac OS 9 or earlier (provided you have MacPerl
installed).
=over 4
=item 1.
Copy the "SmartyPants.pl" file to appropriate filters folder in your
"BBEdit Support" folder. On Mac OS X, this should be:
BBEdit Support:Unix Support:Unix Filters:
On Mac OS 9 or earlier, this should be:
BBEdit Support:MacPerl Support: Perl Filters:
See the BBEdit documentation for more details on the location of these
folders.
You can rename "SmartyPants.pl" to whatever you wish.
=item 2.
That's it. To use SmartyPants, select some text in a BBEdit document,
then choose SmartyPants from the Filters sub-menu or the Filters
floating palette. On Mac OS 9, the Filters sub-menu is in the "Camel"
menu; on Mac OS X, it is in the "#!" menu.
=item 3.
If you wish to configure SmartyPants' behavior, open the SmartyPants
file and edit the value of the C<$smartypants_attr> configuration
variable, located near the top of the script. The default value is 1;
see "Options", below, for the full list of supported values.
=back
=head1 Options
=head2 smarty_pants
For MT users, the C<smarty_pants> template tag attribute is where you
specify configuration options. For Blosxom and BBEdit users, settings
are specified by editing the value of the C<$smartypants_attr> variable
in the script itself.
Numeric values are the easiest way to configure SmartyPants' behavior:
=over 4
=item B<"0">
Suppress all transformations. (Do nothing.)
=item B<"1">
Performs default SmartyPants transformations: quotes (including
``backticks'' -style), em-dashes, and ellipses. "--" (dash dash) is used
to signify an em-dash; there is no support for en-dashes.
=item B<"2">
Same as smarty_pants="1", except that it uses the old-school typewriter
shorthand for dashes: "--" (dash dash) for en-dashes, "---" (dash dash dash)
for em-dashes.
=item B<"3">
Same as smarty_pants="2", but inverts the shorthand for dashes: "--"
(dash dash) for em-dashes, and "---" (dash dash dash) for en-dashes.
=item B<"-1">
Stupefy mode. Reverses the SmartyPants transformation process, turning the
HTML entities produced by SmartyPants into their ASCII equivalents. E.g.
"“" is turned into a simple double-quote ("), "—" is turned
into two dashes, etc. This is useful if you are using SmartyPants from
Brad Choate's MT-Textile text filter, but wish to suppress smart
punctuation in specific MT templates, such as RSS feeds. Text filters do
their work before templates are processed; but you can use
smarty_pants="-1" to reverse the transformations in specific templates.
=back
The following single-character attribute values can be combined to toggle
individual transformations from within the smarty_pants attribute. For
example, to educate normal quotes and em-dashes, but not ellipses or
``backticks'' -style quotes:
<$MTFoo smarty_pants="qd"$>
=over 4
=item B<"q">
Educates normal quote characters: (") and (').
=item B<"b">
Educates ``backticks'' -style double quotes.
=item B<"B">
Educates ``backticks'' -style double quotes and `single' quotes.
=item B<"d">
Educates em-dashes.
=item B<"D">
Educates em-dashes and en-dashes, using old-school typewriter shorthand:
(dash dash) for en-dashes, (dash dash dash) for em-dashes.
=item B<"i">
Educates em-dashes and en-dashes, using inverted old-school typewriter
shorthand: (dash dash) for em-dashes, (dash dash dash) for en-dashes.
=item B<"e">
Educates ellipses.
=item B<"w">
Translates any instance of C<"> into a normal double-quote character.
This should be of no interest to most people, but of particular interest
to anyone who writes their posts using Dreamweaver, as Dreamweaver
inexplicably uses this entity to represent a literal double-quote
character. SmartyPants only educates normal quotes, not entities (because
ordinarily, entities are used for the explicit purpose of representing the
specific character they represent). The "w" option must be used in
conjunction with one (or both) of the other quote options ("q" or "b").
Thus, if you wish to apply all SmartyPants transformations (quotes, en-
and em-dashes, and ellipses) and also translate C<"> entities into
regular quotes so SmartyPants can educate them, you should pass the
following to the smarty_pants attribute:
<$MTFoo smarty_pants="qDew"$>
For Blosxom and BBEdit users, set:
my $smartypants_attr = "qDew";
=back
=head2 Deprecated MT Attributes
The following Movable Type attributes are supported only for
compatibility with older versions of SmartyPants. They are obsoleted by
the C<smarty_pants> attribute, which offers more control than these
individual attributes. If you're setting up SmartyPants for the first
time, you should use the C<SmartyPants> attribute instead.
Blosxom and BBEdit users should simply ignore this section.
=head3 smart_quotes
The smart_quotes attribute accepts the following values:
=over 4
=item B<"0">
Suppress all quote education. (Do nothing.)
=item B<"1">
Default behavior. Educates normal quote characters: (") and (').
=item B<"2">
Educate ``backticks'' -style double quotes (in addition to educating
regular quotes). Transforms each instance of two consecutive backtick
characters (C<``>) into an opening double-quote, and each instance of two
consecutive apostrophes (C<''>) into a closing double-quote.
=back
=head3 smart_dashes
The smart_dashes attribute accepts the following values:
=over 4
=item B<"0">
Suppress dash education. (Do nothing.)