Mapping Submission IDs query fails in AllegroGraph

[mdorf]

The SPARQL query in the method def self.retrieve_latest_submission_ids(options = {}) of /lib/ontologies_linked_data/mappings/mappings.rb works in 4store but quietly fails in AllegroGraph (returns no results where results are expected):

SELECT (CONCAT(?ontology, "/submissions/", (MAX(?submissionId))) as ?id)
WHERE {
	?id <http://data.bioontology.org/metadata/ontology> ?ontology .
	?id <http://data.bioontology.org/metadata/submissionId> ?submissionId .
	?id <http://data.bioontology.org/metadata/submissionStatus> ?submissionStatus .
	?submissionStatus <http://data.bioontology.org/metadata/code> "RDF" .
	OPTIONAL {
		?id <http://data.bioontology.org/metadata/ontology> ?ontJoin .
	}
	OPTIONAL {
		?ontJoin <http://data.bioontology.org/metadata/viewOf> ?viewOf .
	}
	FILTER(!BOUND(?viewOf))
}
GROUP BY ?ontology

[mdorf]

Turns out AG has a stricter interpretation of CONCAT, which takes in String values as arguments. The solution is to explicitly cast the arguments in CONCAT to strings:

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT (CONCAT(xsd:string(?ontology), "/submissions/", xsd:string(MAX(?submissionId))) as ?id)
WHERE {
	?id <http://data.bioontology.org/metadata/ontology> ?ontology .
	?id <http://data.bioontology.org/metadata/submissionId> ?submissionId .
	?id <http://data.bioontology.org/metadata/submissionStatus> ?submissionStatus .
	?submissionStatus <http://data.bioontology.org/metadata/code> "RDF" .
	OPTIONAL {
		?id <http://data.bioontology.org/metadata/ontology> ?ontJoin .
	}
	OPTIONAL {
		?ontJoin <http://data.bioontology.org/metadata/viewOf> ?viewOf .
	}
	FILTER(!BOUND(?viewOf))
}
GROUP BY ?ontology

[mdorf]

This has been resolved and deployed to production.